The SCAN function returns the nth word from a character string. The SCAN function enables you to separate a character value into words and to return a specified word.

Use the SCAN function to create your new name variables for Hrd.Temp. First, examine the values of the existing Name variable to determine which characters separate the names in the values.

LastName=scan(name,1);

Notice that blanks and commas appear between the names and that the employee's last name appears first, then the first name, and then the middle name.

To create the LastName variable to store the employee's last name, you write an assignment statement that contains the following SCAN function:

LastName=scan(name,1,' ,');

Note that a blank and a comma are specified as delimiters. You can also write the function without listing delimiters, because the blank and comma are default delimiters.

LastName=scan(name,1);

Here is the complete DATA step that is needed to create LastName, FirstName, and MiddleName. Notice that the original Name variable is dropped from the new data set.

data hrd.newtemp(drop=name); 
   set hrd.temp; 
   LastName=scan(name,1); 
   FirstName=scan(name,2); 
   MiddleName=scan(name,3); 
run;

The SCAN function uses delimiters, which are characters that are specified as word separators, to separate a character string into words. For example, if you are working with the character string below and you specify the comma as a delimiter, the SCAN function separates the string into three words.

Then the function returns the word that you specify. In this example, if you specify the third word, the SCAN function returns the word HIGH.

Here is another example that uses the comma as a delimiter, and specifies that the third word be returned.

209 RADCLIFFE ROAD, CENTER CITY, NY, 92716

In this example, if you specify the third word, the word returned by the SCAN function is NY ( NY contains a leading blank).

When using the SCAN function, you can specify as many delimiters as needed to correctly separate the character expression. When you specify multiple delimiters, SAS uses any of the delimiters, singly or in any combination, as word separators. For example, if you specify both the slash and the hyphen as delimiters, the SCAN function separates the following text string into three words:

The SCAN function treats two or more contiguous delimiters, such as the parenthesis and slash below, as one delimiter. Also, leading delimiters have no effect.

If you do not specify delimiters when using the SCAN function, default delimiters are used. Here are the default delimiters:

blank . < ( + | & ! $ * ) ; ^ - / , %

If a variable is not assigned a length before it is specified in the SCAN function, the variable is given the length of the first argument. This length could be too small or too large for the remaining variables.

You can add a LENGTH statement to the DATA step, and specify an appropriate length for all three variables. Because SAS sets the length of a new character variable the first time it is encountered in the DATA step, the LENGTH statement is placed before the assignment statements that contain the SCAN function.

data hrd.newtemp(drop=name); 
   set hrd.temp; 
   length LastName FirstName MiddleName $ 10; 
   lastname=scan(name,1); 
   firstname=scan(name,2); 
   middlename=scan(name,3); 
run;

The SUBSTR function extracts a substring from an argument, starting at a specific position in the string.

The SUBSTR function can be used on either the right or left of the equal sign to replace character value constants.

This example begins with the task of extracting a portion of a value. In the data set Hrd.Newtemp, the names of temporary employees are stored in three name variables: LastName, FirstName, and MiddleName.

However, suppose you want to modify the data set to store only the middle initial instead of the full middle name. To do so, you must extract the first letter of the middle name values and assign these values to the new variable MiddleInitial.

Using the SUBSTR function, you can extract the first letter of the MiddleName value to create the new variable MiddleInitial.

You write the SUBSTR function as the following:

substr(middlename,1,1)

This function extracts a character string from the value of MiddleName. The string to be extracted begins in position 1 and contains one character. This function is placed in an assignment statement in the DATA step.

data work.newtemp(drop=middlename); 
   set hrd.newtemp; 
   length MiddleInitial $ 1;
   MiddleInitial=substr(middlename,1,1); 
run;

The new MiddleInitial variable is given the same length as MiddleName. The MiddleName variable is then dropped from the new data set.

You can use the SUBSTR function to extract a substring from any character value if you know the position of the value.

There is a second use for the SUBSTR function. This function can also be used to replace the contents of a character variable. For example, suppose the local phone exchange 622 was replaced by the exchange 433. You need to update the character variable Phone in Hrd.Temp to reflect this change.

You can use the SUBSTR function to complete this modification. The syntax of the SUBSTR function, when used to replace a variable's values, is identical to the syntax for extracting a substring.

SUBSTR(argument,position,n)

However, in this case, note the following:

SAS uses the SUBSTR function to extract a substring or to modify a variable's values, depending on the position of the function in the assignment statement.

When the function is on the right side of an assignment statement, the function returns the requested string.

MiddleInitial=substr(middlename,1,1);

But if you place the SUBSTR function on the left side of an assignment statement, the function is used to modify variable values.

substr(region,1,3)='NNW';

When the SUBSTR function modifies variable values, the right side of the assignment statement must specify the value to place into the variable. For example, to replace the fourth and fifth characters of a variable named Test with the value 92, you write the following assignment statement:

substr(test,4,2)='92'; 

Test             Test

S7381K2    →    S7392K2
S7381K7    →    S7392K7

It is possible to use the SUBSTR function to replace the 622 exchange in the variable Phone. First, write this assignment statement:

data hrd.temp2; 
   set hrd.temp; 
   substr(phone,1,3)='433'; 
run;

This statement specifies that the new exchange 433 should be placed in the variable Phone, starting at character position 1 and replacing three characters.

However, executing this DATA step places the value 433 into all values of Phone. You need to replace only the values of Phone that contain the 622 exchange. To extract the exchange from Phone, add an assignment statement to the DATA step. Notice that the SUBSTR function is used on the right side of the assignment statement.

data hrd.temp2(drop=exchange); 
   set hrd.temp; 
   Exchange=substr(phone,1,3); 
   substr(phone,1,3)='433'; 
run;

Now the DATA step needs an IF-THEN statement to verify the value of the variable Exchange. If the exchange is 622, the assignment statement executes to replace the value of Phone.

data hrd.temp2(drop=exchange); 
   set hrd.temp; 
   Exchange=substr(phone,1,3); 
   if exchange='622' then substr(phone,1,3)='433'; 
run;

After the DATA step is executed, the appropriate values of Phone contain the new exchange.

Recall that when the SUBSTR function is on the right side of an assignment statement, the function extracts a substring.

MiddleInitial=substr(middlename,1,1);

When the SUBSTR function is on the left side of an assignment statement, the function replaces the contents of a character variable.

 substr(region,1,3)='NNW';

The TRIM function removes trailing blanks from character expressions and returns one blank if the expression contains missing values.

FullName = trim(First) || trim(Middle) || Last;

The TRIM function is useful for concatenating because the concatenation operator does not remove trailing blanks.

If the TRIM function returns a value to a variable that was not yet assigned a length, by default, the variable length is determined by the length of the argument.

The CATX function enables you to concatenate character strings, remove leading and trailing blanks, and insert separators. The CATX function returns a value to a variable, or returns a value to a temporary buffer. The results of the CATX function are usually equivalent to those that are produced by a combination of the concatenation operator and the TRIM and LEFT functions.

In the DATA step, if the CATX function returns a value to a variable that has not previously been assigned a length, then the variable is given the length of 32,767. To save storage space, you can add a LENGTH statement to your DATA step, and specify an appropriate length for your variable. Because SAS sets the length of a new character variable the first time it is encountered in the DATA step, be sure to place the LENGTH statement before the assignment statements that contain the CATX function.

If the concatenation operator (||) returns a value to a variable that has not previously been assigned a length, then that variable is given a length that is the sum of the lengths of the values that are being concatenated.

Remember that you learned to use the TRIM function along with the concatenation operator to create one address variable that contains the values of the three variables Address, City, and Zip, and to remove extra blanks from the new values. You used the DATA step shown below.

data hrd.newtemp(drop=address city state zip); 
   set hrd.temp; 
   NewAddress=trim(address)||', '||trim(city)||', '||zip; 
run;

You can accomplish the same concatenation using only the CATX function.

You want to create the new variable NewAddress by concatenating the values of the Address, City, and Zip variables from the data set Hrd.Temp. You want to strip excess blanks from the old variables' values and separate the variable values with a comma and a space. The DATA step below uses the CATX function to create NewAddress.

data hrd.newtemp(drop=address city state zip); 
   set hrd.temp; 
   NewAddress=catx(', ',address,city,zip); 
run;

The revised DATA step creates the values that you would expect for NewAddress.

The INDEX function enables you to search a character value for a specified string. The INDEX function searches values from left to right, looking for the first occurrence of the string. It returns the position of the string's first character. If the string is not found, it returns a value of 0.

Suppose you want to search the values of the variable Job, which lists job skills. You want to create a data set that contains the names of all temporary employees who have word processing experience. The following figure shows a partial list of observations in the Hrd.Temp data set.

To search for the occurrences of the phrase “word processing” in the values of the variable Job, you write the INDEX function as shown below. Note that the character string is enclosed in quotation marks.

index(job,'word processing')

To create the new data set, include the INDEX function in a subsetting IF statement. Only those observations in which the function locates the string and returns a value greater than 0 are written to the data set.

data hrd.datapool; 
   set hrd.temp; 
   where index(job,'word processing') > 0; 
run;

Here is the data set that shows the temporary employees who have word processing experience. The program processed all of the observations in the Hrd.Temp data set.

Note that the INDEX function is case sensitive, so the character string that you search for must be specified exactly as it is recorded in the data set. For example, the INDEX function shown below would not locate any employees who have word-processing experience.

index(job,'WORD PROCESSING')

The FIND function enables you to search for a specific substring of characters within a specified character string.

The modifiers argument enables you to specify one or more modifiers for the function, as listed below.

Here are several facts about modifiers and constants.

If startpos is not specified, FIND starts the search at the beginning of the string and searches the string from left to right. If startpos is specified, the absolute value of startpos determines the position at which to start the search. The sign of startpos determines the direction of the search. That is, when startpos is positive, FIND searches from startpos to the right; when startpos is negative, FIND searches from startpos to the left.

The values of the variable Job are all lowercase. Therefore, to search for the occurrence of word processing in the values of the variable Job, you write the FIND function as shown below. Note that the character substring is enclosed in quotation marks.

find(job,'word processing')

To create the new data set, include the FIND function in a subsetting IF statement. Only those observations in which the function locates the string and returns a value greater than 0 are written to the data set.

data hrd.datapool; 
   set hrd.temp; 
   where find(job,'word processing') > 0; 
run;
proc print data=hrd.datapool;
run;

The TRANWRD function replaces or removes all occurrences of a word in a character string. The translated characters can be located anywhere in the string.

In a DATA step, if the TRANWRD function returns a value to a variable that has not previously been assigned a length, then that variable is given a length of 200 bytes. To save storage space, you can add a LENGTH statement to the DATA step and specify an appropriate length for the variable. SAS sets the length of a new character variable the first time it is encountered in the DATA step. Be sure to place the LENGTH statement before the assignment statements that contain the TRANWRD function.

You can use TRANWRD function to update variables in place. In this example, the function updates the values of Name by changing every occurrence of the string Monroe to Manson.

name=tranwrd(name,'Monroe','Manson')

Another example of the TRANWRD function is shown below. In this case, two assignment statements use the TRANWRD function to change all occurrences of Miss or Mrs. to Ms.

data hrd.after; 
   set hrd.before; 
   name=tranwrd(name,'Miss','Ms.'); 
   name=tranwrd(name,'Mrs.','Ms.'); 
run;
proc print data=work.after;
run;

The new data set is created. The TRANWRD function changes all occurrences of Miss or Mrs. to Ms.

The COMPRESS function returns a character string with specified characters removed from the original string. Null arguments are allowed and treated as a string with a length of zero.

The COMPRESS function returns a character string with specified characters removed from the original string.

Based on the number of arguments, the COMPRESS functions works as follows:

The COMPRESS function compiles a list of characters to keep or remove, comprising the characters in the second argument plus any types of characters that are specified by the modifiers. For example, the D modifier specifies digits. Both of the following function calls remove digits from the result:

compress(source, "1234567890");
compress(source, , "d");

To remove digits and plus or minus signs, you can use either of the following function calls:

compress(source, "1234567890+-");
compress(source, "+-", "d");