The Shapes collection uses different methods for adding the different types of shapes. Table 25.1 lists the Shape objects you can add and the methods and arguments for adding them. The following sections explain the arguments.

Sub test()

ActivePresentation.Slides(ActivePresentation.Slides.Count - 1) _
    .Shapes.AddShape Type:=msoShapeBentUpArrow, Left:=575, Top:=10, _
    Width:=150, Height:=75

End Sub

ActivePresentation.Slides(3).Shapes.AddTextEffect _
   PresetTextEffect:=msoTextEffect14, _
        Text:="Questions" + Chr$(CharCode:=13) + _
        "&" + Chr$(CharCode:=13) + "Answers", _
        FontName:="Garamond", FontSize:=54, FontBold:=msoTrue, _
        FontItalic:=msoFalse, Left:=230, Top:=125

Dim myTextBox As Shape

With ActivePresentation.Slides(2)
    Set myTextBox = .Shapes.AddTextbox _
        (Orientation:=msoTextOrientationHorizontal, Left:=100, Top:=50, _
        Width:=400, Height:=100)
    myTextBox.TextFrame.TextRange.Text = "Corrective Lenses"
End With

To delete a shape, use the Delete method with the appropriate Shape object. For example, the following statement deletes the first Shape object on the second slide in the active presentation:

ActivePresentation.Slides(2).Shapes(1).Delete

To select all the shapes on a slide, use the SelectAll method of the appropriate Shapes collection. For example, the following statement selects all the Shape objects on the first slide in the active presentation:

ActivePresentation.Slides(1).Shapes.SelectAll

To reposition a shape, set its Left property (to specify the distance in points from the left edge of the slide to the left edge of the shape) and its Top property (to specify the distance in points from the top edge of the slide to the top edge of the shape).

To change the size of a shape, set its Width and Height properties to the appropriate number of points.

For example, the following statements position the first shape on the first slide in the active presentation 200 points from the left of the slide and 100 points from its top and make the shape 300 points wide by 200 points high:

With ActivePresentation.Slides(1).Shapes(1)
    .Left = 200
    .Top = 100
    .Width = 300
    .Height = 200
End With

You can also move a shape by using the IncrementLeft method and the IncrementTop method and rotate the shape by using the IncrementRotation method. These moves are relative to the current position of the shape, not absolute specified locations within a slide. Each of these methods takes an Increment argument:

The following example works with the first shape on the third slide of the active presentation, moving it 100 points to the left and 200 points down and rotating it 90 degrees counterclockwise:

With ActivePresentation.Slides(3).Shapes(1)
    .IncrementLeft Increment:=-100
    .IncrementTop Increment:=200
    .IncrementRotation Increment:=-90
End With

Often, it's useful to be able to apply the same formatting to multiple shapes. When one shape has the formatting you need, you can use the PickUp method of the Shape object to copy the formatting from that shape and then use the Apply method to apply that formatting to another shape.

Neither the PickUp method nor the Apply method uses any arguments. The following example copies the formatting from the first shape on the second slide in the active presentation and applies it to the third shape on the fourth slide:

With ActivePresentation
    .Slides(2).Shapes(1).PickUp
    .Slides(4).Shapes(3).Apply
End With

The text within a shape is contained in a TextRange object, which itself is contained in a TextFrame object. To work with the text in a shape, you use the TextFrame property of the Shape object to return the TextFrame object and then use the TextRange property of the TextFrame object to return the TextRange object. Got it?

Within the TextRange object, the Text property contains the text, the Font object contains the font formatting, the ParagraphFormat object contains the paragraph formatting, and the ActionSettings collection contains the action settings for the text range.

If ActivePresentation.Slides(1).Shapes(1).HasTextFrame = msoTrue Then
    MsgBox "The shape contains a text frame."
End If

With ActivePresentation.Slides(1).Shapes(1).TextFrame
    If .HasText = msoTrue Then MsgBox .TextRange.Text
End With

Sub Test()

Dim myPresentation As Presentation
Set myPresentation = Presentations(1)

myPresentation.Slides(4).Shapes(1).TextFrame.TextRange.Text _
    = "Strategic Planning Meeting"

End Sub

expression.Paragraphs(Start, Length)

MsgBox ActivePresentation.Slides(1).Shapes(1).TextFrame _
    .TextRange.Words(Start:=2, Length:=4)

myPresentation.Slides(6).Shapes(2).TextFrame.TextRange _
    .Paragraphs(Start:=2, Length:=1).Text = "VP of Business Development"

Dim mySlide As Slide
Set mySlide = Presentations(1).Slides(2)

With mySlide.Shapes(2).TextFrame.TextRange.ParagraphFormat
    .Alignment = ppAlignLeft
    .LineRuleAfter = msoFalse
    .SpaceAfter = 18
    .LineRuleBefore = msoFalse
    .SpaceBefore = 18
    .LineRuleWithin = msoFalse
    .SpaceWithin = 12
End With

Formatting the Bullets for a Text Range

Bullets and numbers are vital to the lists used in many PowerPoint slides. To control whether and how bullets and numbers appear, use the Bullet property of the TextRange object to return the BulletFormat object, and then work with the BulletFormat object's properties and methods.

To make bullets and numbers visible, set the Visible property of the BulletFormat object to msoTrue; to hide bullets and numbers, set Visible to msoFalse.

To specify which type of bullet or numbering to use, set the Type property of the BulletFormat object to ppBulletUnnumbered (for a bullet), ppBulletNumbered (numbers), ppBulletPicture (for a picture), or ppBulletNone (no bullet).

Another Mixed Data Type

The Type property of the BulletFormat object returns the value ppBulletMixed when the selection includes multiple types of bullets. You can't set Type to ppBulletMixed. You can only read it.

To specify the bullet character, use the Character property and the character number. You can find out the character number from the Symbol dialog box or the Character Map applet, which you can run by choosing Start

Unfortunately, the character codes are given in the hexadecimal numbering system. If you look up the check box symbol for the Wingdings font that's used in the following code example, the character map utility doesn't say 254 in our human decimal numbering system. Instead, it says Character Code: 0xFE. This tedious holdover from the early days of computing serves no particular purpose in character codes, but you have to deal with it. Why? Because some people think that pointless complexity is cute, or it helps make programming seem somehow more mysterious than it in fact is.

To solve the hex character code problem, you can either use a calculator that can translate between hex and decimal or prepend the characters &H in front of the hex code and let VBA translate it for you when executing your procedure. For example, in the following code example, I used 254 (a decimal number) because I can translate hex. But if you can't, or more likely don't want to be bothered, just click the character you want to use in the Character Map dialog box and then look at its hex code in the lower-left portion. In this example, it's listed as 0xFE (which means, you guessed it, decimal 254). Since the Wingdings font has only 256 characters, ignore the 0x part and use the FE, like this, in your code:

.Character = &H FE

Use the Font property to specify the font name, size, and color. The following example sets the bullet for the first shape on the slide identified by the object variable mySlide to Wingdings character 254, a check box, using the color white, which is RGB(255, 255, 255), and 44-point size:

With mySlide.Shapes(1).TextFrame.TextRange.ParagraphFormat.Bullet
    .Type = ppBulletUnnumbered
    .Character = 254
    With .Font
        .Name = "Wingdings"
        .Size = 44
        .Color = RGB(255, 255, 255)
    End With
End With

Color is of course an important element in any design. You can easily find out which RGB values you need to employ for various colors by visiting this web page:

http://cloford.com/resources/colours/500col.htm

To use your own custom picture as a bullet, set the Type property of the BulletFormat object to ppBulletPicture and then use the Picture method with the Picture argument, a required String argument that specifies the path and filename of the file to use as the bullet. You can use most types of graphics files, including BMP, EPS, GIF, JPG, JPEG, PCX, PNG, TIFF, and WMF files. The following example uses the file Face1.jpg stored in the folder Z:PublicPictures as the bullet for the first shape on the slide identified by the object variable mySlide:

With mySlide.Shapes(1).TextFrame.TextRange.ParagraphFormat.Bullet
    .Type = ppBulletPicture
    .Picture Picture:="z:PublicPicturesFace1.jpg"
End With

To animate a shape or a range of shapes, use the AnimationSettings property of the Shape object or the ShapeRange object to return the AnimationSettings object.

To specify the animation effect to use, set the EntryEffect property to the constant for the effect. Let's see how to figure out which animation effect looks best for the shape you're working with. First, click a shape in a slide to select the shape. Now display the Add Animation pane.

There are too many animation constants to list here, but their names are easy to work out from the names listed in the Add Animation pane. To open this pane, click the Animation tab in PowerPoint's Ribbon, then click the Add Animation icon in the Advanced Animation section. A pane drops down on the right side of PowerPoint's window. As you hover your mouse pointer over each animation option in the Add Animation pane, you'll see the effect illustrated visually in the slide. It's pretty cool, not to mention efficient.

To write code that creates an animation, set the Animate property to msoTrue. (To turn off an animation, set Animate to msoFalse.)

To control how the text in a shape is animated, set the TextLevelEffect property to ppAnimateLevelNone (no animation), ppAnimateByFirstLevel, ppAnimateBySecondLevel, ppAnimateByThirdLevel, ppAnimateByFourthLevel, ppAnimateByFifthLevel, or ppAnimateByAllLevels.

If you set TextLevelEffect to any value other than ppAnimateByAllLevels or ppAnimate LevelNone, you can use the TextUnitEffect property to specify how to animate the text. Use ppAnimateByParagraph to animate by paragraph, ppAnimateByWord to animate by word, or ppAnimateByCharacter to animate by character.

To reverse the order of the animation, set the AnimateTextInReverse property to msoTrue. (The default is msoFalse.)

To control how the animation advances, set the AdvanceMode property to ppAdvanceOnTime (for automatic advancing using a timing) or ppAdvanceOnClick (for manual advancing). If you use automatic advancing, use the AdvanceTime property to specify the number of seconds to wait before advancing.

To play a preset sound effect with the transition, use the SoundEffect property of the AnimationSettings object to return the SoundEffect object, use the Name property to specify the name of the sound effect, and then use the Play method to play the sound effect. You can also play a separate sound file by using the ImportFromFile method of the SoundEffect object and using the FullName argument to specify the path and filename of the sound file.

To control how a media clip is played, use the PlaySettings property of the Animation Settings object to return the PlaySettings object. For example, if you want the sound to loop until the next sound, set the LoopSoundUntilNext property of the PlaySettings object within the AnimationSettings object to msoTrue. The default value is msoFalse.

You can find all these options by pressing F2 to display the Object Browser in the VBA Editor and then searching for them. For example, search for ppEntryEffect to see all possible constants for the various possible lead-in animations.

The following example applies a custom animation to the first shape on the slide identified by the object variable mySlide. The animation uses the entry effect Fly In from the right, plays a sound effect from a file, animates the text by first-level paragraphs and by whole paragraphs, and advances when the user clicks:

Dim mySlide As Slide
Set mySlide = Presentations(1).Slides(2)

With mySlide.Shapes(1).AnimationSettings
    .EntryEffect = ppEffectFlyFromRight
    .AdvanceMode = ppAdvanceOnClick
    .SoundEffect.ImportFromFile FileName:="D:MediaWhistle4.wav"
    .TextLevelEffect = ppAnimateByFirstLevel
    .TextUnitEffect = ppAnimateByParagraph
End With

To test this (or other code examples you try in PowerPoint), just press F5 in the main PowerPoint window, and then repeatedly click the screen to activate the various transitions and effects. Press Esc when you're done.

To return the object you want, use the appropriate property of the HeaderFooter object:

The following example uses the Footer property to set the text of the HeaderFooter object of the first slide in the active presentation:

ActivePresentation.Slides(1).HeadersFooters.Footer.Text = "Sentence 102"

To display the HeaderFooter object, set its Visible property to msoTrue (or just True). To hide the HeaderFooter object, set its Visible property to msoFalse. For example, the following statement hides the footer on the fifth slide in the active presentation:

ActivePresentation.Slides(5).HeadersFooters.Footer.Visible = False

To set the text that you want in a HeaderFooter object, assign a string containing the text to the object's Text property. For example, the following statement sets the text of the footer of the fifth slide in the active presentation to Confidential:

ActivePresentation.Slides(5).HeadersFooters.Footer.Text = "Confidential"

If you executed the previous example code, executing this example will trigger an error message. That's because you made the same slide (#5) invisible in the previous code. To be able to set the text in this slide, it must first be visible:

ActivePresentation.Slides(5).HeadersFooters.Footer.Visible = True
ActivePresentation.Slides(5).HeadersFooters.Footer.Text = "Confidential"

If your slides, notes pages, or handouts use dates and times in their footers or headers, use the Format property to specify how the dates and times should appear. Table 25.2 lists the constants you can use.

Set the UseFormat property of the HeaderFooter to msoTrue if you want the date and time to be updated automatically. Set UseFormat to msoFalse if you want the date and time to remain unchanged.

The following sections show an example of using the UseFormat property and the format property of a HeaderFooter object.

To specify the type of show, set the ShowType property of the SlideShowSettings object to ppShowTypeSpeaker (for a standard full-screen presentation presented by a speaker), ppShowTypeKiosk (for a kiosk presentation), or ppShowTypeWindow (for a "browsed by an individual" presentation that appears in a window). For a show in a window, you can use the Left and Top properties to specify the position of the upper-left corner of the window and the Height and Width properties to specify its size.

To control whether animation and narration are used, set the ShowWithAnimation property and the ShowWithNarration property of the SlideShowSettings object to msoTrue or msoFalse.

To control whether the presentation loops until stopped, set the LoopUntilStopped property of the SlideShowSettings object to msoTrue or msoFalse.

To control how the presentation advances, set the AdvanceMode property to ppSlideShow ManualAdvance (for manual advancing), ppSlideShowUseSlideTimings (for automatic advancing using timings already set), or ppSlideShowRehearseNewTimings (to rehearse new timings while the show plays).

The following example sets the active presentation running as a kiosk presentation that will advance automatically using its timings and loop until it is stopped:

With ActivePresentation.SlideShowSettings
    .LoopUntilStopped = msoCTrue
    .AdvanceMode = ppSlideShowUseSlideTimings
    .ShowType = ppShowTypeKiosk
    .Run
End With

The following example sets the presentation named Corporate.pptm running in speaker (full-screen) mode, sizing the image to 800×600 pixels and positioning it at the upper-left corner of the screen. The show uses manual advancing:

With Presentations("Corporate.pptm").SlideShowSettings
    .LoopUntilStopped = msoFalse
    .ShowType = ppShowTypeSpeaker
    .AdvanceMode = ppSlideShowManualAdvance
    With .Run

.Height = 600
        .Width = 800
        .Left = 0
        .Top = 0
    End With
End With

Custom shows within a presentation are represented by the NamedSlideShows collection within the SlideShowSettings object. Use the NamedSlideShows property of the SlideShowSettings object to return the NamedSlideShows collection.

To create a custom show, use the Add method of the NamedSlideShows collection. The syntax is as follows:

expression.Add(Name, SafeArrayOfSlideIDs)

Here, expression is a required expression that returns a NamedSlideShows object. Name is a required String argument that specifies the name to assign to the new custom show. SafeArrayOfSlideIDs is a required Variant that specifies the numbers or names of the slides to include in the custom show.

For example, the following statements declare an array of the Long data type; assign to it slides 2, 4, 5, and 10 from the open presentation named Corporate.pptm; and create a new custom show named Short Show using the array:

Dim myArray(4) As Long
With Presentations("Corporate.pptm")
    myArray(1) = .Slides(2).SlideID
    myArray(2) = .Slides(4).SlideID
    myArray(3) = .Slides(5).SlideID
    myArray(4) = .Slides(10).SlideID
    .SlideShowSettings.NamedSlideShows.Add Name:="Short Show", _
         safeArrayOfSlideIDs:=myArray
End With

To delete a custom show, use the Delete method with the appropriate NamedSlideShow object. For example, the following statement deletes the custom show named Overview from the active presentation:

ActivePresentation.SlideShowSettings.NamedSlideShows("Overview").Delete

To start a slide show using the whole presentation, use the Run method of the SlideShowSettings object. For example, the following statement starts the slide show running in the presentation identified by the object variable myPresentation:

myPresentation.SlideShowSettings.Run

To show only a range of slides from a presentation, set the RangeType property of the SlideShowSettings object to ppShowSlideRange, use the StartingSlide property of the SlideShowSettings object to specify the first slide and the EndingSlide property to specify the last slide, and then use the Run method to run the presentation. The following example shows slides 4 through 8 in the presentation named Corporate.pptm:

With Presentations("Corporate.pptm").SlideShowSettings
    .RangeType = ppShowSlideRange
    .StartingSlide = 4
    .EndingSlide = 8
    .Run
End With

To start running a custom show, set the RangeType property of the SlideShowSettings object to ppShowNamedSlideShow, use the SlideShowName property to specify the name of the custom show, and then use the Run method to run the custom show. The following example shows the custom show named Short Show in the active presentation:

With ActivePresentation.SlideShowSettings
    .RangeType = ppShowNamedSlideShow
    .SlideShowName = "Short Show"
    .Run
End With

When you start a slide show, VBA creates a SlideShowWindow object representing the object. You can access the SlideShowWindow object either through the SlideShowWindows collection (a creatable object that contains a SlideShowWindow object for each open slide show) or through the SlideShowWindow property of the Presentation object. If you know which presentation is running, it's easier to go through the appropriate Presentation object.

To find out whether a slide show is displayed full screen or in a window, check the IsFullScreen property of the SlideShowWindow object. If the IsFullScreen property returns −1, the presentation is full screen; if the property returns 0, the presentation is a window.

To set the height and width of the slide show window in pixels, use the Height property and the Width property. To set its position, use the Top property to specify the distance in pixels of the top edge of the presentation from the top of the window or screen and the Left property to specify the distance in pixels of the left edge of the presentation from the left edge of the window or the screen.

Apart from controlling the position and size of the presentation, most of the actions you can take with a presentation involve the View object. To find out which slide is displayed, return the CurrentShowPosition property:

MsgBox ActivePresentation.SlideShowWindow.View.CurrentShowPosition

To display the first slide in the presentation, use the First method. To display the last slide, use the Last method:

ActivePresentation.SlideShowWindow.View.First
ActivePresentation.SlideShowWindow.View.Last

To display the next slide, use the Next method. To display the previous slide, use the Previous method. Here's an example:

ActivePresentation.SlideShowWindow.View.Previous

To display a particular slide in the slide show, use the GotoSlide method of the View object, using the Index argument to specify the slide number. For example, the following statement displays slide 5 in the first open slide show window:

Application.SlideShowWindows(1).View.GotoSlide Index:=5

To display a black screen, set the State property of the View object to ppSlideShowBlackScreen. To display a white screen, set the State property to ppSlideShowWhiteScreen:

ActivePresentation.SlideShowWindow.View.State = ppSlideShowBlackScreen
ActivePresentation.SlideShowWindow.View.State = ppSlideShowWhiteScreen

To toggle the black screen or white screen off and start the show running again, set the State property to ppSlideShowRunning.

To pause the presentation, set the State property of the View object to ppSlideShowPaused. To start the show again, set the State property to ppSlideShowRunning, as in this example:

With ActivePresentation.SlideShowWindow.View
    .State = ppSlideShowPaused
    .State = ppSlideShowRunning
End With

To start a custom show running, use the GotoNamedShow method and use the SlideShowName argument to specify the name of the custom show. For example, the following statement starts the custom show named New Show running:

SlideShowWindows(1).GotoNamedShow SlideShowName:="New Show"

To exit a custom show, use the EndNamedShow method and then use the Next method to advance the presentation. PowerPoint then displays the first slide in the full presentation:

With ActivePresentation.SlideShowWindow.View
    .EndNamedShow
    .Next
End With

To exit the slide show, use the Exit method of the View property of the SlideShowWindow object. For example, the following statement exits the slide show in the active presentation:

ActivePresentation.SlideShowWindow.View.Exit