Let’s connect the reflection sensor to Arduino. Prepare the cable by cutting the end that doesn’t fit to the sensor. In our case, the small white connector fit to the sensor and we left it in place. The big black connector didn’t fit anywhere, so we cut it away. Strip the free wires for connecting to Arduino (Figure 2-6).

Figure 2-6. Stripped sensor wire

Connect free sensor wires to Arduino as shown in the circuit diagram for helloreflection.pde (Figure 2-7). Connect the red plus wire to +5V, and the black ground wire to GND. Connect the green data wire to D4. (Figure 2-8). Use the ScrewShield to keep the wires in place (Figure 2-9).

Figure 2-7. Circuit diagram for helloreflection.pde

Figure 2-8. Reflection sensor connected

Figure 2-9. Free wires connected to Arduino with ScrewShield

For line avoidance, we use a typical reflectivity sensor. We read it with Arduino’s digitalRead() function.

The value tells how much light is reflected back from the surface. It returns HIGH (true, 1) for a white surface. Black doesn’t reflect light back, so the sensor gives a LOW value (false, 0).

// hellorefelection.pde - turn led on if line detected
// (c) Kimmo Karvinen & Tero Karvinen http://MindControl.BotBook.com

const int tinyLedPin=13;        // 
const int linePin=4;

void setup()
{
        pinMode(tinyLedPin, OUTPUT);
        pinMode(linePin, INPUT);
}

void loop()
{
        if (LOW == digitalRead(linePin)) {        // 
                digitalWrite(tinyLedPin, HIGH);
        } else {
                digitalWrite(tinyLedPin, LOW);
        }
        delay(20);        // 
}

Test your reflectivity sensor by holding it near white and black surfaces.

Lighting an LED is a nice way to test the sensor, but what we really want to do is turn to avoid the border. Something like this:

void loop()
{
        while (lineDetected()) turn();
        forward();
}

You already have all the knowledge to do this (in separate parts) from the previous examples, so let’s combine them. Connect the servos and reflection sensor according to the circuit diagram for avoidline.pde (Figure 2-10).

Figure 2-10. Circuit diagram for avoidline.pde

// avoidline.pde - turn when black line seen
// (c) Tero Karvinen & Kimmo Karvinen http://MindControl.BotBook.com

const int linePin=4;
const int servoLeftPin=3;
const int servoRightPin=2;

void setup()
{
        pinMode(linePin, INPUT);
        pinMode(servoLeftPin, OUTPUT);
        pinMode(servoRightPin, OUTPUT);
}

void loop()
{
        while (lineDetected()) turn();        // 
        forward();
}

bool lineDetected()
{
        return ! digitalRead(linePin);        // 
}

void forward()
{
        for (int i = 0; i < 10; i++) {
                pulseServo(servoLeftPin, 1500+500);
                pulseServo(servoRightPin, 1500-500);
        }
}

void turn()        // 
{
        for (int i = 0; i < 30; i++) { // 
                pulseServo(servoLeftPin, 1500+500);
                pulseServo(servoRightPin, 1500+500); // 
        }
}

void pulseServo(int pin, int microseconds)
{
        digitalWrite(pin, HIGH);
        delayMicroseconds(microseconds);
        digitalWrite(pin, LOW);
        delay(5);
}