Every SAS date value can be queried for the values of its year, quarter, month, and day. You extract these values by using the functions YEAR, QTR, MONTH, and DAY. They each work the same way.

The YEAR function returns a four-digit numeric value that represents the year (for example, 2018). The QTR function returns a value of 1, 2, 3, or 4 from a SAS date value to indicate the quarter of the year in which a date value falls. The MONTH function returns a numeric value that ranges from 1 to 12, representing the month of the year. The value 1 represents January, 2 represents February, and so on. The DAY function returns a numeric value from 1 to 31, representing the day of the month.

Suppose you want to create a subset of the data set Cert.Temp that contains information about all temporary employees who were hired in November 2017. The data set Cert.Temp contains the beginning and ending dates for staff employment, but there are no month or year variables in the data set. To determine the year in which employees were hired, you can apply the YEAR function to the variable that contains the employee start date, StartDate. Here is a way to write the YEAR function:

year(startdate)

Likewise, to determine the month in which employees were hired, you apply the MONTH function to StartDate.

month(startdate)

To create the new data set, you include these functions in a subsetting IF statement within a DATA step. The subsetting IF statement specifies the new data set include only the observations where the YEAR function extracts a value of 2017 and the MONTH function extracts a value of 11. The value of 11 stands for November.

data work.nov17; 
  set cert.temp; 
  if year(startdate)=2017 and month(startdate)=11; 
run;

When you add a PROC PRINT step to the program, you can view the new data set.

proc print data=work.nov17; 
  format startdate enddate birthdate date9.;
run;

The new data set contains information about only those employees who were hired in November 2017.

Suppose you want to create a subset of the data set Cert.Temp that contains information about all temporary employees who were hired during a specific year, such as 2016. Cert.Temp contains the dates on which employees began work with the company and their ending dates, but there is no year variable.

To determine the year in which employees were hired, you can apply the YEAR function to the variable that contains the employee start date, StartDate. You write the YEAR function as follows:

year(startdate)

To create the new data set, you include this function in a subsetting IF statement within a DATA step. This subsetting IF statement specifies that only observations in which the YEAR function extracts a value of 2016 are placed in the new data set.

data work.temp16; 
  set cert.temp; 
  if year(startdate)=2016; 
run;

When you add a PROC PRINT step to the program, you can view the new data set.

data work.temp16; 
  set cert.temp; 
  where year(startdate)=2016; 
run; 
proc print data=work.temp16; 
  format startdate enddate birthdate date9.;
run;

The new data set contains information for only those employees who were hired in 2016.

The WEEKDAY function enables you to extract the day of the week from a SAS date value.

The WEEKDAY function returns a numeric value from 1 to 7. The values represent the days of the week.

For example, suppose the data set Cert.Sch contains a broadcast schedule. The variable AirDate contains SAS date values. To create a data set that contains only weekend broadcasts, you use the WEEKDAY function in a subsetting IF statement. You include only observations in which the value of AirDate corresponds to a Saturday or Sunday.

data work.schwkend; 
  set cert.sch; 
  if weekday(airdate)in(1,7); 
run;
proc print data=work.schwkend;
run;

The MDY function returns a SAS date value from month, day, and year values.

In the data set Cert.Dates, the values for month, day, and year are stored in the numeric variables Month, Day, and Year. It is possible to write the following MDY function to create the SAS date values:

mdy(month,day,year)

To create a new variable to contain the SAS date values, place this function in an assignment statement.

data work.datestemp; 
  set cert.dates; 
  Date=mdy(month,day,year); 
run;
proc print data=work.datestemp;
  format date mmddyy10.;
run;

The MDY function can also add the same SAS date to every observation. This might be useful if you want to compare a fixed beginning date with different end dates. Just use numbers instead of data set variables when providing values to the MDY function.

data work.datestemp;
  set cert.dates;
  DateCons=mdy(6,17,2018);
run;
proc print data=work.datestemp;
  format DateCons mmddyy10.;
run;

To display the years clearly, format SAS dates with the DATE9. format. This forces the year to appear with four digits, as shown above in the Date and DateCons variables of the Work.DatesTenp output.

The data set Cert.Review2018 contains a variable named Day. This variable contains the day of the month for each employee's performance appraisal. The appraisals were all completed in December of 2018.

The following DATA step uses the MDY function to create a new variable named ReviewDate. This variable contains the SAS date value for the date of each performance appraisal.

data work.review2018 (drop=Day);
  set cert.review2018;
  ReviewDate=mdy(12,day,2018);
run;
proc print data=work.review2018;
  format ReviewDate mmddyy10.;
run;

data work.review2018 (drop=Day);
  set cert.review2018;
  ReviewDate=mdy(15,day,2018);
run;
proc print data=work.review2018;
  format ReviewDate mmddyy10.;
run;

The DATE function returns the current date as a numeric SAS date value.

The DATE function produces the current date in the form of a SAS date value, which is the number of days since January 1, 1960.

The TODAY function returns the current date as a numeric SAS date value.

The TODAY function produces the current date in the form of a SAS date value, which is the number of days since January 1, 1960.

The DATE and TODAY functions have the same form and can be used interchangeably. To add a new variable, which contains the current date, to the data set Cert.Temp. To create this variable, write an assignment statement such as the following:

EditDate=date();

After this statement is added to a DATA step and the step is submitted, the data set that contains EditDate is created. To display these SAS date values in a different form, you can associate a SAS format with the values. For example, the FORMAT statement below associates the DATE9. format with the variable EditDate. The output that is created by this PROC PRINT step appears below.

data work.tempdate; 
  set cert.dates; 
  EditDate=date(); 
run;
proc print data=work.tempdate; 
  format EditDate date9.; 
run;

The INTCK function returns the number of interval boundaries of a given kind that lie between two dates, times, or datetime values. You can use it to count the passage of days, weeks, months, and so on.

The INTCK function counts intervals from fixed interval beginnings, not in multiples of an interval unit from the from value. Partial intervals are not counted. For example, WEEK intervals are counted by Sundays rather than seven-day multiples from the from argument. MONTH intervals are counted by day 1 of each month, and YEAR intervals are counted from 01JAN, not in 365-day multiples.

Consider the results in the following table. The values that are assigned to the variables Weeks, Months, and Years are based on consecutive days.

Weeks=intck('week','31dec2017'd,'01jan2018'd);

Months=intck('month','31dec2017'd,'01jan2018'd);

Years=intck('year','31dec2017'd,'01jan2018'd);

Because December 31, 2017, is a Sunday, no WEEK interval is crossed between that day and January 1, 2018. However, both MONTH and YEAR intervals are crossed.

The following statement creates the variable Years and assigns it a value of 2. The INTCK function determines that two years have elapsed between June 15, 2016, and June 15, 2018.

Years=intck('year','15jun2016'd,'15jun2018'd);

Likewise, the following statement assigns the value 24 to the variable Months.

Months=intck('month','15jun2016'd,'15jun2018'd);

However, the following statement assigns 0 to the variable Years, even though 364 days have elapsed. In this case, the YEAR boundary (01JAN) is not crossed.

Years=intck('year','01jan2018'd,'31dec2018'd);

A common use of the INTCK function is to identify periodic events such as due dates and anniversaries.

The following program identifies mechanics whose 20th year of employment occurs in the current month. It uses the INTCK function to compare the value of the variable Hired to the date on which the program is run.

data work.anniversary; 
  set cert.mechanics(keep=id lastname firstname hired); 
  Years=intck('year',hired,today()); 
  if years=20 and month(hired)=month(today()); 
run;
proc print data=work.anniversary; 
  title '20-Year Anniversaries'; 
run;

The following output is created when the program is run in July 2018.

The INTNX function is similar to the INTCK function. The INTNX function applies multiples of a given interval to a date, time, or datetime value and returns the resulting value. You can use the INTNX function to identify past or future days, weeks, months, and so on.

When you specify date intervals, the value of the character constant or variable that is used in interval can be one of the following:

For example, the following statement creates the variable TargetYear and assigns it a SAS date value of 22281, which corresponds to January 1, 2021.

TargetYear=intnx('year','20Jul18'd,3);

Likewise, the following statement assigns the value for the date July 1, 2018, to the variable TargetMonth.

TargetMonth=intnx('semiyear','01Jan18'd,1);

SAS date values are based on the number of days since January 1, 1960. Yet the INTNX function can use intervals of weeks, months, years, and so on.

The purpose of the optional alignment argument is to specify whether the returned value should be at the beginning, middle, or end of the interval. When specifying date alignment in the INTNX function, use the following values or their corresponding aliases:

The best way to understand the alignment argument is to see its effect on identical statements. The following table shows the results of three INTNX statements that differ only in the value of alignment.

MonthX=intnx('month','01jan2018'd,5,'b');

MonthX=intnx('month','01jan2018'd,5,'m');

MonthX=intnx('month','01jan2018'd,5,'e');

These INTNX statements count five months from January, but the returned value depends on whether alignment specifies the beginning, middle, or end day of the resulting month. If alignment is not specified, the beginning day is returned by default.