2.6. A Hybrid Method

As we've seen, both the GEE method and the random effects method may produce estimates that are markedly different from the fixed effects estimates. That's because neither of those methods controls for stable, unmeasured characteristics of the individuals. There's another approach, however, that combines some of the virtues of fixed effects and random effects methods. This method produces coefficient estimates that are identical to those from the fixed effects method, but the standard errors and test statistics might be somewhat different, depending on the details of the estimation method.

The basic idea is to decompose the time-varying predictors into two parts, one representing within-person variation, the other representing between-person variation (Neuhaus and Kalbfleisch 1998). Both of these components are used as predictors in the regression model. The coefficients for the within-person components will be identical to those for the classic fixed effects estimates.

There are several potential advantages of doing it this way. One is that you also get estimates for the between-person effects, as well as coefficients for any measured time-invariant predictors. Second, by testing whether the between-person coefficients are the same as the corresponding within-person coefficients, you get a test that has the same function as the Hausman test that we looked at earlier. That is, it can tell you whether a fixed effects approach offers any gains over a random effects regression. Third, using the options available in PROC MIXED, you can extend the conventional fixed effects models in several important ways.

Here's how to do it for the NLSY data. First, we use PROC MEANS to calculate the means for SELF and POV across the three observations for each child, and output them to a data set. The NWAY and NOPRINT options suppress unwanted output. The CLASS statement says to compute the means separately for each value of the ID variable. The data set of means is then merged with the original data, and deviations of each variable from its within-person mean are calculated:

PROC MEANS DATA=persyr3 NWAY NOPRINT;
   CLASS id;
   VAR self pov;
   OUTPUT OUT=a MEAN=mself mpov;
PROC SORT DATA=persyr3;
   BY id;
PROC SORT DATA=a;
   BY id;
DATA combine;
   MERGE persyr3 a;
   BY id;
   dself=self-mself;
   dpov=pov-mpov;
   dtime=time-2;
   time1=(time=1);
   time2=(time=2);
RUN;

Note that I've calculated deviation scores for TIME, although I won't use those in the first few models. (The mean of TIME is necessarily 2 for every child). I've also created two dummy variables, TIME1 and TIME2, so that I can represent time in PROC REG, which doesn't have a CLASS statement.

In the literature on multilevel models (Bryk and Raudenbusch 1992; Goldstein 1987; Kreft et al. 1995), the practice of subtracting person-specific means from each time-varying variable is referred to as group-mean centering. Although it is well-known that using group-mean centered variables can produce substantially different results, this literature has not generally made the connection to fixed effects models nor has it been recognized that group-mean centering controls for all time-invariant covariates.

The calculation of centered predictors is similar to the computational method for getting fixed effects estimates that I described in the previous section. What's new here is that we don't calculate centered scores for the dependent variable. Once the new data set is constructed, we can run an OLS regression with both the centered variables and the mean variables, along with any other time-invariant predictors that we want to include:

PROC REG DATA=combine;
   MODEL anti=dpov dself mpov mself time1 time2 black hispanic
         childage married gender momage momwork;
RUN;

Results are in Output 2.20. The coefficients for the centered variables, DPOV and DSELF, are the same as the fixed effects coefficients for POV and SELF in Output 2.10. But we also get coefficients for several time-invariant predictors, something that was not available with the earlier method.

Table 2.20. Output 2.20 OLS Regression Using Centered Predictors

Root MSE	1.50725	R-Square	0.0935
Dependent Mean	1.63683	Adj R-Sq	0.0867
Coeff Var	92.08316

Variable	DF	Parameter Estimate	Standard Error	tValue	Pr>|t|
Intercept	1	3.11882	0.79422	3.93	<.0001
dpov	1	0.11247	0.14121	0.80	0.4258
dself	1	−0.05515	0.01591	−3.47	0.0005
mpov	1	0.61643	0.10710	5.76	<.0001
mself	1	−0.09003	0.01506	−5.98	<.0001
time1	1	−0.21074	0.08888	−2.37	0.0179
time2	1	−0.16634	0.08853	−1.88	0.0604
black	1	0.11093	0.09019	1.23	0.2189
hispanic	1	−0.27990	0.09513	−2.94	0.0033
childage	1	0.08575	0.06206	1.38	0.1672
married	1	−0.12841	0.08788	−1.46	0.1441
gender	1	−0.50816	0.07289	−6.97	<.0001
momage	1	−0.01134	0.01738	−0.65	0.5142
momwork	1	0.16412	0.08141	2.02	0.0440

Despite the fact that the coefficients for DPOV and DSELF replicate our earlier results, the reported standard errors for those coefficients are about 50% larger in Output 2.20 than they were in Output 2.10. This means, of course, that the t-statistics are about 1/3 smaller. That's because the error term in the earlier regression consisted entirely of within-person variation on the dependent variable. Here there is both within-person and between-person variation. We can correct the problem by estimating a random effects model in PROC MIXED:

PROC MIXED DATA=combine COVTEST NOCLPRINT;
   CLASS id time;
   MODEL anti=dpov dself mpov mself time black hispanic
         childage married gender momage momwork / SOLUTION;
   RANDOM INTERCEPT / SUBJECT=id;
RUN;

Results in Output 2.21 have standard errors for DPOV and DSELF that are identical to those in Output 2.10. Note, however, that for the time-invariant predictors, the random effects standard errors are larger than the OLS standard errors rather than smaller (which is just what is expected from clustering adjustments).

Table 2.21. Output 2.21 PROC MIXED Estimates for Centered Predictors

Covariance Parameter Estimates
Cov Parm	Subject	Estimate	Standard Error	Z Value	PrZ
Intercept	id	1.2896	0.09692	13.31	<.0001
Residual		0.9942	0.04132	24.06	<.0001

Solution for Fixed Effects
Effect	time	Estimate	Standard Error	DF	tValue	Pr > |t|
Intercept		3.1188	1.1601	571	2.69	0.0074
dpov		0.1125	0.09341	1158	1.20	0.2288
dself		−0.05515	0.01053	1158	−5.24	<.0001
mpov		0.6164	0.1567	1158	3.93	<.0001
mself		−0.09003	0.02203	1158	−4.09	<.0001
time	1	−0.2107	0.05880	1158	−3.58	0.0004
time	2	−0.1663	0.05857	1158	−2.84	0.0046
time	3	0	.	.	.	.
black		0.1109	0.1320	1158	0.84	0.4007
hispanic		−0.2799	0.1392	1158	−2.01	0.0446
childage		0.08575	0.09080	1158	0.94	0.3452
married		−0.1284	0.1286	1158	−1.00	0.3181
gender		−0.5082	0.1066	1158	−4.77	<.0001
momage		−0.01134	0.02543	1158	−0.45	0.6558
momwork		0.1641	0.1191	1158	1.38	0.1685

What we've gained by the centering method is the ability to estimate coefficients for time-invariant predictors. It's essential to keep in mind, however, that the coefficients of the time invariant predictors (unlike those for the within-person time-varying predictors) will be biased if those variables are correlated with the unobserved fixed effects. There's another attraction to this approach. If the random effects model is correct (that is, if the time-varying predictors are uncorrelated with person-specific fixed effects), the coefficients for the centered variables should be the same as the coefficients for the mean variables. Since both are estimated in the same model, it's easy to test that assumption in PROC MIXED by including CONTRAST statements after the MODEL statement:

CONTRAST 'pov' dpov 1 mpov −1;
CONTRAST 'self' dself 1 mself −1;
CONTRAST 'overall' dpov 1 mpov −1, dself 1 mself −1;

For each CONTRAST statement, the text in quotes is a required label, used for distinguishing one test from another in the output. The first CONTRAST statement tests whether the coefficients for DPOV and MPOV are the same. In detail, the coefficient for DPOV is multiplied by 1, the coefficient for MPOV is multiplied by −1, the results are added together, and the sum is tested for a difference with 0. The next CONTRAST statement does the same for the two self-esteem variables, and the final CONTRAST statement tests both hypotheses simultaneously. In Output 2.22, we see strong evidence that the assumption is not satisfied for POV, but might be for SELF. The overall test yields results very similar to the Hausman test in Output 2.17.

Table 2.22. Output 2.22 Tests for Fixed Effects vs. Random Effects Using Centered Scores

Contrasts
Label	Num DF	Den DF	F Value	Pr>F
pov	1	1158	7.63	0.0058
self	1	1158	2.04	0.1535
overall	2	1158	4.93	0.0073

If we conclude that the coefficients for the mean and deviation scores are different for a particular variable, a natural question is whether the coefficient for the mean has any useful interpretation. In most cases, I don't think so, because that coefficient is typically confounded with the effects of other unobserved variables. Nevertheless, it's important to have the mean variables in the model in order to get good estimates of the effects of other time-invariant variables. Omitting them would mean that the variable in question was not fully controlled.

Another advantage of the centering method for getting fixed effects estimates is that we can allow for random variation in the slope parameters for the time-varying predictors. For example, instead of estimating separate coefficients for time 1 and time 2, let's assume that the antisocial behavior changes linearly with time. Then we allow the coefficient of TIME (actually DTIME, which is TIME minus the mean of 2) to vary randomly from child to child—a random, linear growth model. Here's how to set it up:

PROC MIXED DATA=combine COVTEST NOCLPRINT;
   CLASS id;
   MODEL anti=dpov dself dtime mpov mself / SOLUTION;
   RANDOM INTERCEPT dtime / SUBJECT=id;
RUN;

Output 2.23 gives the results. We see that the fixed coefficient for DTIME (.1055) is highly significant, but the variance around that coefficient (.1409) is also highly significant. So we conclude that antisocial behavior tends to increase over time during the adolescent years, but there is substantial variation among children in the rate of increase.

Table 2.23. Output 2.23 Estimates for a Random Growth Curve Model with Fixed Effects

Covariance Parameter Estimates
Cov Parm	Subject	Estimate	Standard Error	Z Value	PrZ
Intercept	id	1.4139	0.1013	13.96	<.0001
dtime	id	0.1409	0.04184	3.37	0.0004
Residual		0.8539	0.05021	17.01	<.0001

Solution for Fixed Effects
Effect	Estimate	Standard Error	DF	tValue	Pr > |t|
Intercept	2.9336	0.4616	579	6.36	<.0001
dpov	0.1387	0.09391	578	1.48	0.1402
dself	−0.05515	0.01048	578	−5.26	<.0001
dtime	0.1055	0.03140	580	3.36	0.0008
mpov	0.6842	0.1376	578	4.97	<.0001
mself	−0.07477	0.02225	578	−3.36	0.0008

In the same way, I tried fitting models for random variation in the effect of POV and SELF, but there is no evidence for such variation (results not shown). This approach of combining models with fixed and random effects is quite similar to the conditional linear mixed models of Verbeke et al. (2001), although they used a somewhat different computational method for obtaining the estimates.^[]

^[] Verbeke et al. (2001) provide a SAS macro that transforms the data set as a precursor to using PROC MIXED.

One final attraction of estimating the fixed effects model with PROC MIXED is the ability to specify models for the error structure that are less constrained than the conventional fixed effects method, which implies a covariance structure for the dependent variable known as compound symmetry. Compound symmetry means that variance of the error term is constant over time and the covariance between any two time points is the same. PROC MIXED allows for a wide variety of alternative structures that can be specified with the REPEATED statement. Although there isn't space for a detailed discussion of the many options, let's consider the most general option, which has no constraints whatever on the error structure. While this option would not work well if there were many time points (there would be too many different covariances), it's quite reasonable when there are only three. A model with an unstructured covariance matrix is specified as follows:

PROC MIXED DATA=combine COVTEST NOCLPRINT;
   CLASS id time;
   MODEL anti=dpov dself mpov mself time black hispanic
         childage married gender momage momwork / SOLUTION;
   REPEATED time / SUBJECT=id TYPE=UN;
RUN;

On the REPEATED statement, the TIME variable is optional as long as everyone has the same number of time points and they are in the same order. UN stands for unstructured. The output from this program (not shown) has both coefficients and standard errors that differ slightly from those in Output 2.23, but with no appreciable change in the p-values.^[]

^[] Another, similar approach is to modify the program that produced Output 2.23 by specifying the EMPIRICAL option on the PROC statement. This produces robust standard errors and test statistics using the method of White (1980), which allows for heterogeneous variances and unstructured correlations.