Each record in the file Data97 contains a sales representative's ID number, followed by four repeating fields that represent his or her quarterly sales totals for 1997. You want to pair each employee ID number with one quarterly sales total to produce a single observation. Four observations are generated from each record.

To accomplish this, you must execute the DATA step once for each record, repetitively reading and writing values in one iteration.

This means that a DATA step must do the following:

To read the value for ID and hold the record so that subsequent values for Sales can be read, submit the following code.

data perm.sales07; 
   infile data07; 
   input ID $

Recall that, in general, the trailing @@ holds the current record across multiple iterations of the DATA step.

However, in this case, you want to hold the record with the trailing @, so that a second INPUT statement can read the multiple sales values from a single record within the same iteration of the DATA step. Like the trailing @@, the single trailing @ can do the following:

To distinguish between the trailing @@ and the trailing @, remember the following:

In this example, the first INPUT statement reads the value for ID and uses the trailing @ to hold the current record for the next INPUT statement in the DATA step.

data perm.sales07; 
   infile data07; 
   input ID $ @; 
   input Sales : comma. @; 
output;

The second INPUT statement reads a value for Sales and holds the record. The COMMAw.d informat in the INPUT statement reads the numeric value for Sales and removes the embedded commas. An OUTPUT statement writes the observation to the SAS data set, and the DATA step continues processing.

When all of the repeating fields have been read and written to output, control returns to the top of the DATA step, and the record is released.

data perm.sales07; 
   infile data07; 
   input ID $ @; 
   input Sales : comma. @; 
   output; 
   input Sales : comma. @; 
   output; 
   input Sales : comma. @; 
   output; 
   input Sales : comma. @; 
   output; 
run;

Each record contains four different values for the variable Sales. Therefore, the INPUT statement must execute four times. Rather than writing four INPUT statements, you can execute one INPUT statement repeatedly in an iterative DO loop.

Each time the loop executes, you need to write the values for ID, Quarter, and Sales as an observation to the data set. This is easily accomplished by using the OUTPUT statement.

data perm.sales07; 
   infile data07; 
   input ID $ @; 
   do Quarter=1 to 4; 
      input Sales : comma. @; 
      output; 
   end; 
run;

By default, every DATA step contains an implicit OUTPUT statement at the end of the step. Placing an explicit OUTPUT statement in a DATA step overrides the automatic output, and SAS adds an observation to a data set only when the explicit OUTPUT statement is executed.

Now that the program is complete, here is how SAS processes a DATA step that contains an iterative DO loop.

data perm.sales07;  
   infile data07; 
   input ID $ @; 
   do Quarter=1 to 4; 
      input Sales : comma. @; 
      output; 
   end; 
run;

During the first iteration, the value for ID is read and Quarter is initialized to 1 as the loop begins to execute.

The INPUT statement reads the first repeating field and assigns the value to Sales in the program data vector. The @ holds the current record.

The OUTPUT statement writes the values in the program data vector to the data set as the first observation.

The END statement indicates the bottom of the loop, but control returns to the DO statement, not to the top of the DATA step. Now the value of Quarter is incremented to 2.

The INPUT statement executes again, reading the second repeating field and storing the value for Sales in the program data vector.

The OUTPUT statement writes the values in the program data vector as the second observation.

The loop continues executing while the value for Quarter is 3, and then 4. In the process, the third and fourth observations are written.

After the fourth observation is written, Quarter is incremented to 5 at the bottom of the DO loop and control returns to the top of the loop. The loop does not execute again because the value of Quarter is now greater than 4.

Control returns to the top of the DATA step, and the input pointer moves to column 1 of the next record. The variable values in the program data vector are reset to missing.

You can display the data set with the PRINT procedure.

proc print data=perm.sales07; 
run;