Chapter 11 Examples of Special Applications

11.1 Introduction

11.2 Confounding in a Factorial Experiment

11.2.1 Confounding with Blocks

11.2.2 A Fractional Factorial Example

11.3 A Balanced Incomplete-Blocks Design

11.4 A Crossover Design with Residual Effects

11.5 Models for Experiments with Qualitative and Quantitative Variables

11.6 A Lack-of-Fit Analysis

11.7 An Unbalanced Nested Structure

11.8 An Analysis of Multi-Location Data

11.8.1 An Analysis Assuming No Location×Treatment Interaction

11.8.2 A Fixed-Location Analysis with an Interaction

11.8.3 A Random-Location Analysis

11.8.4 Further Analysis of a Location×Treatment Interaction Using a Location Index

11.9 Absorbing Nesting Effects

11.1 Introduction

As already noted, the GLM and MIXED procedures can be used to analyze a multitude of data structures. In this chapter several applications are presented that utilize tools discussed in the previous chapters. Some of these applications involve statistical topics that are not discussed in great detail in this book. References are given to provide the necessary background information.

11.2 Confounding in a Factorial Experiment

Experiments use confounding in two forms. The first are factorial treatments designs in which all factorial combinations appear in the experiment, but they appear in incomplete blocks containing only a subset of the factor combinations. Thus, within a given block, one or more treatment effects are confounded with block effects. The second are fractional factorial experiments in which only a subset of the factor combinations appear in the experiment. Thus, some of the factorial effects are not estimable, but are aliased with other effects, meaning that the same estimable function estimates both effects. Confounding is covered in most textbooks on the design of experiments (for example, Hicks and Turner 2000).

11.2.1 Confounding with Blocks

The first example for this topic is a 2³ factorial with factors labeled A, B, and C in blocks of size four. There are three replications with interactions ABC, AC, and BC, confounded with blocks in replications 1, 2, and 3, respectively. These factors are thus partially confounded with blocks. The data appear in Output 11.1.

Output 11.1 Data for a Two-Cube Factorial in Blocks of Size Four

Contrasts corresponding to confounded effects can be estimated only from those replications in which they are not confounded. In this example, they are estimated from only two-thirds of the data; thus their standard errors should be larger by a factor of $\sqrt{3/2}$.

The analysis using PROC GLM is straightforward. You can generate contrasts in the DATA step instead of specifying classes for treatments and using CONTRAST statements, as the following code shows:

data confound;
   input rep blk a b c y;
      ca= -(a=0) + (a=1);
      cb= -(b=0) + (b=1);
      cc= -(c=0) + (c=1);
    datalines;
      ·
      data
      ·
;

By sorting the data and running the analysis by REP, you can use the ALIASING option in PROC GLM to print out the confounding pattern. Use the following statements:

proc sort;
   by rep;
proc glm;
   by rep;
   class blk;
   model y=blk ca|cb|cc/solution aliasing;

The results appear in Output 11.2.

Output 11.2 Aliasing Output Showing a Confounding Pattern for a 2³Factorial in Blocks of Size Four

The contents of Output 11.2 appear immediately after the parameter estimates generated by the SOLUTION option in the MODEL statement. For REP=1, you can see that the three-way interaction CA*CB*CC has a blank under “Expected Value” but the INTERCEPT and BLK 1 effects estimate their usual estimable functions plus the CA*CB*CC effect. This indicates that the ABC interaction effect is confounded with block in REP=1. Similarly, the output indicates that the AC interaction is confounded with block in REP=2, and the BC interaction is confounded with block in REP=2. Although in this example the ALIASING option merely confirms the confounding pattern stated in the introduction, it can be very useful in data sets where the confounding pattern is not obvious and needs to be investigated.

For a complete analysis of the data, combined over all replications, use the following SAS statements:

proc glm;
   classes rep blk;
   model y=rep blk(rep) ca|cb|cc/ solution;

The results appear in Output 11.3.

Output 11.3 ANOVA for a Two-Cube Factorial in Blocks of Size Four

The standard errors of the coefficients of the confounded effects (ABC, AC, and BC) are indeed larger by $\sqrt{3/2}$ than the coefficients of the effects not confounded. You can verify that the sums of squares of the confounded effects, based on data from the replications in which they are not confounded, are identical to the sums of squares in Output 11.3.

The estimable functions option can be used to indicate the nature of the confounding. Requesting the Type I functions for effects in the same order as in the MODEL statement above gives the effects for BLK(REP) unadjusted for the factorial effects and reveals how the blocks are related to the factorial effects.

Output 11.4 Estimable Functions for a Two-Cube Factorial in Blocks of Size Four

Output 11.4 gives the nonzero coefficients of BLK(REP). The coefficient L5 appears on the terms for BLK in REP 1 and also the CA*CB*CC interaction term. This happens because CA*CB*CC is confounded with BLK in REP 1. This is apparent from the data set shown in Output 11.1. The product CA*CB*CC is equal to 1 for all observations in REP 1 of BLK 1 and CA*CB*CC= – 1 for REP 2 of BLK 1. In some data sets, the confounding pattern is not so obvious. Using the coefficients for estimable functions in conjunction with the output from the ALIASING option shown above, you can discover the confounding pattern.

11.2.2 A Fractional Factorial Example

The second example is a ½ fraction of a 2⁴ factorial experiment. The defining contrast is ABCD. The data appear in Output 11.5.

Output 11.5 Data for a ½ Fraction of a 2⁴ Factorial Experiment

The data in Output 11.5 include the factor levels in their original form (A, B, C, and D) and in contrast (–1,1) form (CA, CB, CC, and CD).

You can compute the analysis with the aliasing pattern by using PROC GLM statements similar to those used in the previous example:

proc glm;
   model y=ca|cb|cc|cd/solution aliasing;

Output 11.6 shows the results.

Output 11.6 PROC GLM Analysis of Data from a ½ Fraction of a 2⁴ Factorial Experiment

From Output 11.6, you can see that because there are only eight observations, only the first seven parameters in the model plus the intercept can be estimated. Also, each estimate is confounded—aliased—with one other factorial effect. The tables of “Parameter” and “Expected Value” at the end of the printout give the aliases. For example, the estimate of the intercept is aliased with the ABCD interaction, indicated on the printout by the fact that the expected value of the intercept is INTERCEPT + CA*CB*CC*CD. Similarly, the output indicates that the expected value of the parameter CA is CA+CB*CC*CD, that is, the main effect of A is aliased with the BCD interaction. You can apply analogous interpretations to the remaining parameters. You can see that this aliasing pattern agrees with the pattern you would derive from standard fractional factorial methods. In this case, which uses a very basic design, the ALIASING option merely restates information someone familiar with fractional factorial design would already know. However, for nonstandard incomplete factorial designs, for instance those you could generate with PROC OPTEX, the ALIASING option can provide useful information that usually is not obvious.

There are three important additional points about the analysis in Output 11.6. First, the default order of effects from the CA|CB|CC|CD syntax used in the MODEL statement causes all estimates involving factors A, B, and C to be estimated first, before any effects involving D appear in the model. This is not very realistic. Normally, you would not use a fractional factorial design unless you expect higher-order interaction effects to be negligible. For example, the output gives an estimate of the ABC interaction, which is aliased with the main effect of D. In practice, you would assume this to be an estimate of the main effect of D. That is, you would use this design only if you could assume that the ABC interaction is essentially zero. Also, because all the two-factor interactions are aliased with other two-factor interactions, you must be sure which you can assume to be negligible, and not alias two potentially important effects.

The second point is that there are no degrees of freedom and hence no F-values or p-values given in Output 11.6. The model used to compute the analysis is saturated. There are various strategies to get around this. A common approach is to assume that all interactions are zero and compute a main-effects-only model using the three degrees of freedom for the two-way interactions to estimate experimental error. You can do this by using the following statements:

proc glm;
   model y=ca cb cc cd/solution aliasing;

The results appear in Output 11.7. However, you can easily question whether the results in Output 11.7 are valid, because in Output 11.6, the largest single source of variation was the BC (aliased with AD) interaction. For these data, at least, the assumption that all interaction effects are zero is questionable. If there is a non-negligible BC (or AD) interaction, then the MS(ERROR) in Output 11.7 overestimates σ² and hence the F-values are too low. An alternative strategy, not shown here, uses half-normal plots to estimate σ² and construct approximate tests for the model effects. See Milliken and Johnson (1989, Chapter 4) for an explanation of how to implement half-normal plot analysis using SAS. Under the half-normal plot method, the main effects of A and the BC (or AD) interaction are statistically significant. You would need sufficient understanding of the data to decide whether the interaction is a BC or an AD interaction.

Output 11.7 Main-Effects-Only Analysis of Fractional Factorial Data

The final point concerns the use of the (–1,1) contrasts CA through CD instead of the original (0,1) coding of A through D. If you use the variables A through D in the model, the ALIASING option assesses the aliasing pattern based on the estimable functions that follow from the (0,1) coding. These do not correspond to the standard aliasing pattern for fractional factorial experiments, and can be difficult to interpret. For example, these SAS statements yield the results shown in Output 11.8:

proc glm;
   model y=a|b|c|d/ aliasing;

Output 11.8 An Analysis of Fractional Factorial Data Using 0-1 Coding

You can see that the sums of squares are the same as those computed from the contrast coding (–1,1). The parameter estimates are different, as you would expect, because the different coding changes the intercept and hence the other coefficients. The aliasing pattern shown in the “Expected Value” of the parameter estimates is also quite different. This reflects the fact that the (0,1) coding results in a different set of estimable functions. As shown in the theory section of Chapter 6, GLM determines estimable functions from the nonzero rows of the (X′X)^–(X′X) matrix. The contrast coding results in estimable functions in standard form for assessing aliasing patterns in incomplete factorials. On the other hand, the (0,1) coding results in a different, and unfamiliar, form.

11.3 A Balanced Incomplete-Blocks Design

Incomplete-blocks designs are used whenever there are not enough experimental units in blocks to accommodate all treatments. Perhaps the best-known incomplete-blocks design is the so-called balanced incomplete-blocks (BIB) design. This design in not balanced in the sense that we have used the word in previous chapters, because, in fact, not all treatments are assigned in all blocks. Instead, balance in the context of incomplete-blocks designs has the specific definition that all treatments appear in the same number of blocks, and all pairs of treatments appear together in the same number of blocks. These requirements result in certain conditions on the numbers of blocks, treatments, and numbers of treatments per block. For the BIB design with four treatments in blocks of size two, six blocks (three replications) are required (Cochran and Cox 1957). The data appear in Output 11.9. The design is shown below:

BIB Design Example Data (Numbers in parentheses indicate treatment number)
Block
1	2	3	4	5	6
2.7(1)	7.1(3)	7.1(1)	8.8(2)	9.7(1)	13.0(2)
2.7(2)	8.6(4)	9.7(3)	15.1(4)	17.4(4)	16.6(3)

Output 11.9 Data for a Balanced Incomplete- Blocks Design

Consider the following statements:

proc glm;
   class blk trt;
   model y=trt blk / e1 ss3;
   means trt blk;
   lsmeans trt / stderr pdiff cl;
run;

The analysis-of-variance portion appears in Output 11.10.

Output 11.10 ANOVA for a Balanced Incomplete-Blocks Design

The Type I sum of squares is the unadjusted treatment sum of squares, based on the ordinary treatment means. Therefore, the unadjusted treatment sum of squares contains both treatment differences and block differences. The Type III treatment sum of squares is adjusted for blocks. This means that block effects have been removed from the sum of squares. Thus, the adjusted treatment mean square measures only differences between treatment means and random error. These concepts are revealed in the estimable functions. Table 11.1 shows the Type I estimable functions.

Table 11.1 Type I Estimable Functions for Treatments

Effect		Symbolic Expression	Coefficients for TRT1 Effect
TRT	1	L2	+.75
	2	L3	–.25
	3	L4	–.25
	4	–L2–L3–L4	–.25
BLK	1	.333L2 +.333L3	.167
	2	.333L2 +.333L3	–.167
	3	.333L2 +.333L4	–.167
	4	.333L2 +.333L3	–.167
	5	.333L3 +.333L4	–.167
	6	.333L3 +.333L4	–.167

The Type I estimable function for treatments (TRT) is of some interest. Consider the contrast

TRT1 − 1/4(TRT1 + TRT2 + TRT3 + TRT4)

This is often called the effect of treatment 1, or the difference between the treatment 1 mean from the mean of all treatments. Simplification gives

3/4(TRT1) − 1/4(TRT2) − 1/4 (TRT3) − 1/4(TRT4)

This expression is obtained by defining

L2 = 3/4

L3 = 1/4

L4 = 1/4

and results in the coefficients that appear in the right-hand column of Table 11.1. You can see that the Type I (unadjusted) estimate of the TRT 1 effect is also a contrast between blocks 1, 3, and 5, which contain treatment 1, and blocks 2, 4, and 6, which do not.

The least-squares means (see Output 11.10) have been “adjusted” for block effects. The corresponding estimable functions (not reproduced here) show that the LS means contain equal representation of block parameters even though individual treatments do not appear in all the blocks. Differences between LS means provide the so-called intra-block comparisons of treatments. There is information about differences between the treatment means contained in the block means that is not used in the intra-block comparisons. This is called the inter-block information.

Expected mean squares from the RANDOM statement reveal the presence of block effects in the Type I mean squares, but not in the Type III mean squares, as shown in Output 11.11. The Type I EMS for TRT contains VAR(BLK), but the Type III EMS does not.

Output 11.11 Expected Mean Squares for a Balanced Incomplete-Blocks Design

The MIXED procedure can be used to obtain the combined inter- and intra-block information about differences between treatment means. Run the following statements:

proc mixed data=bibd;
   class blk trt;
   model y=trt / ddfm=satterth;
   random blk;
   lsmeans trt / pdiff cl;
run;

The results appear in Output 11.12.

Output 11.12 A Mixed-Model Analysis of a Balanced Incomplete-Blocks Design

You can see the distinction between the intra-block and the combined inter- and intra-block comparisons of treatments by comparing results in Output 11.10 and Output 11.12. First of all, the TRT LSMEANS are slightly different in the two output tables. Also, the confidence for the difference between TRT 1 and TRT 2 in Output 11.10 is (–3.802709, 2.102709), whereas the confidence interval in Output 11.12 is (–3.7462, 1.9552). The confidence interval using the combined information in Output 11.12 is slightly narrower. However, this can be misleading. The standard error in Output 11.12 does not take into account the variation induced by estimating the variance-covariance matrix to obtain the estimated GLS estimates of differences between treatment means. If you use DDFM=KENWARDROGER in the MODEL statement you will get a better assessment of the true error of estimation.

11.4 A Crossover Design with Residual Effects

Crossover designs are used in animal nutrition and pharmaceutical studies to compare two or more treatments (diets or drugs). The treatments are administered sequentially to each subject over a set of time periods. This enables the comparison of treatments on a within-subjects basis. However, there is a possibility that the response obtained after a particular time period might be influenced by the treatment assigned not only in that period but also in previous periods. If so, then the response contains residual effects from the previous periods. Some authors call these “carry-over” effects. Certain crossover designs permit the residual effects to be estimated, and thus to be effectively removed from estimates of treatment means and comparisons of means.

Cochran and Cox (1957) present two 3×3 Latin squares as a design for estimating the residual effects on milk yields of treatment from the preceding period. The treatment allocation is shown in the table below. The columns of the two squares contain the six possible sequences.

Square Cow		I	1 II	III	IV	2 V	VI
	1	A	B	C	A	B	C
Period	2	B	C	A	C	A	B
	3	C	A	B	B	C	A

Output 11.13 contains data from a study that was conducted to compare the effects on heart rate of three treatments; a test drug, a standard drug, and a placebo. Treatments were assigned in the six possible sequences to four patients each. The treatment design for the data in Output 11.13 is equivalent to the Cochran and Cox design in the table above with sequences A-F in Output 11.13 corresponding to Cows I-VI in the table, respectively.

Heart rate was measured one hour following the administration of treatment in each of three visits. The visits are labeled 2, 3, and 4, because visit 1 was a preliminary visit for baseline data. Thus, in the general terminology of crossover designs, period 1 is visit 2, period 2 is visit 3, and period 3 is visit 4. Baseline heart rate was measured, but it is not used in the illustrative analysis.

A model for the data is

y_ijk = μ + α_i + d_j + β_k + τ_l(ik) + ρ_m(ik) + e_ijk

where α_i is the effect of sequence i, d_j is the random effect of patient j, β_k is the effect of visit k, τ_l(ik) is the direct effect of treatment l, τ_l(ik) is the residual effect of treatment m, and e_ijk is a random effect associated with patient j in visit k. The subscript l(jk) on the treatment direct effect indicates that the treatment (l) is a function of the visit (k) and sequence (i). The same is true of the treatment residual effect subscript m(ik).

When using PROC GLM to analyze data from a crossover design, the sequence, patient, period, and direct treatment effects can be incorporated into the model with the dummy variables that result from using a CLASS statement. However, it is more convenient to use explicitly created covariates in the model for the residual effects. In the data set for the heartrate data, we create covariates for the standard and test drug residual effects named RESIDS and RESIDT, respectively. Their values in the first period (visit 2) are zero because there is no period prior to the first period that would contribute a residual effect. In periods 2 and 3 (visits 3 and 4), the values of RESIDS and RESIDT are 0 or ±1 depending on the treatment in the preceding visit. This particular coding provides estimates of the residual effects corresponding to those prescribed by Cochran and Cox (1957). For example, patient number 2 is in sequence F (test, placebo, standard). The values of RESIDS and RESIDT are both 0 in the first period (visit 2). Patient 2 received the test drug in period 1, so in period 2 (visit 3), the covariates have values RESIDS=0 and REISIDT=1. This specifies that the residual effect ρ_T for test is contained in the observation on patient 2 in period 2. In period 3 (visit 4), the covariates both have values of –1. This coding specifies a sum-to-zero constraint on the residual effects. Thus, the residual effect ρ_P of the placebo satisfies the equation ρ_P = −ρ_T − ρ_S, and hence the residual effect ρ_P of the placebo can be represented with –1 times the residual effects of test and standard.

Output 11.13 Date for Crossover Design with Residual Effects

The following SAS statements can be used to construct an analysis of variance and parameter estimates similar to those proposed by Cochran and Cox (1957):

proc glm data=hrtrate;
   class sequence patient visit drug;
   model hr = sequence patient(sequence) visit drug
      resids residt / solution;
   random patient(sequence)
run;

ANOVA results appear in Output 11.14.

Output 11.14 ANOVA for a Crossover Design

The desired ANOVA table is constructed as follows:

Source of Variation	DF	SS
Sequence	5	508.94	(Type I)
Patient(Sequence)	18	4692.33	(Type I)
Visits	2	146.78	(Type III)
Direct effect of drugs (adjusted for residual effects)	2	343.95	(Type III)
Residual effects(adjusted)	2	391.86	(Type I SS RESIDS+Type I SS RESIDT)

Expected mean squares shown in Output 11.15 show that appropriate tests for VISIT, DRUG, and the carry-over effect covariates utilize residual means square as an error term. A test for SEQUENCE would use PATIENT(SEQUENCE) in the error term.

Output 11.15 Expected Mean Squares for a Crossover Design

The effect of SEQUENCE is clearly not significant, since the F-ratio would be less than 1 using either a Type I or a Type III mean square in the numerator. The Type III test for DRUG has a significance level p=0.0538. The Type III mean square for DRUG has been adjusted for the residual effects. The Type I mean square for DRUG is not adjusted for the residual effects, and an F-test based on it has a significance probability p=0.0054. Thus, results from tests for DRUG depend on whether residual effects have been removed or not. Estimates of the direct and residual effect parameters can be obtained from Output 11.16.

Output 11.16 Parameter Estimates for a Crossover Design

First of all, the residual effects presented by Cochran and Cox (1957) are obtained from the parameter estimates for RESIDS and RESIDT. The values are

STD: –4.396

TST: 0.229

PCB: – (–4.396 + 0.229) = 4.167

Notice that these estimates come from the sum-to-zero coding for the residual effect dummy variables.

The direct treatment effects reported by Cochran and Cox (1957) can be obtained from the TRTMENT parameter estimates according to the following equations:

STD: –0.4375 =      2.3125 (1/3)(2.3125 + 5.9375 + 0.0000)

TST: 3.1875 =        5.9375 (1/3)(2.3125 + 5.9375 + 0.0000)

PCB: –2.7500 =      0.000 (1/3)(2.3125 + 5.9375 + 0.0000)

Thus, the direct effects can be obtained from the following ESTIMATE statements:

estimate 'DIRECT EFFECT OF STD'
          drug 2 –1 –1 / divisor=3;
estimate 'DIRECT EFFECT OF TST'
          drug –1 2 –1 / divisor=3;
estimate 'DIRECT EFFECT OF PCB'
          drug –1 –1 2 / divisor=3;

Results from these ESTIMATE statements appear in Output 11.17.

Output 11.17 Direct Effect Estimates

The direct effect means reported by Cochran and Cox (1957) are equal to the overall mean 80.8056 (printed as HR mean in Output 11.14) added to the direct effects. They are also equal to the GLM least-squares means, obtained from the following statement:

lsmeans drug / pdiff cl e;

The results appear in Output 11.18. You can see from the estimable functions that the LS means contain the INTERCEPT, and average across the SEQUENCE, PATIENT(SEQUENCE), and VISIT parameters. Thus, the correct standard error of these LS means would contain variance due to PATIENT(SEQUENCE). However, this variance is not contained in the standard error computed by PROC GLM for the LS means. (That is why we specified the STDERR option in the LSMEANS statement.) As a consequence, the confidence intervals for LS means displayed in Output 11.18 are not valid. However, the confidence intervals for the differences between LS means in Output 11.18 are valid because the INTERCEPT, SEQUENCE, PATIENT(SEQUENCE), and VISIT parameters would drop out of the differences.

Output 11.18 Least-Squares Means for a Crossover Design

PROC MIXED can be used to analyze the crossover design data. Run the following statements:

proc mixed data=hrtrate order=internal;
class sequence patient visit drug;
model hr=sequence visit drug resides residt/solution
ddfm=satterth;
random patient(sequence);
lsmeans drug / pdiff cl e;
run;

Edited results appear in Output 11.19.

Output 11.19 Partial Mixed-Model Results for a Crossover Design

The test of significance for DRUG in “Type 3 Tests of Fixed Effects” in Output 11.19 is the same as the test from GLM in Output 11.15. Likewise, the least-squares means are equal in the two analyses. This illustrates that ordinary least-squares analyses, as performed by GLM, can be equivalent to generalized least-squares analyses, as performed by MIXED. The phenomenon occurs in this example because the within-patients effects are orthogonal to the between-patients effects. However, notice that the confidence intervals for differences between LS means are the same in Outputs 11.18 and 11.19, but the confidence intervals for the LS means themselves are wider in Output 11.19 than in Output 11.18 because PROC MIXED computes standard errors of LS means that incorporate the PATIENT(SEQUENCE) variance.

11.5 Models for Experiments with Qualitative and Quantitative Variables

The material in this section is related to the discussions of regression analysis in Chapter 2 and analysis of covariance in Chapter 7. This section concerns details of certain models that contain dummy variables generated from the CLASS statement, and also a continuous variable. These are several regression models in one equation. Of particular interest are cases for which the regressions have a common intercept. These types of models are frequently used, for example, in relative potency and relative bioavailability studies (Littell et al. 1997).

Many experiments involve both qualitative and quantitative factors. For example, the tensile strength (TS) of a monofilament fiber depends on the amount (AMT) of a chemical used in the manufacturing process. This chemical can be obtained from three different sources (SOURCE), with values A, B, or C. SOURCE is a qualitative variable and AMT is a quantitative variable. Measurements of TS were obtained from samples from different amounts and sources. The SAS data set named MONOFIL appears in Output 11.20.

Output 11.20 Data for an Experiment with Qualitative and Quantitative Variables

A simple linear regression model for each source relates to TS and AMT:

TS = α_A + β_A + ε (SOURCE A)

TS = α_B + β_B + ε (SOURCE B)

TS = α_C + β_C + ε (SOURCE C)

The parameters α_A and β_A are the intercept and slope, respectively, for SOURCE=A.

The following statements produce the analysis of variance and parameter estimates in Output 11.21.

proc glm data=monofil;
class source;
model ts=source amt source*amt / solution;
run;

Output 11.21 A Model with Main Effects and Interactions

These parameter estimates pertain to the integrated model

$\text{TS}={\alpha }_{\text{C}}+{{\alpha }^{\prime }}_{\text{A}}{\text{D}}_{\text{A}}+{{\alpha }^{\prime }}_{\text{B}}{\text{D}}_{\text{B}}+{\beta }_{\text{C}}\text{AMT}+{{\beta }^{\prime }}_{\text{A}}{\text{D}}_{\text{A}}\text{AMT}+{{\beta }^{\prime }}_{\text{B}}{\text{D}}_{\text{B}}\text{AMT}+\epsilon$

The parameters α′ and β′ are further defined as

α'_A = α_A - α_C α'_B = α_B - α_C
β'_A = β_A - β_C β'_B = β_B - β_C

The variable D_A is a dummy variable equal to 1 for SOURCE=A and equal to 0 otherwise, and D_B has a corresponding definition with respect to SOURCE=B. Thus, the regression models for the three nitrogen sources are

TS = (α_C + α'_A) + (β_C + β'_A) AMT + ε (SOURCE A)
TS = (α_C + α'_B) + (β_C + β'_B) AMT + ε (SOURCE B)
TS = α_C + α_CAMT + ε                          (SOURCE C)

Therefore, the fitted equations are

TS = 9.49 + 0.33 + (3.35 - 1.61) AMT (SOURCE A)
      = 9.82 + 1.74 AMT
TS = 9.49 - 0.02 + (3.35 - 2.00) AMT (SOURCE B)
      = 9.47 + 1.35 AMT
TS = 9.49 + 3.35 AMT                         (SOURCE C)

The GLM parameter estimates, in effect, treat the regression line for SOURCE=C as a reference line, and the parameters α′_A, α′_B, β′_A, and β′_B are parameters for lines A and B minus parameters for line C. The AMT source parameters β′_A and β′_B measure differences between the slopes for regression lines A and B, and line C, respectively. Thus, a test that these parameters are 0 is testing that the lines are parallel, that is, they have equal slopes. The appropriate statistic is the F=57.28 for the AMT*SOURCE effect, which has a significant probability p=0.0001.

Caution is advised in using the Type III F-test for SOURCE. It is a test of the equality of the intercepts (H₀: α_A = α_B = α_C), which probably has no practical interpretation because the intercepts are simply extrapolations of the lines to L=0. The Type I F-test, on the other hand, tests the equality of the midpoints of the regression lines (H₀: α_A + β_A (2) = α_B + β_B(2) = α_C + β_C(2)).

You can compare two sources at a given amount with an ESTIMATE statement. Suppose you want to compare SOURCE=A with SOURCE=B using AMT=3.5. This difference is

(α_A + β_A(3.5)) - (α_B + β_B(3.5))
=((α_C + α'_A) + (β_C + β'_C) 3.5)
= ((α_C + α'_B) + (β_C + β'_C) 3.5)
= α'_A + α'_B + (β'_A + β'_B) 3.5

So the appropriate ESTIMATE statement is

estimate 'A vs B at AMT=3.5'
source 1 -1 0
   source*amt 3.5 -3.5 0;

The results appear in Output 11.22.

Output 11.22 The Difference between SOURCE=A and SOURCE=B at AMT=3.5

Suppose TS also is measured for AMT=0. This variation of the experiment is commonly mishandled by data analysts. Since AMT=0 means there is no chemical, the intercepts for the models are all equal, α_A = α_B = α_C. Thus, a correct analysis should provide equal estimates of the intercepts. The regressions can be written simultaneously as

TS = α + γ_AD_AAMT + γ_BD_BAMT + γ_CD_CAMT + ε

where D_A is a dummy variable equal to 1 for SOURCE=A and equal to 0 otherwise, and D_B and D_C have corresponding definitions with respect to SOURCE=B and SOURCE=C. Use PROC GLM to create D_A, D_B, and D_C by including the SOURCE variable in a CLASS statement.

Look at the data set MONOFIL2 printed in Output 11.23. The value C is arbitrarily assigned to SOURCE when AMT=0.

Output 11.23 Data with AMT=0

The following statements produce Output 11.24:

proc glm;
   class source;
   model ts=amt*source / solution

Output 11.24 Parameter Estimates for Data with AMT=0

Parameter estimates in Output 11.24 yield the three prediction equations

TS = 9.88 + 1.72 AMT	(SOURCE A)
TS = 9.88 + 1.24 AMT	(SOURCE B)
TS = 9.88 + 3.24 AMT	(SOURCE C)

The relative effect of one source to another can be measured by the ratio of slopes of the regression parameters. For example, the strength of SOURCE B relative to SOURCE A is the ratio 1.24/1.72 = 0.72. This means that one unit of the chemical from SOURCE B has the same effect on tensile strength as .72 units of the chemical from SOURCE A.

Similar models are used in other types of applications. The potency of one drug relative to another in a drug study, or the bioavailability of one nutrient relative to another in a nutrition study, is measured in the same way.