Chapter 7 Analysis of Covariance

7.1 Introduction

7.2 A One-Way Structure

7.2.1 Covariance Model

7.2.2 Means and Least-Squares Means

7.2.3 Contrasts

7.2.4 Multiple Covariates

7.3 Unequal Slopes

7.3.1 Testing the Heterogeneity of Slopes

7.3.2 Estimating Different Slopes

7.3.3 Testing Treatment Differences with Unequal Slopes

7.4 A Two-Way Structure without Interaction

7.5 A Two-Way Structure with Interaction

7.6 Orthogonal Polynomials and Covariance Methods

7.6.1 A 2×3 Example

7.6.2 Use of the IML ORPOL Function to Obtain Orthogonal Polynomial Contrast Coefficients

7.6.3 Use of Analysis of Covariance to Compute ANOVA and Fit Regression

7.1 Introduction

Analysis of covariance can be described as a combination of the methods of regression and analysis of variance. Regression models use direct independent variables—that is, variables whose values appear directly in the model—for example, the linear regression y=β₀+β₁x. Analysis of variance models use class variables—that is, the independent variable’s classifications appear in the model—for example, the one-way ANOVA model y=μ+τ_i. In more theoretical terms, ANOVA class variables set up dummy 0-1 columns in the X matrix (see Chapter 6). Analysis-of-covariance models use both direct and class variables. A simple example combines linear regression and one-way ANOVA, yielding y=μ+τ_i+βx.

Analysis of covariance uses at least two measurements on each unit: the response variable y, and another variable x, called a covariable. You may have more than one covariable. The basic objective is to use information about y that is contained in x in order to refine inference about the response. This is done primarily in three ways:

❏ In all applications, variation in y that is associated with x is removed from the error variance, resulting in more precise estimates and more powerful tests.

❏ In some applications, group means of the y variable are adjusted to correspond to a common value of x, thereby producing an equitable comparison of the groups.

❏ In other applications, the regression of y on x for each group is of intrinsic interest, either to predict the effect of x on y for each group, or to compare the effect of x on y among groups.

Textbook discussions of covariance analysis focus on the first two points, with the main goal of establishing differences among adjusted treatment means. By including a related variable that accounts for substantial variation in the dependent variable of interest, you can reduce error. This increases the precision of the model parameter estimates. Textbooks discuss separate slopes versus common slope models—that is, covariance models with a separate regression slope coefficient for each treatment group, versus a single slope coefficient for all treatment groups. In these discussions, the main role of the separate slope model is to test for differences in slopes among the treatments. Typically, this test should be conducted as a preliminary step before an analysis of covariance, because, aside from carefully defined exceptions, the validity of comparing adjusted means using the analysis of covariance requires that the slopes be homogeneous. The beginning sections of this chapter present the textbook approach to analysis of covariance

There are broader uses of covariance models, such as the study of partial regression coefficients adjusted for treatment effects. Applied to factorial experiments with qualitative and quantitative factors, covariance models provide a convenient alternative to orthogonal polynomial and related contrasts that are often tedious and awkward. Later sections of this chapter present these methods.

To give a practical definition, analysis of covariance refers to models containing both continuous variables and group indicators (CLASS variables in the GLM procedure). Because CLASS variables create less-than-full-rank models, covariance models are typically more complex and hence involve more difficulties in interpretation than regression-only or ANOVA-only models. These issues are addressed throughout this chapter.

7.2 A One-Way Structure

Analysis of covariance can be applied in any data classification whenever covariables are measured. This section deals with the simplest type of classification, the one-way structure.

7.2.1 Covariance Model

The simplest covariance model is written

$y_{ij}=\mu +{\tau }_i+\beta \left(x_{ij}-{\overline{x}}_{\mathrm{..}}\right)+{\epsilon }_{ij}$

and combines a one-way treatment structure with parameters τ_i, one independent covariate x_ij, and associated regression parameter β.

Two equivalent models are

y_ijk = β₀ + τ_i+ βx_ij + ε_ijk

where ${\beta }_0=\left(\mu -\beta {\overline{x}}_{\mathrm{..}}\right),$

y_ijk = β_0i + βx_ij+ ε_ijk

where β_0i is the intercept for the ith treatment. This expression reveals a model that represents a set of parallel lines; the common slope of the lines is β, and the intercepts are β_0i = (β₀ + τ_i). The model contains all the elements of an analysis-of-variance model of less-than-full rank, requiring restrictions on the τ_i or the use of generalized inverses and estimable functions. Note, however, that the regression coefficient β is not affected by the singularity of the X’X matrix; hence, the estimate of β is unique.

The following example, using data on the growth of oysters, illustrates the basic features of analysis of covariance. The goal is to determine

❏ if exposure to water heated artificially affects growth

❏ if the position in the water column (surface or bottom) affects growth.

Four bags with ten oysters in each bag are randomly placed at each of five stations in the cooling water canal of a power-generating plant. Each location, or station, is considered a treatment and is represented by the variable TRT. Each bag is considered to be one experimental unit. Two stations are located in the intake canal, and two stations are located in the discharge canal, one at the surface (TOP), the other at the bottom (BOTTOM) of each location. A single mid-depth station is located in a shallow portion of the bay near the power plant. The treatments are described below:

Treatment (TRT)	Station
1	INTAKE-BOTTOM
2	INTAKE-SURFACE
3	DISCHARGE-BOTTOM
4	DISCHARGE-SURFACE
5	BAY

Stations in the intake canal act as controls for those in the discharge canal, which has a higher temperature. The station in the bay is an overall control in case some factor other than the heat difference due to water depth or location is responsible for an observed change in growth rate.

The oysters are cleaned and measured at the beginning of the experiment and then again about one month later. The initial weight and the final weight are recorded for each bag. The data appear in Output 7.1.

Output 7.1 Data for Analysis of Covariance

You can address the objectives given above by analysis of covariance. The response variable is final weight, but the analysis must also account for initial weight. You can do this using initial weight as the covariate. The following SAS statements are required to compute the basic analysis:

proc glm;
   class trt;
   model final=trt initial / solution;

The CLASS statement specifies that TRT is a classification variable. The variable INITIAL is the covariate. The MODEL statement defines the model y_ij = β₀ + τ_i + βx_ij + ε_ij. Specifying the SOLUTION option requests printing of the coefficient vector.

Results of these statements appear in Output 7.2.

Output 7.2 Results of Analysis of Covariance

Consider the Type I and Type III SS (Type II and Type IV would be the same as Type III here). The Type I SS for TRT is the unadjusted treatment sum of squares. The ERROR SS for a simple analysis of variance can be reconstructed by subtracting the Type I SS from the TOTAL SS, for example,

Source	DF	SS	MS	F
TRT	4	198.407	49.602	4.642
ERROR	15	160.263	10.684
TOTAL	19	358.670

The resulting F-value indicates that p is less than .01. Thus, a simple analysis of variance leads to concluding that statistically significant treatment differences in final weight exist even when initial weights are not considered.

Now compare these results with the analysis of covariance. The Type III TRT SS is 12.089 whereas the Type I TRT SS equals the one-way ANOVA TRT SS of 198.407. The Type III TRT SS reflects differences among treatment means that have been adjusted to a common value of the covariate, INITIAL. In analysis of covariance, the TYPE III TRT SS is the adjusted treatment sum of squares; the Type I TRT SS is the unadjusted treatment sum of squares because it reflects the difference among treatment means prior to adjustment for the covariate. In this example, the unadjusted TRT SS is much larger than the adjusted one. However, the reduction in error mean squares from 10.684 to 0.302 allows an increase in the F-statistic from 4.642 in the simple analysis of variance to 10.02 in Output 7.2. The power of the test for treatment differences increases when the covariate is included because most of the error in the simple analysis of variance is due to variation in INITIAL values.

The last part of Output 7.2 contains the SOLUTION vector. In this one-factor case, the TRT estimates are obtained by setting the estimates for the last treatment (TRT 5) to 0. Therefore, the INTERCEPT estimate is the intercept for TRT 5, and the other four treatment effects are differences between each TRT and TRT 5. Because TRT 5 is the control, the output estimates, standard errors, and t-tests are for treatment versus control. Note that the means of TRT 3 and TRT 4 in the discharge canal differ from TRT 5.

The coefficient associated with INITIAL is the pooled within-groups regression coefficient relating FINAL to INITIAL. The coefficient estimate is a weighted average of the regression coefficients of FINAL on INITIAL, estimated separately for each of the five treatment groups. This coefficient estimates that a difference of 1.083 units in FINAL is associated with a one-unit difference in INITIAL.

7.2.2 Means and Least-Squares Means

A MEANS statement requests the unadjusted treatment means of all continuous (non-CLASS) variables in the model, that is, the response variable and the covariate. You can suppress printing the covariate means by using the DEPONLY option. These means are not strictly relevant to an analysis of covariance unless they are used to determine the effect of the covariance adjustment. The DUNCAN and WALLER options, among others, for multiple-comparisons tests are also available, but they are not useful here.

The LSMEANS (least-squares means) statement produces the estimates that are usually called adjusted treatment means. They are defined as

${\overline{y}}_i-\widehat{\beta }\left({\overline{x}}_{i.}-{\overline{x}}_{\mathrm{..}}\right)$, or, equivalently, ${\widehat{\beta }}_0\text{ + }{\widehat{\tau }}_{\text{i}}\text{ + }\widehat{\beta }{\overline{x}}_{\cdot \cdot }$

Consistent with the MODEL statement in the SAS statements above, this example uses the latter form. Recall that you also obtain adjusted means for the unbalanced two-way classification using the same LSMEANS statement, which is

lsmeans trt / stderr tdiff;

The TDIFF option requests LSD tests among the adjusted means. You can use the ADJUST= option to obtain alternative multiple comparison tests, depending on the relative seriousness of Type I and Type II error. These issues were discussed in more detail in Section 3.3.3. The LSMEANS and TDIFF results appear in Output 7.3.

Output 7.3 Results of Analysis of Covariance: Adjusted Treatment Means (Least-Squares Means)

The estimated least-squares means are followed by their standard errors, which are printed because of the STDERR option. The t-values and associated significance probabilities for all pairwise tests of treatment differences are printed because of the TDIFF option.

The table below shows the unadjusted and adjusted means for the response variable FINAL and the mean of the covariate, INITIAL for each treatment group:

TRT	FINAL Unadjusted Means	Adjusted Least-Squares Means	INITIAL Covariate Mean
1	34.475	30.153	29.750
2	31.650	30.117	27.175
3	30.850	32.052	24.650
4	32.225	31.504	26.425
5	25.025	30.398	20.800

Figure 7.1 illustrates the distinction between adjusted and unadjusted means. The five linear regressions for each treatment are parallel, each with a common slope. Four points appear on each regression line: the end points are the predicted values of the response variable FINAL for the minimum and maximum values of INITIAL in the data set. The other two are 1) the predicted value of FINAL at the INITIAL mean for that treatment, and 2) the predicted value of FINAL at the mean value of the covariate INITIAL for the entire data set (shown by the solid vertical line at the mean value of INITIAL = 25.76). The former are the unadjusted sample means of FINAL; the latter are the adjusted, or LS means. The light-shaded vertical lines represent the mean of the covariate INITIAL at each treatment; the light-shaded horizontal lines correspond to the unadjusted sample means.

Figure 7.1 Regressions for Five Oyster Data Treatments Showing Means and LS Means

You can see that there are large changes between the unadjusted to adjusted treatment means for the variable FINAL. These changes result from the large treatment differences in the covariable INITIAL. Apparently, the random assignment of oysters to treatments did not result in equal mean initial weights. Some treatments, particularly TRT 5, received smaller oysters than other treatments. This biases the unadjusted treatment means. Computation of the adjusted treatment means is intended to remove the bias.

Note: Although the purpose of adjusted means is to remove bias resulting from unequal covariate means among the treatments, adjusted means are not always appropriate. The basic rule is that if the covariate means themselves depend on the treatments, adjustment is likely to be misleading, whereas if there is no reason to believe covariate means depend on treatment, failing to adjust is likely to be misleading. In the oyster growth example, there is no reason initial weights of oysters should depend on TRT. Therefore, you should use adjusted means. Consider, however, a typical example in plant breeding. Plant yield is affected by the population density of the plants. Accounting for plant density is essential to reduce error variance and hence allow manageable experiments to provide adequate power and precision. However, different plant varieties have inherently different plant densities, for a number of well-known reasons. Adjusting mean yield to a common plant density would distort differences among varieties you would actually see under realistic conditions. In this case, you should use unadjusted means. However, analysis of covariance is still useful because it improves precision.

You can use ESTIMATE statements to provide further insight into the mean and LS mean. The following SAS statements illustrate treatments 1 and 2 and their difference:

estimate 'trt 1 adj mean'
     intercept 1 trt 1 0 0 0 0 initial 25.76;
estimate 'trt 2 adj mean'
     intercept 1 trt 0 1 0 0 0 initial 25.76;
estimate 'adj trt diff' trt 1 -1 0 0 0;

The overall mean of the covariable INITIAL is ${\overline{x}}_{\cdot \cdot }$ =25.76, hence ESTIMATE computes the adjusted mean adjusted mean ${\widehat{\beta }}_0\text{ + }{\widehat{\tau }}_{\text{i}}\text{ + }\widehat{\beta }(25.76).$ Because ${\widehat{\beta }}_0$ and $\widehat{\beta }{\overline{x}}_{\cdot \cdot }$ are the same for all adjusted means, the adjusted treatment difference is ${\widehat{\tau }}_{\text{1}}-{\widehat{\tau }}_2$. The unadjusted means, ${\overline{y}}_{i\cdot }$ estimate ${\beta }_0\text{+ }{\tau }_i\text{+ }\beta {\overline{x}}_{i\cdot }$ where ${\overline{x}}_{i\cdot }$ is the sample mean of the covariate for the ith treatment. Use the following ESTIMATE statements to compute the unadjusted means:

estimate 'trt 1 unadj mean'
      intercept 1 trt 1 0 0 0 0 initial 29.75;
estimate 'trt 2 unadj mean'
      intercept 1 trt 0 1 0 0 0 initial 27.175;
estimate 'unadj diff' trt 1 -1 0 0 0 initial 2.575;

For the unadjusted means, $\widehat{\beta }{\overline{x}}_{i\cdot }$ is different for each treatment, so the unadjusted treatment difference estimates ${\widehat{\tau }}_{\text{1}}-{\widehat{\tau }}_2\text{ + }\widehat{\beta }\text{(}{\overline{x}}_{\text{1}\cdot }-{\overline{x}}_{2\cdot })$. This shows how the unadjusted means are confounded with the $\widehat{\beta }{\overline{x}}_{i\cdot }.$. The results of both sets of ESTIMATE statements appear in Output 7.4.

Output 7.4 ESTIMATE Statements for Adjusted and Unadjusted Means

You can see that the apparent difference between treatments 1 and 2 in unadjusted means results from their different mean initial weights. When these are adjusted, the difference disappears. Notice that, with an equal number of observations per treatment, the standard errors of the unadjusted treatment means are equal, whereas for the adjusted means, they depend on the difference between ${\overline{x}}_{i\cdot }$ and ${\overline{x}}_{\cdot \cdot }$. As a final note, you can modify the LSMEANS statement to obtain results similar to Output 7.3, but for the unadjusted means. You use the statement

lsmeans trt / bylevel stderr tdiff;

The BYLEVEL option causes ${\overline{x}}_{i\cdot }$ to be used in place of ${\overline{x}}_{i\cdot \cdot }$ in computing the LS mean. These results are not shown, but would simply complete the results in Output 7.4 for the unadjusted means and differences.

7.2.3 Contrasts

This section illustrates comparing means with contrasts, using the oyster growth example discussed in Section 7.2.1, “Covariance Model.” The five treatments can also be looked upon as a 2×2 factorial (BOTTOM/TOPXINTAKE/DISCHARGE) plus a CONTROL. The adjusted treatment means from the analysis of covariance can be analyzed further with four orthogonal contrasts implemented by the following CONTRAST statements:

contrast 'CONTROL VS. TREATMENT' TRT -1 -1 -1 -1  4;
contrast 'BOTTOM VS. TOP'        TRT -1  1 -1  1  0;
contrast 'INTAKE VS. DISCHARGE'  TRT -1 -1  1  1  0;
contrast 'BOT/TOP*INT/DIS'       TRT  1 -1 -1  1  0;

The output that results from these statements follows the partitioning of sums of squares in Output 7.5. Note that the only significant contrast is INTAKE VS. DISCHARGE. Also, note that these are comparisons among adjusted means. If the objectives of your study compel you to define contrasts among unadjusted means, these must include the contribution from the $\widehat{\beta }{\overline{x}}_{i\cdot },$ which do not cancel out as do the $\widehat{\beta }{\overline{x}}_{\cdot \cdot }$ for the adjusted means. For example, for the first contrast above, CONTROL VS. TREATMENT, you need to include $\widehat{\beta }(-{\overline{x}}_{1\cdot }-{\overline{x}}_{2\cdot }-{\overline{x}}_{3\cdot }-{\overline{x}}_{4\cdot }+4{\overline{x}}_{5\cdot })=\widehat{\beta }(-24.85)$ and thus the required SAS statement

contrast ‘CTL V TRT UNADJUSTED’
   TRT -1 –1 –1 –1 4 INITIAL –24.85;

Notice that the significance level of the unadjusted contrast far exceeds that of the adjusted CONTROL VS. TREATMENT contrast given the large discrepancy between adjusted and unadjusted means, especially for the CONTROL, noted earlier.

Equivalent results can be obtained with the ESTIMATE statement, which also gives the estimated coefficients for the contrasts. All options for CONTRAST and ESTIMATE statements discussed in Chapter 3, “Analysis of Variance for Balanced Data,” and in Chapter 6, “Understanding Linear Models Concepts,” apply here. Although constructed to be orthogonal, these contrasts are not orthogonal to the covariable; hence, their sums of squares do not add to the adjusted treatment sums of squares.

Output 7.5 Results of Analysis of Covariance: Orthogonal Contrasts Plus an Unadjusted Example

7.2.4 Multiple Covariates

Multiple covariates are specified as continuous (non-CLASS) variables in the MODEL statement. If the CLASS variable is designated as the first independent variable, the Type I sums of squares for individual covariates can be added to get the adjusted sums of squares due to all covariates. The Type III sums of squares are the fully adjusted sums of squares for the individual regression coefficients as well as those for the adjusted treatment means.

7.3 Unequal Slopes

Section 7.2 presented analysis of covariance assuming the equal slopes model. The unequal slopes model is a natural extension of covariance analysis. Both models are usually applied to data characterized by treatment groups and one or more covariates. The unequal slopes model allows you to test for heterogeneity of slopes—that is, it tests whether or not the regression coefficients are constant over groups. The analysis in Section 7.2 assumes constant regression coefficients and is invalid if this assumption fails. You can draw valid inference from the unequal slopes model, but it requires considerable care. This section presents the test for heterogeneity of slopes and inference strategies appropriate for the unequal slopes model.

Extending the one independent variable (covariate) and one-way treatment structure used in Section 7.2, the unequal slopes analysis-of-covariance model can be written

y_ij = β_0i + β_1ix_ij + ε

where i denotes the treatment group. The hypothesis of equal slopes is

H₀: β_1i = β_1i' for all i ≠ i′

An alternate formulation of the model is

y_ij = β₀ + α_i + β₁x_ij + δ_ix_ij + ε

where β₀ and β₁ are overall intercept and slope coefficients, and α_i and δ_i are coefficients for the treatment effect on intercept and slope, respectively, thus comparing the formulations of the model, β_0i = β₀ + α_i and β_1i = β₁ + δ_i. Under the alternate formulation, the hypothesis of equal slopes becomes

H₀: δ_i = 0 for all i = 1, 2,...,t

Note that any possible intercept differences are irrelevant to both hypotheses.

Regression relationships that differ among treatment groups actually reflect an interaction between the treatment groups and the covariates. In fact, the GLM procedure specifies and analyzes this phenomenon as an interaction. Thus, if you use the following statements, the expression X*A produces the appropriate statistics for estimating different regressions of Y on X for the different values, or classes, specified by A:

proc glm;
   class a;
   model y=a x x*a / solution;

This MODEL fits the formulation y_ij = β₀ + α_i + β₁x_ij + δ_ix_ij + ε. The α_i correspond to A, β₁x_ij corresponds to X, and δ_ix_ij corresponds to X*A. In this application, the Type I sums of squares for this model provide the most useful information:

X	is the sum of squares due to a single regression of Yon X, ignoring the group.
A	is the sum of squares due to different intercepts (adjusted treatment differences), assuming equal slopes.
X*A	is an additional sum of squares due to different regression coefficients for the groups specified by the factor A.

The associated sequence of tests provides a logical stepwise analysis to determine the most appropriate model. Equivalent results can also be obtained by fitting the nested effects formulation y_ij = β_0i + β_1i + ε. Use the following statements:

proc glm;
   class a;
   model y=a x(a) / noint solution;

Here, the β_0i correspond to A, and the β_1i correspond to X(A). This formulation is more convenient than the alternative for obtaining estimates of the slopes for each treatment group. You can write a CONTRAST statement that generates a test equivalent to X*A in the previous model. However, X(A) does not test for the heterogeneity of slopes. Instead, it tests the hypothesis that all regression coefficients are 0. Also, A tests the hypothesis that all intercepts are equal to 0. For models like this one, the Type III (or Type IV) sums of squares have little meaning; it is not instructive to consider the effect of the CLASS variable over and above the effect of different regressions.

7.3.1 Testing the Heterogeneity of Slopes

This section uses the oyster growth data from Output 7.1 to demonstrate the test for the homogeneity of slopes. In a practical situation, you would do this testing before proceeding to the inference based on equal slopes shown in Section 7.2. Use the following SAS statements to obtain the relevant test statistics:

proc glm;
 class trt;
 model final=trt initial trt*initial;

Output 7.6 shows the results.

Output 7.6 Unequal Slopes Analysis of Covariance for Oyster Growth Data

The Type I sums of squares show that

❏ the INITIAL weight has an effect on FINAL weight (F=1208.03, p<0.0001)

❏ TRT has an effect on FINAL weight, at any given INITIAL weight (F=10.66, p=0.0012)

❏ there is no significant difference in the INITIAL/FINAL relationship among the different levels of TRT (F=1.22, p=0.3602). That is, there is no evidence to contradict the null hypothesis of homogeneous slopes.

The last result is especially important, as it validates the analysis using the equal slopes model. The first two results essentially reiterate the results in Section 7.2.

7.3.2 Estimating Different Slopes

In many cases, the individual regression slopes for each treatment contain useful information. Output 7.7 contains data to illustrate this. The data are from a study of the relationship between the price of oranges and sales per customer. The hypothesis is that sales vary as a function of price differences for different stores (STORE) and days of the week (DAY). The price is varied daily for two varieties of oranges. The variables P1 and P2 denote the prices for the two varieties, respectively. Q1 and Q2 are the sales per customer of the corresponding varieties.

Output 7.7 Orange Sales Data

In this example, consider the variety 1 only—that is, the response variable, sales, for variety 1 is Q1 and the covariable, price, is P1. Examples in Section 7.4 also involve variety 2. Here, you compute the unequal slopes covariance model using the SAS statements

proc glm;
 class day;
 model q1=p1 day p1*day/solution;

Output 7.7 shows the results of this analysis.

Output 7.8 Unequal Slopes Analysis of Covariance for Orange Sales Data

From Output 7.8, you can see that there is no evidence to reject the null hypothesis of equal slopes (F for P1*DAY is 1.51 and p=0.2236). Ordinarily, you would then proceed as with the oyster growth data, using an equal slopes model. The Type I results here indicate a significant effect of price (P1) on sales and a significant effects of DAY on sales at any given price. For these data, however, a closer look at the estimates of the daily regression coefficients reveals additional information. Although the differences in the daily regressions are not statistically significant, it is instructive to look at their estimates.

The estimated daily regression slope coefficients are ${\widehat{\beta }}_{1_i}={\widehat{\beta }}_1+{\widehat{\delta }}_i.$. The estimate corresponding to P1 is ${\widehat{\beta }}_1$ and P1*DAY is ${\widehat{\delta }}_i.$. For example, for DAY 1, the estimated slope is ${\widehat{\beta }}_{1_1}={\widehat{\beta }}_1+{\widehat{\delta }}_1=-1.2252+1.0047=-\mathrm{0.2205.}$. You can use ESTIMATE statements to obtain the daily regression coefficients:

estimate 'P1:DAY 1' p1 1 p1*day 1 0 0 0 0 0;
estimate 'P1:DAY 2' p1 1 p1*day 0 1 0 0 0 0;
estimate 'P1:DAY 3' p1 1 p1*day 0 0 1 0 0 0;
estimate 'P1:DAY 4' p1 1 p1*day 0 0 0 1 0 0;
estimate 'P1:DAY 5' p1 1 p1*day 0 0 0 0 1 0;
estimate 'P1:DAY 6' p1 1 p1*day 0 0 0 0 0 1;

The results appear in Output 7.9.

Output 7.9 Estimated Regression Coefficients for Each TRT

Note that these estimated coefficients are larger in absolute value toward the end of the week. This is quite reasonable given the higher level of overall sales activity near the end of the week, which may result in a proportionately larger response in sales to changes in price. Thus, it is likely that a coefficient specifically testing for a linear trend in price response during the week would be significant.

You can obtain the results in Output 7.7 more conveniently using the nested-effects formation, whose SAS statements are

proc glm;
 class day;
 model q1=day p1(day)/noint solution;
 contrast 'equal slopes' p1(day) 1 0 0 0 0 -1,
                         p1(day) 0 1 0 0 0 -1,
                         p1(day) 0 0 1 0 0 -1,
                         p1(day) 0 0 0 1 0 -1,
                         p1(day) 0 0 0 0 1 -1;

The CONTRAST statement contains one independent comparison of the daily regressions per degree of freedom among daily regressions. In this case, there are 6 days and hence 5 DF. If all five comparisons are true, then H₀: all β_1. equal must be true. Hence the contrast is equivalent to the test generated by P1*DAY in Output 7.8. Output 7.10 contains the results.

Output 7.10 Analysis of Orange Sales Data Using a Nested Covariance Model

As noted earlier, the Type I and Type III sums of squares provide no useful information. P1(DAY) tests the null hypothesis that all daily regression slopes are equal to zero. You can see that the contrast for equal slopes is identical to the equal slopes test given by P1*DAY in Output 7.8. The parameter estimate is the most useful output. You can see that the daily regression coefficients, P1(DAY), are identical to the estimates obtained via the ESTIMATE statements in Output 7.9, although Output 7.10 is easier to compute because no ESTIMATE statements are required. Output 7.9 also gives the intercept of the regressions for each day. For example, using DAY 1 and P1(DAY) 1, you can see that the regression for DAY 1 is Q1 = 18.675 – 0.2205×P1.

Using more than one independent variable is straightforward and can determine which variables have a different coefficient for each treatment group. More complex designs are not difficult to implement but may be difficult to interpret.

7.3.3 Testing Treatment Differences with Unequal Slopes

Tests among adjusted means with the equal slopes model apply to all values of the covariable. For example, Section 7.2.2 showed that the difference between the adjusted mean of TRT 1 and 2 is (β + τ₁ + β ${\overline{x}}_{\cdot \cdot }$) – (β + τ₂ + β ${\overline{x}}_{\cdot \cdot }$) = τ₁–τ₂. If you use any other value of the covariable in the expression, the difference is still τ₁–τ₂. However, for the unequal slope model, the adjusted mean is β + σ_i + β_1ix, and hence the difference depends on x. Typically is used for x. If you compare TRT 1 and 2 at ${\overline{x}}_{\cdot \cdot },$ the difference is ${\alpha }_1-{\alpha }_2+({\beta }_{1_1}-{\beta }_{1_2}){\overline{x}}_{\cdot \cdot }$. If you evaluate the treatment difference at a different value of x, the difference changes. Thus, in the unequal slopes model, you can compare treatments, but only conditional upon a specified value of the covariable.

PROC GLM and PROC MIXED offer a great deal of flexibility for unequal slopes models, but you must be careful, because some defaults do not necessarily result in sensible tests.

Output 7.11 contains the Type III sums of squares and the LS means for the unequal slopes models for the orange sales data. The SAS statements are

proc glm;
 class day;
 model q1=p1 day p1*day;
 lsmeans day;

Output 7.11 Type III SS and Default LS Means for Unequal Slopes Covariance Analysis of Orange Sales Data

The least-squares means are computed using the overall covariable mean, ${\overline{x}}_{\cdot \cdot },$ which for these data is equal to 51.222. You can use the AT MEANS option with the LSMEANS statement to print the value of the covariable means being used. The SAS statement is

lsmeans day/at means;

Output 7.12 shows the results.

Output 7.12 Least-Squares Means for Orange Sales Data Using the AT MEANS Option

Suppose you want to test the null hypothesis of equal adjusted means—that is, among the means adjusted to a common value ${\overline{x}}_{\cdot \cdot }.$. Clearly, the Type I sum of squares for DAY from Output 7.8 does not do this: it tests means for a common slope, not adjusted for P1*DAY, the differences among slopes. What about the Type III sum of squares for DAY in Output 7.11? The Type III sum of squares tests the means adjusted not to ${\overline{x}}_{\cdot \cdot }$ but to x=0. You can see this from the following CONTRAST statement:

contrast 'trt' day 1 -1 0 0 0 0,
               day 1 0 -1 0 0 0,
               day 1 0 0 -1 0 0,
               day 1 0 0 0 -1 0,
               day 1 0 0 0 0 -1;

Output 7.13 shows the results.

Output 7.13 Contrast Testing the Equality of Sales Means Adjusted to Covariable Price=0

You can see that the F=1.85 and p-value of 0.1412 are identical to the Type III SS results in Output 7.11.

You can use the following LSMEANS statement to compute adjusted means at x=0 to see what you are testing:

lsmeans day/at p1=0;

Output 7.14 shows the results.

Output 7.14 Orange Sales Adjusted Means at Price Covariable=0

Recalling Output 7.10, these adjusted means are in fact the intercepts of the separate daily regression equations. Testing makes no sense in this context, because the oranges are not going to be sold for a price P1=0—that is, they are not going to be given away.

You can test the adjusted means at ${\overline{x}}_{\cdot \cdot }$ using the following CONTRAST statement:

contrast 'trt' day 1 -1 0 0 0 0
   p1*day 51.2222 -51.2222 0 0 0 0,
    day 1 0 -1 0 0 0 p1*day 51.2222 0 -51.2222 0 0 0,
    day 1 0 0 -1 0 0 p1*day 51.2222 0 0 -51.2222 0 0,
    day 1 0 0 0 -1 0 p1*day 51.2222 0 0 0 -51.2222 0,
    day 1 0 0 0 0 -1 p1*day 51.2222 0 0 0 0 -51.2222;

This statement uses a set of independent comparisons for the unequal slopes model difference, whose form is ${\alpha }_1-{\alpha }_2+({\beta }_{1_1}-{\beta }_{1_2}){\overline{x}}_{\cdot \cdot }.$ The number of comparisons in the contrast equals the DF for DAY. Output 7.15 gives the results.

Output 7.15 Contrast to Test the Equality of Means Adjusted to Mean Covariable Price=51.22

You can change the value of the AT P1= option in the LSMEANS statement and the coefficients for P1*DAY in the above contrast to test the equality of the adjusted means at any value of the covariable deemed reasonable. Alternatively, you can center the covariable in the DATA step. For example, you can define a new covariable X=P1–51.22 and use X in place of P1 in the analysis. The default Type III sum of squares tests the equality of adjusted means at X=0, which corresponds to P1=51.22, the overall mean. The crucial thing to keep in mind with unequal slopes models is that the treatment difference changes with the covariable, so the test is only valid if it is done at a value of the covariable agreed to be reasonable.

7.4 A Two-Way Structure without Interaction

Analysis of covariance can be applied to other experimental and treatment structures. This section illustrates covariance analysis of a two-factor factorial experiment with two covariates.

This example uses the data from the study of the relationship between the price of oranges and sales per customer described in Section 7.3 and presented in Output 7.7. Recall that the data set had two varieties. The section uses only response variable Q₁, sales per customer for the first variety to illustrate the main ideas. You can easily adapt these methods to Q₂, the response variable for the second variety.

A model for the sales of oranges for variety 1 is

Q₁ = μ + τ_i + δ_j + β₁P₁ + β₂P₂ + e

where

Q1	is the sales per customer for the first variety.
τi	is the effect of the ith STORE, i = 1, 2, . . . , 6.
δj	is the effect of the jth DAY, j = 1, 2, . . . , 6.
β1	is the coefficient of the relationship between sales Q1 and P1 (the price of one variety of oranges).
β2	is the coefficient of the relationship between Q1 and P2 (the price of the other variety of oranges).
e	is the random error term.

Note that because there is no replication, the interaction between STORE and DAY must be used as the error term. In this example, the primary focus is on the influence of price, P1 and P2, and on sales, Q₁. The DAY and STORE differences are of secondary importance.

To implement the model, use following SAS statements:

proc glm;
   class store day;
   model q1 q2=store day p1 p2 / solution;
   lsmeans day / stderr;

The results appear in Output 7.16.

Output 7.16 Results of Analysis of Covariance: Two-Way Structure without Interaction

In addition to the details previously discussed, these also are of interest:

❏ The Type I SS for P1 and P2 can be summed to obtain a test for the partial contribution of both prices:

$F_{2,23}=\left[\left(622.01+39.54\right)/2\right]/\left(17.75\right)=74.54$

❏ The Type III SS show that all effects are highly significant except P2, the price of the competing orange.

❏ Each coefficient estimate is the mean difference between each CLASS variable value (STORE, DAY) and the last CLASS variable value, because there is no interaction.

❏ The P1 coefficient is negative, indicating the expected negatively sloping price response (demand function). The P2 coefficient, although not significant, has the expected positive sign for the price response of a competing product.

❏ Least-squares means are requested only for DAY, which shows the expected higher sales toward the end of the week.

Contrasts and estimates of linear functions could, of course, be requested with this analysis.

7.5 A Two-Way Structure with Interaction

The most complex covariance model discussed in this chapter is a two-factor factorial with two stages of subsampling. Output 7.17 shows data from a study whose objective is to estimate y, the weight of usable lint from x, the total weight of cotton bolls. In addition, the researcher wants to see if lint estimation is affected by varieties of cotton (VARIETY) and the distance between planting rows (SPACING), using x, the boll weight (BOLLWT), as a covariate in the analysis of y, the lint weight. The study is a factorial experiment with two levels of VARIETY (37 and 213) and two levels of SPACING (30 and 40). There are two plants for each VARIETYXSPACING treatment combination, and there are from five to nine bolls per plant (PLANT).

Output 7.17 Data for Analysis of Covariance: Two-Way Structure with Interaction

The model for the analysis is

y_ijkl = μ + v_i + τ_i + (vτ)_ij + γ(vτ)_ijk + βx_ijkl + ε_ijkl

where

yijkl	equals the weight of the lint for the ith VARIETY, jth SPACING, kth PLANT of the (i, j)th cell, and lth(i,j)boll of each plant.
μ	is the intercept.
vi	is the effect of the ith VARIETY.
τj	is the effect of the jth SPACING.
(vτ)ij	is the VARIETY×SPACING interaction.
γ(vτ)ijk	is the effect of the kth plant in the (i,j) th VARIETY and SPACING combination.
xijkl	is the total weight of each boll, the covariate.
β	is the regression effect of the covariate.
εijkl	equals the error variation among bolls within plants.

The primary focus of this study is on estimating lint weight from boll weight (that is, the regression) and only later in determining if this relationship is affected by VARIETY and SPACING factors. In the SAS program to analyze the data, the order of variables in the MODEL statement is changed so that the Type I sums of squares provide the appropriate information:

proc glm;
 class variety spacing plant;
 model lint=bollwt variety spacing variety*spacing
    plant(variety*spacing) / solution;
 random plant(variety*spacing)/test;

Note that the RANDOM statement with the TEST option has been added because the plant-to-plant variation provides the appropriate error term. Results of the analysis appear in Output 7.18.

Because PLANT(VARIETY*SPACING) is a random effect, an alternative is to use PROC MIXED. You use the following SAS statements:

proc mixed;
 class variety spacing plant;
 model lint=bollwt variety spacing
       variety*spacing/solution;
 random plant(variety*spacing);

The results for this analysis appear in Output 7.19. Littell et al. (1996) discuss analysis of covariance for mixed models in much greater detail.

Output 7.18 Results of Analysis of Covariance: Two-Way Structure with Interaction

The Type I SS for BOLLWT is what would be obtained by a simple linear regression of LINT on BOLLWT. If you ran this simple linear regression, you would get an R² value of (29.069/33.091)=0.878, a residual mean square of (33.091 29.069)/47)=0.08557, and an F-statistic of 339.69, thus indicating a strong relationship of lint weight to boll weight.

The Type III SS from the RANDOM statement with the TEST option shows a non-significant contribution from the VARIETY*SPACING interaction (F=0.74, p-value 0.4324). The VARIETY effect (F=16.27, p-value 0.0021) is statistically significant, whereas the SPACING main effect (F=5.76, p-value 0.0660) is only marginally significant. Note that the error terms for the VARIETY and SPACING main effects and interaction use linear combinations of PLANT(VARIETY*SPACING) and ERROR mean squares. This follows from the complex set of expected means squares that result in analysis of covariance.

It might seem that it would be simpler to assume from inspection of the analysis of covariance sources of variance that PLANT(VARIETY*SPACING) is the proper error term for VARIETY, SPACING, and VARIETY*SPACING and use the statement

test h=variety spacing variety*spacing
   e=plant(variety*spacing);

in place of the RANDOM statement. If you do this, the resulting test statistics will be affected and there is the possibility of drawing erroneous conclusions. Now consider the results obtained using PROC MIXED.

Output 7.19 Analysis of Covariance Results Using PROC MIXED

Compared to Output 7.18 for PROC GLM, the exact parameter estimates and F-values differ somewhat. This is partly because PROC MIXED recovers information from the random-model effects, similar to the recovery of interblock information for incomplete-blocks designs discussed in Chapter 4, and partly because the variance component estimate for PLANT(VARIETY*SPACING) is zero. MIXED’s default option for computing F-values in the presence of zero or negative variance component estimates is somewhat different than the F-ratios derived from the expected mean square by PROC GLM.

Section 4.4.2 discussed the possible bias to F-statistics that the MIXED default of setting negative variance component estimates to zero may introduce. This is especially evident in this example with the main effect test for SPACING. The p-value here is 0.0358, whereas it was 0.0660 with the GLM analysis. The MIXED result reflects potential bias. Here, as in Section 4.4.2, you can avoid this problem by using the METHOD=TYPE3 option. The results are not shown here, but they are very similar to the results in Output 7.18. Slight discrepancies result from the recovery of random-effects information present in PROC MIXED but not in PROC GLM.

Both the GLM and MIXED results suggest dropping the terms VARIETY*SPACING and PLANT(VARIETY*SPACING). The justification for VARIETY*SPACING is the same, that is, the F-test. However, with MIXED, there is no test for PLANT(VARIETY*SPACING). The zero variance component estimate provides equivalent justification. Given these results, the model has more factors than necessary; hence, their coefficient estimates are not necessary and can make further inference needlessly awkward. Drop VARIETY*SPACING and PLANT(VARIETY*SPACING), and use the following GLM statements to re-estimate:

model lint=bollwt variety spacing / solution;
lsmeans variety spacing / stderr;

You can use equivalent MIXED statements and obtain the same results. The results appear in Output 7.20. They differ only slightly from those in Outputs 7.18 and 7.19.

Output 7.20 Results of a Simplified Covariance Analysis: Two-Way Structure with Interaction

This model specifies a single regression coefficient that relates LINT to BOLLWT (0.3014), but with different intercepts for the four treatment combinations. These intercepts can be constructed from the SOLUTION vector by summing appropriate component values.

For example, for VARIETY=37, SPACING=30, the model estimate is

y = μ + v₁ + τ₁ + β_x = −.2769 + .4107 + .2052 + .3014x

For the other treatment combinations, the results are

VARIETY	SPACING	Values for Model Estimate, Where x = BOLLWT, the Covariate
37	40	0.1338 + 0.3014x
213	30	–0.0715 + 0.3014x
213	40	–0.2769 + 0.3014x

Note that these results can be obtained with ESTIMATE statements. Least-squares means appear in Output 7.20; other statistics can be obtained but are not necessary in this situation.

7.6 Orthogonal Polynomials and Covariance Methods

A standard method for analyzing treatments with quantitative levels is to decompose the treatment sum of squares using orthogonal polynomial contrasts. That is, contrasts whose coefficients measure the linear, quadratic, and higher-order regression effects associated with treatment level. Most statistical methods textbooks have tables of orthogonal polynomial coefficients for balanced data with equally spaced treatment levels. You can use the ORPOL function in PROC IML to determine coefficients when you have a design that standard tables do not cover, such as unequally spaced designs. Section 7.6.2 shows you how to use the ORPOL function.

In many practical applications, orthogonal polynomials are awkward to use. Often, you want to estimate the regression equation, not merely decide what is “significant.” Even with treatment designs covered by standard tables, extracting the regression equation from orthogonal polynomials is laborious. For factorial experiments, interest usually centers on interaction. That is, are the regressions over the quantitative factor the same for all levels of the other factor? Except for very simple factorial treatment designs, trying to use orthogonal polynomials to measure interaction can become a daunting task.

This section presents analysis-of-covariance methods that are equivalent to orthogonal polynomial contrasts. The main advantage of the covariance, or direct regression, approach is that in most cases, it is easier to implement using SAS.

7.6.1 A 2x3 Example

Output 7.21 contains data from an experiment designed to compare response to increasing dosage for two types of drug. There were three levels of the actual dosage, DOSE in the SAS data set—1, 10, and 100 units. The data were analyzed using LOGDOSE, the base 10 logs of the dosages. Note that the levels of LOGDOSE are equally spaced. The experiment was conducted as a randomized-complete-blocks design. BLOC denotes the blocks and Y denotes the response variable.

Output 7.21 Data for a Type-Dose Factorial Orthogonal Polynomial Example

The analysis of variance of these data is as follows:

SOURCE OF VARIATION	DF
Block	3
Type	1
Log Dose	2
Type × Log Dose	2
Error	15

The dose main effect can be partitioned into linear and quadratic components by orthogonal polynomials whose contrast coefficients are

		COEFFICIENT FOR LOGDOSE
CONTRAST	0	1	2
Linear	–1	0	1
Quadratic	–1	2	–1

Similarly, the Type×Log Dose interaction can be partitioned into a Linear×Type and a Quadratic×Type component. Because the log dose levels are equally spaced, you can look up the contrast coefficients shown above. Most statistical methods texts have such a table. If you don’t have a table readily available, or if you want to use contrasts for a situation not in the table, for instance partitioning DOSE rather than Log Dose into linear and quadratic components, you can use the ORPOL function in PROC IML demonstrated in Section 7.6.2.

For analysis with LOGDOSE, use the following SAS statements:

proc glm;
 class bloc type logdose;
 model y=bloc type|logdose;
 contrast 'linear logdose' logdose -1 0 1;
 contrast 'quadratic logdose' logdose -1 2 -1;
 contrast 'linear logdose x type' type*logdose 1 0 -1 -1 0 1;
 contrast 'quad logdose x type' type*logdose 1 -2 1 -1 2 -1;

Output 7.22 contains the results.

Output 7.22 Analysis of Variance for Type-Dose Data

From this output you can see that there is a significant Type×Log Dose interaction. The Linear Logdose×Type interaction explains most of the interaction. A look at the Type×Log Dose least-squares means (Output 7.23) reveals why. For Type 1, LOGDOSE does not affect mean response, whereas for Type 2, mean response increases approximately linearly with increasing LOGDOSE.

Output 7.23 Least-Squares Means for Type-Dose Data

By inspection, a linear regression for each type appears sufficient to explain the LOGDOSE effect. You can use the following SAS code to formally confirm this:

proc glm;
   class bloc type logdose;
   model y=bloc type logdose(type);
   contrast 'lin in type 1' logdose(type) 1 0 -1 0 0 0;
   contrast 'lin in type 2' logdose(type) 0 0 0 1 0 -1;
   contrast 'quad in type 1' logdose(type) 1 -2 1 0 0 0;
   contrast 'quad in type 2' logdose(type) 0 0 0 1 -2 1;

Output 7.24 shows the results.

Output 7.24 Orthogonal Polynomial Contrast Results within Each Type

You can see that neither type has a significant quadratic regression. The F-values are 0.0 and 0.72, respectively for Types 1 and 2. Type 2 does have a highly significant linear regression, as shown by the Lin In Type 2 contrast. The F-value is 15.04, and the associated p-value is 0.0015. You would then fit the linear regression equation over LOGDOSE for Type 1.

7.6.2 Use of the IML ORPOL Function to Obtain Orthogonal Polynomial Contrast Coefficients

The contrast coefficients used in the previous section are the standard orthogonal polynomial coefficients for equally spaced treatments. You can find these coefficients in tables contained in many statistical methods textbooks. Suppose, however, that you want to partition treatment effects into linear effects, quadratic effects, and so forth, but your treatment levels are not equally spaced. Or suppose that you simply don’t have convenient access to a table of standard orthogonal polynomial contrasts. The interactive matrix algebra procedure PROC IML has a function, ORPOL, that computes orthogonal polynomial contrasts for any set of quantitative treatment levels. The function is simple to use, and does not require knowledge of matrix algebra.

To illustrate the ORPOL function, suppose you want to use DOSE rather than LOGDOSE in the example in Section 7.6.1. The levels are 1, 10, and 100, which are not equally spaced so you won’t find the correct coefficients in any table. Use the following PROC IML statements:

proc iml;
 levels={1,10,100};
 coef=orpol(levels);
 print coef;

Output 7.25 shows the results. The LEVELS={level 1, level 2,...} statement defines a variable named LEVELS that contains a list of the treatment levels. Note that the treatment levels are separated by commas. The name of the variable is your choice; here it is called LEVELS, but you can give it any name you like within the conventions of allowable SAS variable names. The variable named COEF will contain the contrast coefficients; its name is your choice as well. You set it equal to the ORPOL function and put the variable with the treatment levels in parentheses. The PRINT statement causes the variable COEF to be printed.

Output 7.25 Contrast Coefficients for Unequally Spaced Levels of DOSE Using ORPOL

The first column of numbers, all 0.577, is the contrast for the mean, which is rarely, if ever, used. The second column gives you the coefficients for the linear contrasts. The third column gives you the quadratic contrast coefficients. Note that for each contrast, there is one coefficient per treatment (in this case dose) level. Also, there is one contrast per treatment degree of freedom. If you had four treatment levels, there would be four coefficients per contrast and a cubic as well as a linear and quadratic contrast.

The information from Output 7.25 allows you to write the appropriate CONTRAST statements. For example, for linear and quadratic dose effects, use the statements:

contrast ‘linear dose’ dose -0.465 -0.349 0.814;
contrast ‘quadratic dose’ dose 0.671 -0.738 0.067;

Pay attention to the sum of the contrasts. Occasionally, a rounding error will cause the sum of the coefficients to not equal zero; you might get 0.001, for example. This will cause both the GLM and MIXED procedures to declare the contrast non-estimable and you will get no output. Simply adjust one number so the coefficients sum to exactly zero. The impact of this adjustment on the resulting computations is negligible.

You can use ORPOL for equally spaced treatments. For example, add the following statements to the IML program given above to compute the coefficients for the equally spaced levels of LOGDOSE:

log_lev=log10(levels);
coef=orpol(log_lev);
print log_lev;
print coef;
fuzzed_coef=fuzz(coef);
print fuzzed_coef;

Output 7.26 shows the results. The LOG10 function takes the base 10 log of each element of the vector variable LEVELS, defined above. The name of the new variable is your choice; here it is called LOG_LEV. Occasionally, machine-rounding error causes numbers that are supposed to be zero to be computed as very small nonzero numbers, as with the coefficient for the second treatment level in the linear contrast (second column). The FUZZ function cleans up these rounding errors and sets them to zero, as shown in the variable FUZZED_COEF, the COEF variable with FUZZ applied.

Output 7.26 ORPOL Results for Equally Spaced Treatment Level (LOGDOSE)

Note that the coefficients are given the orthonormal form, that is, the squared coefficients for each contrast sum to one, for example, (–0.707)² + 0² + (0.707)² = 1 for the linear contrast (second column). You can rescale these coefficients to integer values, for example, –1, 0, and 1 for the linear contrast and 1, –2, and 1 for the quadratic, without affecting the sum of squares or F-values for the contrasts. This gives you the same coefficients you used in the previous section for LOGDOSE.

7.6.3 Use of Analysis of Covariance to Compute ANOVA and Fit Regression

In the previous sections you saw how to assess regression over treatment levels using orthogonal polynomial contrasts and how to use ORPOL to obtain the needed contrast coefficients. However, orthogonal polynomials can be awkward to use, especially when you want to estimate the regression equation in addition to merely partitioning variation for testing purposes. In practical situations, orthogonal polynomials are something of a holdover from pre-computer-era statistical analysis. You can use analysis-of-covariance methods to compute the same statistics you got using orthogonal polynomials, as well as additional statistics that are often useful. This section uses the example from Section 7.6.1 to illustrate.

You can reproduce the essential elements of the analysis in Output 7.22 using analysis-of-covariance methods. First, you need to define a new variable in the DATA step for the square of LOGDOSE. In the SAS program between, the new variable is called LOGD2, defined in the DATA step as LOGDOSE*LOGDOSE. Then use the following SAS statements:

proc glm;
 class bloc type;
 model y=bloc type logdose logd2
    type*logdose type*logd2;

The results appear in Output 7.27. Notice that LOGDOSE does not appear in the CLASS statement. You use it, as well as LOGD2, as a direct regression variable, exactly as you would if LOGDOSE was a covariable and you suspected heterogeneous quadratic regressions of y on the covariable.

Output 7.27 ANOVA for Type-Dose Data Using Analysis-of-Covariance Methods

Comparing Output 7.25 to Output 7.22, you can see that the Type I SS for LOGDOSE and LOGD2 are identical to the contrast results for Linear Logdose and Quadratic Logdose. The sums of squares are both 115.5625 and 6.0208, respectively. Also, the TYPE*LOGDOSE and TYPE*LOGD2 Type I sum of squares are identical to the Linear Logdose×Type and Quadratic Logdose×Type contrasts from Output 7.21. In both cases, the significant difference between linear regressions of y on LOGDOSE for the two types is the main result. Note that the Type III sums of squares produce nonsense results for the LINEAR LOGDOSE main effect and interaction terms because they are both adjusted for quadratic effects. In general, the Type III SS should be ignored when using analysis of covariance in lieu of orthogonal polynomials.

Outputs 7.22 and 7.25 both lead to the conclusion that you should fit a linear regression over LOGDOSE for each type. You can use the following SAS statements to do so:

proc glm;
 class bloc type;
 model y= bloc type logdose(type)/solution;
 estimate ‘beta-0, type 1’
    intercept 4 bloc 1 1 1 1 type 4 0/divisor=4;
 estimate ‘beta-0, type 2’
    intercept 4 bloc 1 1 1 1 type 0 4/divisor=4;

These statements are similar to those used in Section 7.3 to fit the unequal slopes. The additional ESTIMATE statements allow you to compute the β_0i terms for the ith type, which the MODEL statement implicitly defines to be the sum of the intercept, the average block effect, and the type effect. The results appear in Output 7.28.

Output 7.28 ANOVA for Type-Dose Data Using Analysis-of-Covariance Methods

From Output 7.25, the main results are the regression equations. For Type 1, the equation is y=54.5 – 0.25*LOGDOSE; for Type 2 it is y=50.042+5.625*LOGDOSE.

PROC MIXED makes it somewhat more convenient to obtain the regression equations. You can use the SAS statements

proc mixed;
 class bloc type;
 model y=type logdose(type)/noint solution;
 random bloc;

The results appear in Output 7.29.

Output 7.29 Estimate of Linear Regression Equations for Each Type

The RANDOM BLOC statement and the NOINT option cause the β_0i terms to be estimated directly, rather than requiring ESTIMATE statements. You can assume that RANDOM BLOC does not affect the estimates, but it does change the standard errors of the regression coefficients. For PROC MIXED, the standard errors are 2.89 and 2.24 for the intercept and slope, respectively. These are valid if assuming blocks to be random is reasonable. The PROC GLM results, 1.80 and 1.39, assume fixed blocks.