Creating SAS Data Sets from External Files explained how the PUT statement can be used with column output to write observations from a SAS data set to a raw data file. The PUT statement can also be used with list output to create free-format raw data files.

List output is similar to list input. With list output, you simply list the names of the variables whose values you want to write. The PUT statement writes a value, leaves a blank, and then writes the next value.

The following program creates the raw data file Findat, using the SAS data set sasuser.Finance. The DATEw. format is used to write the value of Date in the form DDMMYYYY.

data _null_; 
   set sasuser.finance; 
   file 'c:datafindat.txt'; 
   put ssn name salary date : date9.; 
run;
proc print data=sasuser.finance noobs;
run;

You can use the DLM= option with a FILE statement to create a character-delimited raw data file.

data _null_; 
   set sasuser.finance; 
   file 'c:datafindat2' dlm=','; 
   put ssn name salary date : date9.; 
run;

What happens if you need to create a comma-delimited file that requires the use of a format that writes out values using commas?

If you used the following program, the resulting raw data file would contain five fields rather than four.

data _null_;  
   set sasuser.finance;  
   file 'c:datafindat2' dlm=',';  
   put ssn name salary : comma6. date : date9.;  
run;

You can use the DSD option in the FILE statement to specify that data values that contain commas should be enclosed in quotation marks. Remember that the DSD option uses a comma as a delimiter, so a DLM= option is not necessary here.

data _null_;  
   set sasuser.finance;  
   file 'c:datafindat2' dsd;  
   put ssn name salary : comma. date : date9.;  
run;