When you run a procedure that supports ODS, SAS automatically
stores a link to each piece of ODS output in the Results folder in
the
Results window. It marks the link with
an icon that identifies the output destination that created the output.
In the following example,
SAS executes the UNIVARIATE, TABULATE, and SGPANEL procedures and
generates HTML, PowerPoint, and Rich Text Format (RTF) output.
options nodate nonumber;
proc sort data=sashelp.prdsale out=prdsale;
by Country;
run;
ods html file='SalesFig–body.htm'
contents='SalesFig–contents.htm'
page='SalesFig–page.htm'
frame='SalesFig–frame.htm';
ods rtf file='odsrtf_output.rtf';
ods powerpoint file='odspp_output.ppt'
;
proc tabulate data=prdsale;
class region division prodtype;
classlev region division prodtype;
var actual;
keyword all sum;
keylabel all='Total';
table (region all)*(division all),
(prodtype all)*(actual*f=dollar10.) /
misstext=[label='Missing']
box=[label='Region by Division and Type'];
run;
title 'Actual Product Sales';
title2 '(millions of dollars)';
proc univariate data=prdsale;
by Country;
var actual;
run;
title 'Sales Figures for First Quarter by Product';
proc sgpanel data=prdsale;
where quarter=1;
panelby product / novarname;
vbar region / response=predict;
vline region / response=actual lineattrs=GraphFit;
colaxis fitpolicy=thin;
rowaxis label='Sales';
run;
ods _all_ close;
ods html;
PROC UNIVARIATE, PROC
TABULATE, and PROC SGPANEL each generate a folder in the
Results window.
Within these folders, folder for variables, BY groups, and statistics
are created. For example, PROC UNIVARIATE creates a folder name
Country for
each BY group, such as
Country=CANADA. Within
each BY group folder is a folder for each actual variable, named
ACTUAL.
Within the folder
ACTUAL there is a folder
for each statistic, such as
Moments. The
last folders, such as
Moments, contain the
output objects that the procedure creates. The output objects are
represented by the appropriate icon.
Within the folder for
each output object is a link to each piece of output. The icon next
to the link indicates which ODS destination created the output. In
this example, the Moments output was sent to the HTML, RTF. and POWEPOINT
destinations.
The
Results window
in the display that follows shows the folders and output objects that
the UNIVARIATE, TABULATE, and SGPANEL procedures creates.
Display 34.16 View of the Results Window