4.6. A Hybrid Approach

As we saw with linear models and logistic models, it's possible to combine the fixed effects and random effects approaches to get some of the virtues of each. As before, the first step is to calculate the mean of each time-varying predictor variable for each individual, and then calculate the deviations from those means:

PROC SORT DATA=patents2;
   BY id;
PROC MEANS DATA=patents2 NWAY NOPRINT;
   CLASS id;
   VAR rd_0-rd_5;
   OUTPUT OUT=means MEAN=mrd_0 mrd_1 mrd_2 mrd_3 mrd_4 mrd_5;
DATA patcomb;
   MERGE patents2 means;
   BY id;
   drd_0=rd_0-mrd_0;
   drd_1=rd_1-mrd_1;
   drd_2=rd_2-mrd_2;
   drd_3=rd_3-mrd_3;
   drd_4=rd_4-mrd_4;
   drd_5=rd_5-mrd_5;
RUN;

The next step is to run a regression model with both the deviations and the means as predictor variables. To do this correctly, it's important to use an estimation method that allows for dependence among the multiple observations for each individual. The simplest approach is GEE with PROC GENMOD:

PROC GENMOD DATA=patcomb;
   CLASS id t;
   MODEL patent= drd_0-drd_5 mrd_0-mrd_5 t / DIST=NB;
   REPEATED SUBJECT=id / TYPE=MDEP(4) CORRW;
   CONTRAST 'FE VS. RE' drd_0 1 mrd_0 −1,drd_1 0 mrd_1 −1,
             drd_2 1 mrd_2 −1, drd_3 1 mrd_3 −1,drd_4 1 mrd_4 −1,
             drd_5 1 mrd_5 −1;
RUN;

Here I've specified a negative binomial distribution with an MDEP correlation structure. The CONTRAST statement produces a chi-square test of the null hypothesis that all the deviation coefficients are equal to all the corresponding mean coefficients.

Results are in Output 4.16. The coefficients for the deviation variables can be interpreted as if they were fixed effects estimates in the sense that they control for all stable covariates. In fact, they are quite close to the fixed effects coefficients of the R & D variables in Output 4.12. However, the GEE standard error estimates are somewhat larger than those from the unconditional fixed effects method. The coefficients for the means are generally quite different from the deviation coefficients, although none is statistically significant. Under the GEE and random effects models of the last section, the deviation and mean coefficients should be the same. The chi-square test of that assumption, reported at the end of the output, indicates that there is marginal evidence for rejection.

The alternative to GEE is to implement the hybrid method in the context of a random effects model. Here's the PROC NLMIXED code for doing that, with results in Output 4.17:

PROC NLMIXED DATA=patcomb;
lambda=EXP(int+d0*drd_0+d1*drd_1+d2*drd_2+d3*drd_3+d4*drd_4+
   d5*drd_5+m0*mrd_0+m1*mrd_1+m2*mrd_2+m3*mrd_3+m4*mrd_4+m5*mrd_5
   +t1*(t EQ 1)+t2*(t EQ 2)+t3*(t EQ 3)+t4*(t EQ 4)+alpha);
   MODEL patent~NEGBIN(theta,(theta/(lambda+theta)));
   RANDOM alpha~NORMAL(0,s2) SUBJECT=id;
   PARMS int=1 d0=0 d1=0 d2=0 d3=0 d4=0 d5=0 m0=0 m1=0
         m2=0 m3=0 m4=0 m5=0 t1=0 t2=0 t3=0 t4=0 s2=1 theta=1;
RUN;

The coefficients for the deviation scores, along with their standard errors, are remarkably close to the fixed effects estimates in Output 4.12. This suggests that the random effects hybrid approach may be superior to GEE in replicating fixed effects results (as we found for logistic models in chapter 3), but beware. While PROC GENMOD took about a fifth of a second to run the GEE model, PROC NLMIXED took seven minutes to estimate the random effects model. For both of these methods I could also have included time-invariant variables like SCIENCE. I did not do so in order to maximize comparability with the fixed effects results.