If you're a developer who's new to VBA, you might be confused by the coding environment. The Code window has two combo boxes, shown in Figure 9.1. The combo box on the left lists objects. For a form or report, the list includes all its objects; for a module, which has no objects, only (General) appears.

Figure 9.1. The Code window with the Object combo box.

The combo box on the right lists all the event procedures associated with a particular object. Figure 9.2 shows all the event procedures associated with a command button. Notice that the Click event is the only one that appears in bold because it's the only event procedure that has been coded.

Figure 9.2. The Code window with the Procedure combo box.

As you become more advanced with VBA, you can create libraries of VBA functions and subroutines. When you're viewing a call to a particular subroutine or function, you usually want to view the code behind that function. Fortunately, VBA gives you a quick and easy way to navigate from procedure to procedure. Assume that the following code appears in your application:

Private Sub cmdOkay_Click()
    Dim iAgeInTen As Integer
    If IsNull(Me!txtName) Or IsNull(Me!txtAge) Then
        MsgBox "You must fill in name and age"
        Exit Sub
    Else
        MsgBox "Your Name Is: " & Me!txtName & " and Your Age Is: " & Me!txtAge
        Call EvaluateAge(Val(Me!txtAge))
        iAgeInTen = AgePlus10(Fix(Val(Me!txtAge)))
        MsgBox "In 10 Years You Will Be " & iAgeInTen
    End If
End Sub

Say you want to quickly jump to the procedure called EvaluateAge so that you can take a better look at it. All you need to do is place your cursor anywhere within the call to EvaluateAge and then press Shift+F2. This immediately moves you to the EvaluateAge procedure. Ctrl+Shift+F2 takes you back to the routine you came from (in this case, cmdOkay_Click). This procedure works for both functions and subroutines.

Often, you name a variable only to decide later that you want to change the name. VBA comes with an excellent find-and-replace feature to help you with this change. You can simply search for data, or you can search for a value and replace it with some other value. To invoke the Find dialog box, shown in Figure 9.3, choose Edit | Find or use Ctrl+F.

Figure 9.3. The Find dialog box is set up to search for typCompanyInfo in the current module.

Type the text you want to find in the Find What text box. Notice that you can search in the Current Procedure, Current Module, Current Database, or Selected Text. The option Find Whole Word Only doesn't find the text if it's part of another piece of text. For example, if you check Find Whole Word Only, then search for “Count,” VBA doesn't find “Counter.” Other options include toggles for case sensitivity and pattern matching.

You use the Replace dialog box to search for text and replace it with another piece of text. (See Figure 9.4.) It offers all the features of the Find dialog box, but also allows you to enter Replace With text. In addition, you can select Replace or Replace All. Replace asks for confirmation before each replacement, but Replace All replaces text without this prompt. I recommend you take the time to confirm each replacement because it's all too easy to miscalculate the pervasive effects of a global search-and-replace.

Figure 9.4. The Replace dialog box is set to find typCompanyInfo and replace it with typCompanyInformation in the current module.

A very useful but little-known feature of VBA is getting context-sensitive help while coding. With your cursor placed anywhere in a VBA command or function, press the F1 key to get context-sensitive help on that command or function. Most of the help topics let you view practical examples of the function or command within code. Figure 9.5 shows help on the With...End With construct. Notice that the Help window includes the syntax for the command, a detailed description of each parameter included in the command, and remarks about using the command. At the top of the window, you can see hypertext links to related topics (See Also), as well as a link to an example of using the With...End With construct. If you click on Example, a specific example of the construct appears that you can copy and place into a module. (See Figure 9.6.) This feature is a great way to learn about the various parts of the VBA language.

Figure 9.5. Help on With...End With.

Figure 9.6. An example of With...End With.

The VBA Code window can be split so that you can look at two routines in the same module at the same time. This option is useful if you're trying to solve a problem involving two procedures or event routines in a large module. An example of a split Code window is shown in Figure 9.7. To split your Code window, choose Window | Split.

Figure 9.7. A split Code window lets you view two routines.

Notice the splitter. By placing your mouse cursor on the gray splitter button just above the Code window's vertical scrollbar and clicking and dragging, you can size each half of the window. The window can be split into only two parts. After it has been split, you can use the Object and Procedure drop-down lists to navigate to the procedure of your choice.

Another way to view multiple routines at the same time is to work in Full Module view (briefly discussed in Chapter 8). You use it to view all the code in a module as though you were in a normal text editor. To activate Full Module view so that it appears automatically each time you open a Code window, choose Tools | Options. Click on the Module tab, then place an × in the Full Module View checkbox under Window Settings. This global setting affects all the modules in all your databases, but can be changed at any time.

Full Module view has a slightly different effect than splitting a Code window does. Full Module View allows you to view multiple contiguous code routines, but splitting the Code window lets you view two nonconsecutive routines in the same module.

The Access 97 coding environment allows you to create placemarkers—called bookmarks—so that you can easily return to key locations in your modules. To add a bookmark, right-click on the line of code where the bookmark will be placed and choose Toggle | Bookmark or either Bookmarks | Bookmark from the Edit menu. You can add as many bookmarks as you like.

To navigate between bookmarks, choose Edit | Bookmarks | Next Bookmark or Edit | Bookmarks | Previous Bookmark. A bookmark is a toggle; to remove one, you simply choose Toggle | Bookmark from the shortcut menu or Bookmarks | Bookmark from the Edit menu. If you want to clear all bookmarks, choose Edit | Bookmarks | Clear All Bookmarks. All bookmarks are automatically removed when you close the database.

You declare a user-defined type by using a Type statement that must be placed in the module's Declarations section. Types can be declared as Public or Private, but types can't be placed in Form or Report modules.

A Type variable is an instance of the type in memory; it must be declared before you can use the type. To declare a Type variable, create a Local, Private, Module-Level, or Public variable based on the type. Depending on where you place this declaration and how you declare it (Dim, Private, or Public), you determine its scope. The same rules for any other kind of variable apply to Type variables. The Dim statement in the code that follows creates a variable called typTimeCardData. If you place this Dim statement in the module's General section, it's visible to all routines in that module. If you place it in a subroutine or function, it's local to that particular routine:

Dim typTimeCardData As TimeCardInfo

After a Type variable has been declared, you can store data into each of its elements. The following code stores information from the frmTimeCardHours form into a Type variable called typTimeCardData, declared in basDataHandling:

Private Sub cmdWriteToType_Click()
   Dim typTimeCardData As TimeCardInfo
   typTimeCardData.TimeCardDetailID = Me!TimeCardDetailID
   typTimeCardData.TimeCardID = Me!TimeCardID
   typTimeCardData.DateWorked = Me!DateWorked
   typTimeCardData.ProjectID = Me!ProjectID
   typTimeCardData.WorkDescription = Me!WorkDescription
   typTimeCardData.BillableHours = Me!BillableHours
   typTimeCardData.BillingRate = Me!BillingRate
   typTimeCardData.WorkCodeID = Me!WorkCodeID
End Sub

The code for this chapter can be found in the CHAP9EX.MDB database on the book's CD-ROM. The advantage of this code is that rather than creating eight variables to store these eight pieces of related information, it creates one variable with eight elements. This method keeps things nice and neat.

To retrieve information from your Type variable, simply refer to its name, followed by a period, then the name of the element. The following code displays a message box containing all the time-card hour information:

Private Sub cmdDisplayFromType_Click()
   MsgBox "Timecard Detail ID Is " & typTimeCardData.TimeCardDetailID & Chr(13) & _
         "Timecard ID Is " & typTimeCardData.TimeCardID & Chr(13) & _
         "Date Worked Is " & typTimeCardData.DateWorked & Chr(13) & _
         "Project ID Is " & typTimeCardData.ProjectID & Chr(13) & _
         "Work Description Is " & Trim(typTimeCardData.WorkDescription) & Chr(13) _
          & _
         "Billable Hours Is " & typTimeCardData.BillableHours & Chr(13) & _
         "Billing Rate Is " & typTimeCardData.BillingRate & Chr(13) & _
         "Workcode ID Is " & typTimeCardData.WorkCodeID
End Sub

As mentioned, a Symbolic constant is declared by using the Const keyword. A constant can be declared in a subroutine or function or in the General section of a Form or Report module. Unlike in previous versions of Access, constants can be strong-typed in Access 97. The naming convention for constants is to use a suitable scoping prefix, the letter c to indicate you're working with a constant rather than a variable, and then the appropriate tag for the data type. The declaration and use of a Private constant would look like this:

Private Const mccurTaxRate As Currency = .0875

This code, when placed in a module's Declarations section, creates a Private constant called mccurTaxRate and sets it equal to .0875. Here's how the constant is used in code:

Function TotalAmount(curSaleAmount As Currency)
   TotalAmount = curSaleAmount * mccurTaxRate
End Function

This routine multiplies the curSaleAmount, received as a parameter, by the constant mccurTaxRate. It returns the result of the calculation by setting the function name equal to the product of the two values. The advantage of the constant in this example is that the code is more readable than TotalAmount = curSaleAmount * .0875 would be.

Scoping Symbolic Constants

Just like regular variables, user-defined constants have scope. In the preceding example, you created a Private constant. The following statement, when placed in a module's Declarations section, creates a Public constant:

Public Const pccurTaxRate = 0.0875 As Currency

Because this constant is declared as Public, it can be accessed from any subroutine or function (including event routines) in your entire application. To better understand the benefits of a Public constant, say you have many functions and subroutines all making reference to the constant pccurTaxRate. Imagine what would happen if the tax rate were to change. If you hadn't used a constant, you would need to search your entire application, replacing the old tax rate with the new tax rate. However, because your Public constant is declared in one place, you can easily go in and modify the one line of code where this constant is declared.

Note

By definition, the value of constants can't be modified at runtime. If you try to modify the value of a constant, you get this VBA compiler error:

Variable Required—can't assign to this expression

Figure 9.9 illustrates this message box. You can see that an attempt was made to modify the value of the constant called pccurTaxRate, which resulted in a compile error.

Figure 9.9. Trying to modify the value of a constant.

If you need to change the value at runtime, you should consider storing the value in a table rather than declaring it as a constant. You can read the value into a variable when the application loads, then modify the variable if necessary. If you choose, you can write the new value back to the table.

Microsoft Access declares a number of intrinsic constants that can be used in Code, Form, and Report modules. Because they're reserved by Microsoft Access, you can't modify their values or reuse their names; however, they can be used at any time without being declared.

You should use intrinsic constants whenever possible in your code. Besides making your code more readable, they make your code more portable to future releases of Microsoft Access. Microsoft might change the value associated with a constant, but it isn't likely to change the constant's name. All intrinsic constants appear in the Object Browser; to activate it, simply click the Object Browser tool on the Visual Basic toolbar. To view the constants that are part of the VBA language, select VBA from the Object Browser's Project/Library drop-down list. Click Constants in the Classes list box, and a list of those constants are displayed in the “Members of 'Constants'” list box. (See Figure 9.10.)

Figure 9.10. Using the Object Browser to view intrinsic constants.

In the list shown in Figure 9.10, all the constant names begin with vb. All VBA constants are prefixed with vb, all Data Access Object constants are prefixed with db, and all constants that are part of the Access language are prefixed with ac. To view the Access language constants, select Access from the Project/Library drop-down list and Constants from the Classes list box. To view the Data Access Object constants, select DAO from the Project/Library drop-down list. The constants are categorized by their function into various classes (for example, DAOCollatingOrderConstants, DAOCursorDriverConstants). Select the appropriate class from the Classes list box, and its members appear in the “Members of…” list box.

Another way to view constants is within the context of the parameter you're working with in the Code window. Right-click after the name of a parameter and select List Constants to display the constants associated with the parameter. This feature is covered in detail in Chapter 8.

When declaring a fixed array, you give VBA the upper bound and the type of data it will contain. The following code creates an array that holds six string variables:

Dim astrNames(5) As String

Fixed means that this array's size can't be altered at runtime. The following code gives an example of how you can loop through the array:

Sub FixedArray()
    Dim astrNames(5) As String
    Dim intCounter As Integer
    astrNames(0) = "Dan"
    astrNames(1) = "Reggie"
    astrNames(2) = "Alexis"
    astrNames(3) = "Joshua"
    For intCounter = 0 To UBound(astrNames)
        Debug.Print astrNames(intCounter)
    Next intCounter
End Sub

This code starts by storing values into the first four elements of a six-element array. It then loops through each element of the array, printing the contents. Notice that the For...Next loop starts at zero and goes until the upper bound of the array, which is (5). Because the array is made up of strings, the last two elements of the array contain zero-length strings. If the array were composed of integers, the last two elements would contain zeros.

Another way to traverse the array is to use the For Each...Next construct. Your code would look like this:

Sub ArrayWith()
    Dim astrNames(5) As String
    Dim intCounter As Integer
    Dim vntAny As Variant
    astrNames(0) = "Dan"
    astrNames(1) = "Reggie"
    astrNames(2) = "Alexis"
    astrNames(3) = "Joshua"
    For Each vntAny In astrNames
        Debug.Print vntAny
    Next vntAny
End Sub

This code declares a Variant variable called vntAny. Instead of using a loop with Ubound as the upper delimiter to traverse the array, the example uses the For Each...Next construct.

Often, you don't know how many elements your array needs. In this case, you should consider declaring a dynamic array, which can be resized at runtime. Using this type of array can make your code more efficient because VBA preallocates memory for all elements of a fixed array, regardless of whether data is stored in each of the elements. However, if you aren't sure how many elements your array will contain, preallocating a huge amount of memory can be quite inefficient.

To create a dynamic array, you declare it without assigning an upper bound. You do this by omitting the number between the parentheses when declaring the array, as shown in this example:

Sub DynamicArray()
    Dim astrNames() As String
    Dim intCounter As Integer
    Dim vntAny As Variant
    ReDim astrNames(1)
    astrNames(0) = "Dan"
    astrNames(1) = "Reggie"
    For Each vntAny In astrNames
        Debug.Print vntAny
    Next vntAny
End Sub

However, there's a potential problem when you try to resize the array:

Sub ResizeDynamic()
    Dim astrNames() As String
    Dim intCounter As Integer
    Dim vntAny As Variant
    ReDim astrNames(1)
    astrNames(0) = "Dan"
    astrNames(1) = "Reggie"
    ReDim astrNames(3)
    astrNames(2) = "Alexis"
    astrNames(3) = "Joshua"
    For Each vntAny In astrNames
        Debug.Print vntAny
    Next vntAny
End Sub

You might expect that all four elements will contain data. Instead, the ReDim statement reinitializes all the elements, and only elements two and three contain values. This problem can be avoided by using the Preserve keyword. The following code behaves quite differently:

Sub ResizePreserve()
    Dim astrNames() As String
    Dim intCounter As Integer
    Dim vntAny As Variant
    ReDim astrNames(1)
    astrNames(0) = "Dan"
    astrNames(1) = "Reggie"
    ReDim Preserve astrNames(3)
    astrNames(2) = "Alexis"
    astrNames(3) = "Joshua"
    For Each vntAny In astrNames
        Debug.Print vntAny
    Next vntAny
End Sub

In this example, all values already stored in the array are preserved. The Preserve keyword brings its own difficulties, though. It can temporarily require huge volumes of memory because during the ReDim process, VBA creates a copy of the original array. All the values from the original array are copied to a new array. The original array is removed from memory when the process is complete. The Preserve keyword can cause problems if you're dealing with very large arrays in a limited memory situation.

By default, parameters in Access are passed by reference. This means that a memory reference to the variable being passed is received by the function. This process is best illustrated by an example:

Sub PassByRef()
   Dim strFirstName As String
   Dim strLastName As String
   strFirstName = "Alison"
   strLastName = "Balter"
   Call FuncByRef(strFirstName, strLastName)
   Debug.Print strFirstName
   Debug.Print strLastName
End Sub
Sub FuncByRef(strFirstParm As String, strSecondParm As String)
   strFirstParm = "Bill"
   strSecondParm = "Gates"
End Sub

You might be surprised that the Debug.Print statements found in the subroutine PassByRef print "Bill" and "Gates". This is because strFirstParm is actually a reference to the same location in memory as strFirstName, and strSecondParm is a reference to the same location in memory as strLastName. This violates the concepts of black-box processing, in which a variable can't be changed by any routine other than the one it was declared in. The following code eliminates this problem:

Sub PassByVal()
   Dim strFirstName As String
   Dim strLastName As String
   strFirstName = "Alison"
   strLastName = "Balter"
   Call FuncByVal(strFirstName, strLastName)
   Debug.Print strFirstName
   Debug.Print strLastName
End Sub
Sub FuncByVal(ByVal strFirstParm As String, ByVal strSecondParm As String)
   strFirstParm = "Bill"
   strSecondParm = "Gates"
End Sub

This FuncByVal subroutine receives the parameters by value. This means that only the values in strFirstName and strLastName are passed to the FuncByVal routine. The strFirstName and strLastName variables, therefore, can't be modified by the FuncByVal subroutine. The Debug.Print statements print "Alison" and "Balter".

Although I try to avoid passing parameters by reference, sometimes it makes good sense to do so. Take a look at the following example:

Sub GoodPassByRef()
   Dim blnSuccess As Boolean
   Dim strName As String
   strName = "Microsoft"
   blnSuccess = GoodFunc(strName)
   Debug.Print blnSuccess
End Sub
Function GoodFunc(strName As String)
   If Len(strName) Then
      strName = UCase$(strName)
      GoodFunc = True
   Else
      GoodFunc = False
   End If
End Function

In essence, the GoodFunc function needs to return two values. Not only does the function need to return the uppercase version of the string passed to it, but it also needs to return a success code. Because a function can return only one value, you need to be able to modify the value of strName within the function. As long as you're aware of what you're doing and why you're doing it, there's no problem with passing a parameter by reference.

Access 97 allows you to use optional parameters. In other words, it isn't necessary to know how many parameters will be passed. The ReturnInit function in the following code receives the second two parameters as optional, then evaluates whether the parameters are missing and responds accordingly:

Function ReturnInit(ByVal strFName As String, _
       Optional ByVal strMI, Optional ByVal strLName)
   If IsMissing(strMI) Then
      strMI = InputBox("Enter Middle Initial")
   End If
   If IsMissing(strLName) Then
      strLName = InputBox("Enter Last Name")
   End If
   ReturnInit = strLName & "," & strFName & " " & strMI
End Function

This function could be called as follows:

strName = ReturnInit("Bill",,"Gates")

As you can see, the second parameter is missing. Rather than causing a compiler error, as in earlier versions of Access, this code compiles and runs successfully. The IsMissing function, built into Access, determines whether a parameter has been passed. After identifying missing parameters, you must decide how to handle the situation in code. In the example, the function prompts for the missing information, but here are some other possible choices:

The following two examples illustrate how to carry out these two alternatives:

Function ReturnInit2(ByVal strFName As String, _
       Optional ByVal strMI, Optional ByVal strLName)
   If IsMissing(strMI) Then
      strMI = "B"
   End If
   If IsMissing(strLName) Then
      strLName = "Jones"
   End If
   ReturnInit2 = strLName & "," & strFName & " " & strMI
End Function

This example uses a default value of "B" for the middle initial and a default last name of "Jones". Now take a look at Listing 9.2, which illustrates another method of handling missing parameters.

Function ReturnInit3(ByVal strFName As String, _
       Optional ByVal strMI, Optional ByVal strLName)
   Dim strResult As String
   If IsMissing(strMI) And IsMissing(strLName) Then
      ReturnInit3 = strFName
   ElseIf IsMissing(strMI) Then
      ReturnInit3 = strLName & ", " & strFName
   ElseIf IsMissing(strLName) Then
      ReturnInit3 = strFName & " " & strMI
   Else
      ReturnInit3 = strLName & "," & strFName & " " & strMI
   End If
End Function

This example manipulates the return value, depending on which parameters it receives. If neither optional parameter is passed, just the first name displays. If the first name and middle initial are passed, the return value contains the first name followed by the middle initial. If the first name and last name are passed, the return value contains the last name, a comma, and the first name. If all three parameters are passed, the function returns the last name, a comma, a space, and the first name.

In all the examples you've seen so far, the parameters to a procedure have been supplied positionally. Named parameters allow you to supply parameters without regard for their position, which is particularly useful with procedures that receive optional parameters. Take a look at this example:

strName = ReturnInit("Bill",,"Gates")

Because the second parameter isn't supplied, and the parameters are passed positionally, a comma must be used as a placemarker for the optional parameter. This requirement can become unwieldy when you're dealing with several optional parameters. The following example greatly simplifies the process of passing the parameters and also better documents what's happening:

strName = ReturnInit3(strFName:= "Bill",strLName:= "Gates")

When parameters are passed by name, it doesn't even matter in what order the parameters appear, as shown in the following example:

strName = ReturnInit3(strLName:= "Gates",strFName:="Bill")

This call to the ReturnInit3 function yields the same results as the call to the function in the previous example.

The Property Let routine defines a property procedure that assigns a value to a user-defined object's property. Using a Property Let is similar to assigning a value to a Public variable, but a Public variable can be written to from anywhere in the database, with little or no control over what's written to it. With a Property Let routine, you can control exactly what happens when a value is assigned to the property. Here's an example:

Property Let TextEnabled(blnEnabled As Boolean)
   Dim ctl As Control
   For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
         ctl.Enabled = blnEnabled
      End If
   Next ctl
End Property

This routine receives a Boolean parameter. It loops through each control in the controls collection, setting the Enabled property of each text box to True or False, depending on the value of the Boolean variable that was passed to it. You might be thinking this code looks just like a subroutine, and you're somewhat correct. It's a special type of subroutine that executes automatically in response to the change in a custom property's value. The following line of code causes the code in the Property Let to execute:

Me.TextEnabled = False

The value False is received as a parameter to the Property Let routine, so all the text boxes become disabled. The TextEnabled property of the form can be called from any module in the database, causing the Property Let routine to execute.

Property Let sets the value of a custom property, but Property Get defines a property procedure that retrieves a value from a user-defined object's property. This example illustrates how Property Get is used:

Property Get TextBoxValues()
   Dim ctl As Control
   For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
         TextBoxValues = TextBoxValues & ctl.Name & _
            " = " & ctl.Value & Chr(13)
      End If
   Next ctl
End Property

The Property Get routine loops through each control on the form. It retrieves the name and value of each text box, building a return value that's a concatenated string with the names and values of all the text boxes. The call to the Property Get routine looks like this:

MsgBox Me.TextBoxValues

When the MsgBox command executes, it retrieves the value of the form's TextBoxValues property. The Property Get routine automatically executes whenever the code tries to retrieve the value of the property. This routine can be executed by retrieving the property from anywhere in the database.

Variant variables are initialized to the value of Empty. Often, you need to know whether a value has been stored in a Variant variable. If a Variant has never been assigned a value, its value is Empty. As mentioned, the Empty value is not the same as zero, Null, or a zero-length string.

It's important to be able to test for Empty in a runtime environment. This can be done by using the IsEmpty function, which determines whether a variable has the Empty value. The following example tests a String variable for the Empty value:

Sub StringVar()
    Dim sName As String
    Debug.Print IsEmpty(sName) 'Prints False
    Debug.Print sName = "" 'Prints True
End Sub

The Debug.Print statement prints False. This variable is equal to a zero-length string because the variable is initialized as a String variable. All String variables are initialized to a zero-length string. The next example tests a Variant variable to see whether it has the Empty value:

Sub EmptyVar()
    Dim vntName As Variant
    Debug.Print IsEmpty(vntName) 'Prints True
    vntName = ""
    Debug.Print IsEmpty(vntName) 'Prints False
    vntName = Empty
    Debug.Print IsEmpty(vntName) 'Prints True
End Sub

A Variant variable loses its Empty value when any value has been stored in it, including zero, Null, or a zero-length string. It can become Empty again only by storing the keyword Empty in the variable.

Null is a special value that indicates unknown or missing data. Null is not the same as Empty, nor is one Null value equal to another one. Variant variables can contain the special value called Null.

Often, you need to know whether specific fields or controls have ever been initialized. Uninitialized fields and controls have a default value of Null. By testing for Null, you can make sure fields and controls contain values.

If you want to make sure that all fields and controls in your application have data, you need to test for Nulls. This can be done by using the IsNull function:

Sub NullVar()
    Dim vntName As Variant
    Debug.Print IsEmpty(vntName) 'Prints True
    Debug.Print IsNull(vntName) 'Prints False
    vntName = Null
    Debug.Print IsNull(vntName) 'Prints True
End Sub

Notice that vntName is equal to Null only after the value of Null is explicitly stored in it. It's important to know not only how variables and Null values interact, but also how to test for Null within a field in your database. A field contains a Null if data hasn't yet been entered in the field and the field has no default value. In queries, you can test for the criteria "Is Null" to find all the records in which a particular field contains a Null value. When dealing with recordsets (covered in Chapter 15, “What Are Data Access Objects and Why Are They Important?”), you can also use the IsNull function to test for a Null value in a field. Here's an example:

Sub LoopProjects()
   Dim db As DATABASE
   Dim rs As Recordset
   Set db = CurrentDb
   Set rs = db.OpenRecordset("tblProjects", dbOpenDynaset)
   Do While Not rs.EOF
      Debug.Print rs![ProjectID], rs![ProjectName]
      If IsNull(rs!ProjectBeginDate) Then
        Debug.Print "Project Begin Date Contains No Value!!"
      End If
      rs.MoveNext
   Loop
End Sub

All the concepts of recordset handling are covered in Chapter 15. For now, you need to understand only that this code loops through each record in tblProjects. It uses the IsNull function to evaluate whether the ProjectBeginDate field contains a Null value. If the field does contain a Null, a warning message is printed to the Debug window:

Private Sub Form_Current()
   Dim ctl As Control
   For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
         If IsNull(ctl.Value) Then
            ctl.BackColor = 16776960
         Else
            ctl.BackColor = 16777215
         End If
      End If
   Next ctl
End Sub

The code in this example (found in the frmProjects form in CHAP9EX.MDB) loops through every control on the current form. If the control is a text box, the routine checks to see whether the value in the text box is Null. If it is, the BackColor property of the text box is set to Aqua; otherwise, it's set to White.

You should know about some idiosyncrasies of Null:

The following example shows how Null values are propagated:

Sub PropNulls()
   Dim db As DATABASE
   Dim rs As Recordset
   Set db = CurrentDb
   Set rs = db.OpenRecordset("tblProjects", dbOpenDynaset)
   Do While Not rs.EOF
      Debug.Print rs![ProjectID], rs![ProjectBeginDate] + 1
      rs.MoveNext
   Loop
End Sub

Figure 9.11 illustrates the effects of running this routine on a table in which the first and third records contain Null values. Notice that the result of the calculation is Null for those records because the Null propagated within those records.

Figure 9.11. The result of running the PropNulls routine.

Notice the difference if the value in the field is Empty:

Sub EmptyVersusNull()
   Dim db As DATABASE
   Dim rs As Recordset
   Set db = CurrentDb
   Set rs = db.OpenRecordset("tblProjects", dbOpenDynaset)
   Do While Not rs.EOF
      Debug.Print rs![ProjectID], rs![PurchaseOrderNumber] + "Hello"
      rs.MoveNext
   Loop
End Sub

In this example, the tblProjects table has four records. The PurchaseOrderNumber for the first record contains a Null; for the third record, it contains an Empty. Notice the different effects of the two values, as shown in Figure 9.12.

Figure 9.12. The result of running the EmptyVersusNull routine.

Looking at Figure 9.12, you can see that Null printed for the first record, and Hello printed for the third record.

Note

The EmptyVersusNull routine uses a numeric operator (+). As discussed, the effect of Null used in a calculation is a resulting Null. In text strings, you can use an ampersand (&) instead of a plus (+) to eliminate this problem. Figure 9.13 illustrates the same code with an ampersand to concatenate rather than add. You can see that no Null values result from the concatenation.

Figure 9.13. The result of changing plus (+) in the EmptyVersusNull routine to ampersand (&).

It's very common to create a generic routine that receives any value, tests to see whether it's Null, and returns a non-Null value. An example is the CvNulls function:

Function CvNulls(vntVar1 As Variant, vntVar2 As Variant) _
      As Variant
   CvNulls = IIf(IsNull(vntVar1), vntVar2, vntVar1)
End Function

This routine would be called as follows:

Sub TestForNull(vntSalary As Variant, vntCommission As Variant)
   Dim curTotal As Currency
   curTotal = CvNulls(vntSalary, 0) + CvNulls(vntCommission, 0)
   MsgBox curTotal
End Sub

The TestForNull routine receives two parameters: salary and commission. It adds the two values to determine the total of salaries plus commissions. Ordinarily, if the value of either parameter is Null, the expression results in Null. This problem is eliminated by the CvNulls function, which also receives two parameters. The first parameter is the variable being tested for Null; the second is the value you want the function to return if the first parameter is determined to be Null. The routine combines the Immediate If (IIf) function and the IsNull function to evaluate the first parameter and return the appropriate value.

By default, VBA compiles your code only when the code in the module changes or when a procedure in one module is called by another module. Although this default setting can dramatically speed up the compilation process, it can also leave you wondering whether you have a hidden timebomb lurking somewhere in your application.

Here's a typical scenario: You open a form, make some simple changes, save the changes, and close the form. You repeat this process for a few additional forms. You also open a couple of modules to make some equally simple changes. During the testing process, you forget to test one or more of the forms and one or more of the modules. With the Compile On Demand option set to True (its default value), errors aren't identified until the offending code is accessed.

To disable the Compile On Demand feature, choose Tools | Options. Click the Module tab and remove the check from Compile On Demand. You might notice some degradation in performance each time your code compiles, but this is time well spent.

Whether the Compile On Demand feature is on or off, the Compile Loaded Modules tool, found on the Visual Basic toolbar, compiles only loaded modules. This means that all open Access, Form, and Report modules are compiled, but the code in any closed modules, forms, and reports is not compiled. If an error is found in any open module, the compilation process terminates, an error message is displayed, and your cursor is placed on the offending line of code.

The Compile All Modules and Compile and Save All Modules features are found under the Debug menu. These menu items, when selected, compile every module in the database, regardless of whether it's open.

The Compile and Save All Modules selection takes an additional step and saves all code in the database in its fully compiled state. This procedure not only ensures that the modules compile successfully, it makes sure they're saved in their compiled state so that they don't need to be compiled again when the application is run.

In Access 97, you can customize code colors, font, size, and tab width within the coding environment. You can also specify the foreground and background colors for the Code window text, selection text, syntax error text, comment text, keyword text, and more. You can select from any of the Windows fonts and sizes for the text in the Code window. Finally, you can specify how many characters your text is indented each time the Tab key is pressed.

The coding options available to you include Auto Indent, Auto Syntax Check, Require Variable Declaration, Compile On Demand (discussed in the previous section), Auto List Members, Auto Quick Info, and Auto Data Tips. The Auto Indent feature invokes the automatic indenting of successive lines of code. This means that when you indent one line, all other lines are indented to the same position until you specify otherwise.

The Auto Syntax Check feature determines whether Access performs a syntax check each time you press Enter after typing a single line of code. Many developers find this option annoying. It's not uncommon to type a line of code and notice a typo in a previous line of code, so you want to rectify the error before you forget. You move off the incomplete line of code you're typing, only to get an error message that your syntax is incorrect. Although I find this aspect of Auto Syntax Check annoying, I would still rather identify any syntax errors sooner instead of later.

The Require Variable Declaration option is a must. If this option is turned on, all variables must be declared before they are used. This important feature, when set, places the Option Explicit line in the Declarations section of every module. You're then forced to declare all variables before they're used. Many innocent typos are identified by the compiler at compile time rather than by your users at runtime.

The Auto List Members option determines whether the List Properties/Methods and List Constants features are automatically invoked as you type code in the Code window. They help you in your coding endeavors by presenting a valid list of properties, methods, and constants. For more about these features, see Chapter 8.

The Auto Quick Info feature determines whether the syntax of a procedure or method is automatically displayed. If this option is selected, the syntax information is displayed as soon as you type a procedure or method name followed by a space, period, or opening parenthesis.

The Auto Data Tips feature is used when you're debugging. It displays the current value of a selected value when you place your mouse pointer over the variable in Break mode. This feature is discussed in Chapter 16, “Debugging: Your Key to Successful Development.”

The following event routine is used to view all the projects associated with the selected client. It illustrates the importance of the ability to work with Null values, the DoCmd object, and intrinsic constants.

Private Sub cmdProjects_Click()
On Error GoTo Err_Projects_Click
    If IsNull(Me![txtClientID]) Then
        MsgBox "Enter client information before viewing projects form."
    Else
        DoCmd.RunCommand Command:=acSaveRecord
        DoCmd.OpenForm "frmProjects", , , "[ClientID]=" & [txtClientID]
    End If
Exit_Projects_Click:
    Exit Sub
Err_Projects_Click:
    MsgBox Err.Description
    Resume Exit_Projects_Click
End Sub

The routine first invokes error handling (discussed in Chapter 17, “Handling Those Dreaded Runtime Errors”), then uses the IsNull function to test whether a ClientID has been entered. The IsNull function returns a True if the value in the txtClientID control is Null. If it is, an error message is displayed. If the txtClientID control contains a non-Null value, two methods are performed on the DoCmd object.

The first method performed on the DoCmd object is the RunCommand method. This method receives the constant associated with the name of the menu command you want to execute. The use of intrinsic constants makes this code more readable, and the RunCommand method makes it much easier now to call menu commands from code.

The second method performed on the DoCmd object is OpenForm, which opens the frmProjects form. Two optional parameters, View and FilterName, are omitted. The fourth parameter, the WhereCondition, is set to the ClientID that's displayed on the Client form.

Many parts of the Time and Billing application require the company information stored in the tblCompanyInfo table. It would be inefficient to read the data from this table each time the application needs it. It would be much more efficient to read this data once, when the application loads, and store it in a type structure. Because it remains in memory at all times, you can efficiently retrieve it whenever needed. The type structure is defined and a Public Type variable based on the type structure is declared in a module's Declarations section. It looks like this:

Type CompanyInfo
    SetUpID As Long
    CompanyName As String * 50
    Address As String * 255
    City As String * 50
    StateProvince As String * 20
    PostalCode As String * 20
    Country As String * 50
    PhoneNumber As String * 30
    FaxNumber As String * 30
    DefaultPaymentTerms As String * 255
    DefaultInvoiceDescription As String
End Type
Public typCompanyInfo As CompanyInfo

A subroutine is invoked when the client form (your startup form) is first loaded. This routine populates all the elements of the type structure. The routine looks like this:

Sub GetCompanyInfo()
    Dim db As DATABASE
    Dim rs As Recordset
    Set db = CurrentDb
    Set rs = db.OpenRecordset("tblCompanyInfo", dbOpenSnapshot)
    typCompanyInfo.SetUpID = rs!SetUpID
    typCompanyInfo.CompanyName = rs!CompanyName
    typCompanyInfo.Address = rs!Address
    typCompanyInfo.City = rs!City
    typCompanyInfo.StateProvince = rs!StateProvince
    typCompanyInfo.PostalCode = rs!PostalCode
    typCompanyInfo.Country = rs!Country
    typCompanyInfo.PhoneNumber = rs!PhoneNumber
    typCompanyInfo.FaxNumber = rs!PhoneNumber
    rs.Close
    db.Close
End Sub

Don't be concerned with the recordset handling included in this routine. Instead, notice that the value from each field in the first (and only) record of the tblCompanyInfo table is being loaded into the elements of the Global Type variable. Here's an example of how the Type variable is used:

Sub PopulateControls()
    txtCompanyName.Value = Trim(typCompanyInfo.CompanyName)
    txtAddress.Value = Trim(typCompanyInfo.Address)
    txtCityStateZip.Value = Trim(typCompanyInfo.City) & ", " & _
        Trim(typCompanyInfo.StateProvince) & _
        "  " & Format(Trim(typCompanyInfo.PostalCode), "!&&&&&-&&&&")
    txtPhoneFax.Value = "PHONE: " & _
        Format(Trim(typCompanyInfo.PhoneNumber), "(&&&)&&&-&&&&") & _
        "       FAX: " & _
        Format(Trim(typCompanyInfo.FaxNumber), "(&&&)&&&-&&&&")
End Sub

This routine is called by the Activate event of rptInvoice. It populates four different controls on the form with the company information retrieved from the elements of the Global Type variable.