apply plugin: 'java'
apply plugin: 'eclipse'

eclipse {
    pathVariables 'APPSERVER_HOME': file('/apps/appserver/1.0')

    project {
        name = 'sample-eclipse'

        comment = 'Eclipse project file build by Gradle'

        // Add new natures like Spring nature.
        natures 'org.springframework.ide.eclipse.core.springnature'

        // Add build command for Spring.
        buildCommand 'org.springframework.ide.eclipse.core.springbuilder'

        // If using location attribute then type 1 is file, 2 is folder
        linkedResource name: 'config', type: '2', location: file('/opt/local/config')

        // If using locationUri attribute then type 1 for file/folder, 2 is virtual folder
        linkedResource name: 'config2', type: '1', locationUri: 'file:../config'

        // Define reference to other project. This is not 
        // a build path reference.
        referencedProjects 'other-project'
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'

eclipse {
    classpath {
        // Add extra dependency configurations.
        plusConfigurations += configurations.extraLib

        // Remove dependency configurations.
        minusConfigurations += configurations.testCompile

        // Included configurations are not exported.
        noExportConfigurations += configurations.testCompile

        // Download associated source files.
        downloadSources = true

        // Download Javadoc for dependencies.
        downloadJavadoc = true

        // Add extra containers.
        containers 'ApacheCommons'

        // Change default output dir (${projectDir}/bin)
        defaultOutputDir file("$buildDir/eclipse-classes")        
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'

eclipse {
    jdt {
        sourceCompatibility = 1.6
        targetCompatibility = 1.6
    }
}

apply {
    plugin 'java'
    plugin 'eclipse'
}

eclipse {
    project {
        file { 
            beforeMerged { project ->
                // We can access the internal object structure
                // using merge hooks.
                project.natures.clear()
            }

            afterMerged { project ->
                project.name = 'sample-eclipse'

                project.comment = 'Eclipse project file build by Gradle'       
       
                project.natures.add 'org.springframework.ide.eclipse.core.springnature'

                buildCommand.add 'org.springframework.ide.eclipse.core.springbuilder'

                linkedResources.add name: 'config', type: '2', location: 'file:/opt/local'

                referencedProjects.add 'other-project'
            }
        }
    }
}

apply {
    plugin 'java'
    plugin 'eclipse'
}

eclipse {
    classpath {
        file {
            beforeMerged { classpath ->
                // Remove lib classpath entries.
                classpath.entries.removeAll {
                    it.kind == 'lib'
                }
            }

            whenMerged { classpath ->
                classpath.entries.add kind: 'output', path: "$buildDir/eclipse-classes"
            }
        }
    }

    jdt {
        file {
            beforeMerged { jdt ->
            }

            whenMerged { jdt ->
                jdt.sourceCompatibility = 1.6
                jdt.targetCompatibility = 1.6
            }

            whenProperties { properties ->
                properties.extraProperty = 'value'
            }
        }
    }
}

apply {
    plugin 'java'
    plugin 'eclipse'
}

eclipse {
    project {
        file { 
            withXml { xml ->
                def projectXml = xml.asNode()
                projectXml.name = 'sample-eclipse'

                def natures = projectXml.natures
                natures.plus {
                    nature {
                        'org.springframework.ide.eclipse.core.springnature'
                    }   
                }   
            }
        }
    }

    classpath {
        file {
            withXml { xml ->
                def classpathXml = xml.asNode()
                classpathXml.classpathentry.findAll { it.@kind == 'con' }*.@exported = 'true'
            }
        }
    }
}

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse-wtp'


eclipse {
    wtp {
        component {
            // Change context path of the Web application.
            // Default value is project.war.baseName.
            contextPath = '/sample-web'

            // Customize wb-resource elements of type WbResource.
            // Default for war plugin is 
            // [deployPath: '/', sourcePath: project.webAppDirName] and
            // for ear plugin is []
            resources += [deployPath: '/css', sourcePath: 'src/main/css']
            // We can also use the resource() method   resource deployPath: '/css', sourcePath: 'src/main/css'

            // Remove configurations from 
            // the deployed configurations.
            minusConfigurations += project.configurations.testCompile

            // Add dependency configurations to 
            // the deployLibPath location.
            libConfigurations += project.configurations.testCompile
   
            // Extra source directory.
            sourceDirs += file('src/main/css')
        }

        facet {
            // Add extra facet via property.
            facets += [name: 'extra', version: '1.0']

            // Or via facet() method.
            facet name: 'gradle', version: '1.1'
        }
    }
}

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse-wtp'

version = 1.0

description = 'Sample project'

repositories {
    mavenCentral()
}

dependencies {
    testCompile 'junit:junit:4.8'
}

eclipse {
    wtp {
        component {
            file { 
                beforeMerged { wtpComponent ->
                    wtpComponent.wbEntries.clear()
                }

                whenMerged { wtpComponent ->
                    wtpComponent.contextPath = '/sample-web'
                    wtpComponent.deployName = 'sample'
                }
            }
        }

        facet {
            file {
                beforeMerged { wtpFacet ->
                }

                whenMerged { wtpFacet ->
                    def java = wtpFacet.facets.find { it.facet == 'jst.java' }
                    java.version = '5.0'
                }
            }
        }
    }
}

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse-wtp'

version = 1.0

description = 'Sample project'

repositories {
    mavenCentral()
}

dependencies {
    testCompile 'junit:junit:4.8'
}

eclipse {
    wtp {
        component {
            file {
                withXml { componentXml ->
                    def root = componentXml.asNode()
                    root.'wb-module'.@'deploy-name' = 'sample'
                }
            }
        }

        facet {
            file {
                withXml { facetXml ->
                    def root = facetXml.asNode()
                    root.installed.find { it.@facet == 'jst.web' }.@version = '2.5'
                }
            }
        }
    }
}