An array is a collection of related types, and there are several ways to declare an array in MSIL. The underlying type of any array is always System.Array. With an array reference, you can call the methods and access the properties of System.Array.

Table 14-6 lists different syntax for defining an array.

The newarr instruction initializes a one-dimensional array. In addition, the instruction pushes a reference to the array onto the evaluation stack. You might want to use the array for some time. Move the array reference from the evaluation stack to memory, such as to a local variable, to maintain access to the array. Alternatively, use the dup instruction to push additional references to the array on the evaluation stack, as needed. The newarr instruction takes as an argument the number of elements, which must be placed on the evaluation stack prior to the instruction call.

The syntax is as follows:

newarr type

Elements of an array can be accessed with the ldelem or stelem instructions. The ldelem instruction loads an element of an array onto the evaluation stack; the stelem instruction stores a value from the evaluation stack into an element of an array. Both instructions have variations that depend on the type of data being manipulated. The variations of ldelem and stelem are shown in Table 14-7.

The ldelem instruction requires the array reference and the element index on the evaluation stack, in that order. The stelem instruction requires the array reference, element index, and the new value, again in that order.

In the following code, an array of three strings is created. Each element is initialized to a different color name. The array elements then are displayed in a loop:

.assembly extern mscorlib {}
.assembly application {}

.namespace Donis.CSharpBook {

    .class starter {

        .method static public void Main() il managed {
            .locals init (string [] names, int32 count)
            .entrypoint
            ldc.i4.3
            newarr string
            stloc names
            ldloc names
            ldc.i4.0
            ldstr "Aqua"
            stelem.ref
            ldloc names
            ldc.i4.1
            ldstr "Violet"
            stelem.ref
            ldloc names
            ldc.i4.2
            ldstr "Orange"
            stelem.ref
            ldc.i4.0
            stloc count
loop:       ldloc names
            ldloc count
            ldelem.ref
            call void [mscorlib] System.Console::WriteLine(string)
            ldloc count
            ldc.i4.1
            add
            dup
            stloc count
            ldc.i4.3
            blt loop
            ret
        }
    }
}