This example uses the data set below to create a summary variable, Total.

As you write the DATA step to read this file, think about performing several tasks. First, the value of Address must be retained as detail records are read and summarized.

data perm.residents; 
   infile census; 
   retain Address;

Next, the value of Type must be read in order to determine whether the current record is a header record or a detail record. You can add an @ to hold the record so that another INPUT statement can read the remaining values.

data perm.residents; 
   infile census; 
   retain Address; 
   input type $1. @;

When the value of Type indicates a header record, several statements need to be executed. When the value of Type indicates a detail record, you need to define an alternative set of actions.

To execute multiple SAS statements based on the value of a variable, you can use a simple DO group with an IF-THEN statement. When the condition Type='H' is true, several statements need to be executed.

data perm.residents; 
   infile census; 
   retain Address; 
   input type $1. @; 
   if type='H' then do;

When the value of type is not H, you need to define an alternative action. You can do this by adding an ELSE statement after the DO group.

Remember that the IF-THEN statement executes a SAS statement when the condition that is specified in the IF clause is true. By adding an ELSE statement after the IF-THEN statement, you define an alternative action to be performed when the IF condition is false.

data perm.residents; 
   infile census;  
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
      if _n_ > 1 then output; 
      Total=0; 
      input address $ 3-17; 
   end; 
   else

The only other type of record is a detail record, represented by a P. You want to count each person who is represented by a detail record and store the accumulated value in the summary variable Total. You do not need to read the values for Name, Age, and Gender.

data perm.residents; 
   infile census;  
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
      if _n_ > 1 then output; 
      Total=0; 
      input address $ 3-17; 
   end; 
   else if type='P' then

At this point, the value of Total has been initialized each time a header record is read and set to 0. Now, as each detail record is read, you can increment the value of Total by using a sum statement. In this example, you are counting the number of detail records for each header record. Therefore, you increment the value of Total by 1 when the value of type is P.

data perm.residents;   
   infile census;  
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
      if _n_ > 1 then output; 
      Total=0; 
      input address $ 3-17; 
   end; 
   else if type='P' then total+1;

else if type='B' then total+cost;

The program writes an observation to the data set only when another header record is read and the DATA step has executed more than once. But after the last detail record is read, there are no more header records to cause the last observation to be written to the data set.

data perm.residents; 
   infile census; 
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
      if _n_ > 1 then  
         output; 
      Total=0; 
      input address $ 3-17; 
   end; 
   else if type='P' 
        then total+1;

It is necessary to determine when the last record in the file is read so that you can then execute another explicit OUTPUT statement. You can determine when the current record is the last record in an external file by specifying the END= option in the INFILE statement.

In the following example, the END= variable is defined in the INFILE statement as Last. When Last has a value other than 0, the OUTPUT statement writes the final observation to the data set.

data perm.residents; 
   infile census end=last; 
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
    if _n_ > 1 then output; 
       Total=0; 
      input address $ 3-17; 
   end; 
   else if type='P' then total+1; 
   if last then output;

A DROP= option in the DATA statement drops the variable type from the data set, and a RUN statement completes the DATA step.

data perm.residents (drop=type); 
   infile census end=last; 
   retain Address; 
   input type $1. @; 
   if type='H' then do; 
      if _n_ > 1 then output; 
         Total=0; 
      input address $ 3-17; 
   end; 
   else if type='P' then total+1; 
   if last then output; 
run;