Here are examples of statements that accomplish specific data-manipulation tasks.

if resthr<70 then delete;  
if tolerance='D';

drop timemin timesec;

TotalTime=(timemin*60)+timesec;

retain SumSec 5400; 

sumsec+totaltime;

length TestLength $ 6;

  if totaltime>800 then TestLength='Long'; 
  else if 750<=totaltime<=800 
    then TestLength='Normal'; 
      else if totaltime<750 
    then TestLength='Short';

The following topics discuss these tasks.

To add the result of an expression to an accumulator variable, you can use a sum statement in your DATA step.

The sum statement is one of the few SAS statements that do not begin with a keyword.

The sum statement adds the result of the expression that is on the right side of the plus sign (+) to the numeric variable that is on the left side of the plus sign. The value of the accumulator variable is initialized to 0 instead of missing before the first iteration of the DATA step. Subsequently, the variable’s value is retained from one iteration to the next.

To find the total number of elapsed seconds in treadmill stress tests, you need the variable SumSec, whose value begins at 0 and increases by the amount of the total seconds in each observation. To calculate the total number of elapsed seconds in treadmill stress tests, use the sum statement shown below:

data work.stresstest; 
  set cert.tests; 
  TotalTime=(timemin*60)+timesec; 
  SumSec+totaltime; 
run;

The value of the variable on the left side of the plus sign, SumSec, begins at 0 and increases by the value of TotalTime with each observation.

In the previous example, the sum variable SumSec was initialized to 0 before the first observation was read. However, you can initialize SumSec to a different number than 0.

Use the RETAIN statement to assign an initial value, other than 0, to an accumulator variable in a sum statement.

The RETAIN statement has several purposes:

Suppose you want to add 5400 seconds (the accumulated total seconds from a previous treadmill stress test) to the variable SumSec in the StressTest data set when you create the data set. To initialize SumSec with the value 5400, use the RETAIN statement shown below. Now the value of SumSec begins at 5400 and increases by the value of TotalTime with each observation.

data work.stresstest;
  set cert.tests;
  TotalTime=(timemin*60)+timesec;
  retain SumSec 5400;
  sumsec+totaltime;
run;
proc print data=work.stresstest;
run;