Appendix: Code for Select Examples
Code for the First Example in Chapter 1
Code for the Classification Panel Example in Chapter 5
Code for the Survival Plot Example in Chapter 5
Code for the Axis Customization Example in Chapter 7
Code for the First Example in Chapter 1
The following code produces the output shown in Figure 1.1:
/*--WORK.CARMEANS--*/
proc means data=sashelp.cars noprint;
class type;
var mpg_city mpg_highway;
output out=carmeans
mean=mean_city mean_highway
lclm=lcl_city lcl_highway
uclm=ucl_city ucl_highway;
run;
data carmeans;
set carmeans(where=(_type_=1));
drop _type_;
format mean_city mean_highway lcl_city lcl_highway ucl_city
ucl_highway 3.0;
label mean_city='City';
label mean_highway='Hwy';
label lcl_city='CityLCL';
label ucl_city='CityUCL';
label lcl_highway='HwyLCL';
label ucl_highway='HwyUCL';
label _freq_='Count';
run;
proc print data=carmeans noobs label;
run;
Code for the Classification Panel Example in Chapter 5
The following code produces the Work.Mystock data set that is used for the classification panel example shown in Figure 5.2. Copy, paste, and run this code in the SAS session before performing the example:
data mystock;
set sashelp.stocks;
format date date.;
where stock in ("Microsoft" "Intel") and
(date >= "01jan2005"d);
run;
Code for the Survival Plot Example in Chapter 5
The following code produces the Work.Survivalplotdata data set that is used for the survival plot example shown in Figure 5.6. Copy, paste, and run this code in the SAS session before performing the example:
proc format;
value risk 1='ALL' 2='AML-Low Risk' 3='AML-High Risk';
run;
data BMT;
input Group T Status @@;
format Group risk.;
label T='Disease Free Time';
datalines;
1 2081 0 1 1602 0 1 1496 0 1 1462 0 1 1433 0
1 1377 0 1 1330 0 1 996 0 1 226 0 1 1199 0
1 1111 0 1 530 0 1 1182 0 1 1167 0 1 418 1
1 383 1 1 276 1 1 104 1 1 609 1 1 172 1
1 487 1 1 662 1 1 194 1 1 230 1 1 526 1
1 122 1 1 129 1 1 74 1 1 122 1 1 86 1
1 466 1 1 192 1 1 109 1 1 55 1 1 1 1
1 107 1 1 110 1 1 332 1 2 2569 0 2 2506 0
2 2409 0 2 2218 0 2 1857 0 2 1829 0 2 1562 0
2 1470 0 2 1363 0 2 1030 0 2 860 0 2 1258 0
2 2246 0 2 1870 0 2 1799 0 2 1709 0 2 1674 0
2 1568 0 2 1527 0 2 1324 0 2 957 0 2 932 0
2 847 0 2 848 0 2 1850 0 2 1843 0 2 1535 0
2 1447 0 2 1384 0 2 414 1 2 2204 1 2 1063 1
2 481 1 2 105 1 2 641 1 2 390 1 2 288 1
2 421 1 2 79 1 2 748 1 2 486 1 2 48 1
2 272 1 2 1074 1 2 381 1 2 10 1 2 53 1
2 80 1 2 35 1 2 248 1 2 704 1 2 211 1
2 219 1 2 606 1 3 2640 0 3 2430 0 3 2252 0
3 2140 0 3 2133 0 3 1238 0 3 1631 0 3 2024 0
3 1345 0 3 1136 0 3 845 0 3 422 1 3 162 1
3 84 1 3 100 1 3 2 1 3 47 1 3 242 1
3 456 1 3 268 1 3 318 1 3 32 1 3 467 1
3 47 1 3 390 1 3 183 1 3 105 1 3 115 1
3 164 1 3 93 1 3 120 1 3 80 1 3 677 1
3 64 1 3 168 1 3 74 1 3 16 1 3 157 1
3 625 1 3 48 1 3 273 1 3 63 1 3 76 1
3 113 1 3 363 1
;
run;
ods graphics on;
/*--Get survival plot data from LIFETEST procedure--*/
ods output Survivalplot=SurvivalPlotData;
proc lifetest data=BMT plots=survival(atrisk=0 to 2500 by 500);
time T * Status(0);
strata Group / test=logrank adjust=sidak;
run;
Code for the Axis Customization Example in Chapter 7
The following code produces the Work.Cars data set that is used for the axis customization example shown in Figure 7.8. Copy, paste, and run this code in the SAS session before performing the example:
data cars;
set sashelp.cars;
label MPG_City="Mean MPG";
run;