Example 6.9. Placing Hyperlinks in a Report

Goal

Add hyperlinks to elements of a report so that the reader can access additional information related to the report by selecting a hyperlink.

Report

After the reader selects the “Exercise and Lipids Study” hyperlink in the upper left box of the report, the window in Figure 6.9a is presented.

After the reader selects the hyperlink associated with the “Males” class-level heading, the window in Figure 6.9b is presented.

Figure 6.9b. The Window Displayed after Selecting the Hyperlink Associated with the “Males” Class-Level Heading

[View full size image]

After the reader selects the hyperlink associated with the “Females” class-level heading, the window in Figure 6.9c is presented.

Figure 6.9c. The Window Displayed after Selecting the Hyperlink Associated with the “Females” Class Level Heading

[View full size image]

After the reader selects the hyperlink associated with the “Both Genders” summary heading, the window in Figure 6.9d is displayed.

Figure 6.9d. The Window Displayed after Selecting the Hyperlink Associated with the “Both Genders” Summary Heading

[View full size image]

Example Features

Example Overview

Example 3.3 statistically summarizes the three lipid measurements in the LIPIDS data set. It presents the descriptive statistics for the categories defined by testing period and for those defined by the combination of testing period and gender.

This example produces a report similar to the one produced by the PROC TABULATE step in Example 3.3. It illustrates how you can add hyperlinks to the body of your reports. Hyperlinks can provide your readers with a means to access further information associated with your report. The hyperlinks in this example link to files containing descriptive and detailed information about the data that was summarized.

Four hyperlinks are placed in the body of the report in these locations:

The URL attribute is added to the style formatting instruction in the $GENDER format definition and to the STYLE option in two places on the TABLE statement in the PROC TABULATE step. The value assigned to a URL attribute is the name of the file that opens when the reader selects the hyperlink.

This example specifies links to three kinds of files: a Microsoft Excel workbook, an HTML file, and a text file. The references to the Microsoft Excel workbook point to specific cells in specific sheets in the workbook.

A hyperlink to a Microsoft Excel workbook can be written in one of two ways:

The user-defined format uses ODS inline formatting and relies on the assignment of an ODS escape character before any application of the format. See Example 6.12 for a discussion of inline formatting.

Program

ods listing close;

ods escapechar='^';

ods rtf file='c:
eportsexample33c.rtf';

proc format;
  value $gender 'M'=
       "^S={url='c:
eportslipids.xls#Males!A1'
}Males"
                'F'=
  "^S={url='c:
eportslipids.xls#Females!A1'
}Females";

run;
proc tabulate data=lipids;
  title 'Exercise Program Results';
  class gender testperiod / descending
                            style={background=white};
    classlev gender testperiod /
                  style={background=white};
    var chol hdl tri / style={background=white};
    table (gender='Gender'

all="^S={url='c:
eportslipids.html'}Both Genders")*


         testperiod='Testing Period',
         all='Lipid Profile'*
         (chol='Cholesterol' hdl='HDL'
         tri='Triglycerides')*
         (n*f=3.
         (mean std='Std Dev' p25 p50 p75)*f=5.1)
         / box={label='Exercise and Lipids Study'
          style={url='c:
eportslipidsdesc.txt'
                background=white}}

         


         nocontinued;
    keyword all n mean std p25 p50 p75
            / style={background=white};

    format gender $gender.;
run;

ods rtf close;

ods listing;

Related Technique

You can also adapt the related technique in Example 3.3 to include hyperlinks to additional information. The following program uses the same PROC REPORT program with the addition of code that assigns hyperlinks to elements of the report and that formats some elements of the report. Figure 6.9e presents the output from this program.

Figure 6.9e. Output from the PROC REPORT Related Technique that Includes Hyperlinks

[View full size image]

Four hyperlinks are placed in the body of the report in these locations:

This related technique adds a text string above the GENDER and TESTPERIOD columns and associates a hyperlink with the text string.

The program includes a COMPUTE AFTER block that adds a summary line at the end of the report and associates a hyperlink with this summary text.

Instead of associating hyperlinks with the value labels of the $GENDER format as in the PROC TABULATE step in the preceding program, this program uses a CALL DEFINE statement in a COMPUTE block for the variable GENDER. The CALL DEFINE statement can place hyperlinks in cells of your report. The attribute name provided to the CALL DEFINE statement for this purpose is URL.

The same four windows that were displayed by the hyperlinks in the PROC TABULATE step and shown at the beginning of this example are also displayed when their respective hyperlinks are selected from the report produced by PROC REPORT.

The program that produced the output in Figure 6.9e follows.

ods listing close;

ods escapechar='^';

ods rtf file='c:
eportsexample33c.rtf';



proc format;
  value $gender 'M'='Males'
                'F'='Females';
run;

proc report data=lipids nowindows box
            style(headers)={background=white};

  title 'Exercise Program Results';
  column
       ("^S={url='c:
eportslipidsdesc.txt'}Exercise
        and Lipids Study" gender testperiod)
         chol,(n mean std p25 p50 p75)
         hdl,(n mean std p25 p50 p75)
         tri,(n mean std p25 p50 p75);

  define gender / group format=$gender. left id
                  descending 'Gender';
  define testperiod / group left id descending
                      'Testing Period';
  define chol / 'Cholesterol';
  define hdl / 'HDL';
  define tri / 'Triglycerides';
  define n / format=4. 'N';
  define mean / format=5.1 'Mean';
  define std / format=5.1 'Std Dev';
  define p25 / format=5.1 'P25';
  define p50 / format=5.1 'P50';
  define p75 / format=5.1 'P75';

  compute gender;

    if gender='M' then
           urllink="c:
eportslipids.xls#Males!A1";
    else if gender='F' then
           urllink="c:
eportslipids.xls#Females!A1";

     call define('gender','url',urllink);
endcomp;

compute after;

  line "^S={url='c:
eportslipids.html'}View Data for
     Both Genders";
  endcomp;
run;

ods rtf close;

ods listing;