Here are a SAS program and SAS data set that appeared earlier in this chapter.

data sasuser.stress; 
   infile tests; 
   input ID $ 1-4 Name $ 6-25 RestHR 27-29 MaxHR 31-33 
         RecHR 35-37 TimeMin 39-40 TimeSec 42-43 
         Tolerance $ 45; 
   if tolerance='D'; 
   TotalTime=(timemin*60)+timesec; 
run;

Notice that the data set has been modified with SAS statements. If you wanted to write the new observations to a raw data file, you could reverse the process that you have been following and write out the observations from a SAS data set as records or lines to a new raw data file.

Because the goal of your SAS program is to create a raw data file and not a SAS data set, it is inefficient to use a data set name in the DATA statement. Instead, use the keyword _NULL_, which enables you to use the DATA step without actually creating a SAS data set. A SET statement specifies the SAS data set that you want to read from.

data _null_; 
    set sasuser.stress;

The next step is to specify the output file.

You use the FILE and PUT statements to write the observations from a SAS data set to a raw data file, just as you used the INFILE and INPUT statements to create a SAS data set. These two sets of statements work almost identically.

When writing observations to a raw data file, use the FILE statement to specify the output file.

For example, if you want to read the Sasuser.Stress data set and write it to a raw data file that is referenced by the fileref Newdat, you would begin your program with the following SAS statements.

data _null_; 
   set sasuser.stress; 
   file newdat;
run;

Instead of identifying the raw data file with a SAS fileref, you can specify the entire filename and location in the FILE statement. For example, the following FILE statement points directly to the Z:sasuser ests.dat file. Note that the path specifying the filename and location must be enclosed in quotation marks.

data _null_; 
   set sasuser.stress; 
   file 'Z:sasuser	ests.dat';
run;

Whereas the FILE statement specifies the output raw data file, the PUT statement describes the lines to write to the raw data file.

In general, the PUT statement mirrors the capabilities of the INPUT statement. In this case you are working with column output. Therefore, you need to specify the variable name, starting column, and ending column for each field that you want to create. Because you are creating raw text data, the dollar sign ($) is optional.

data _null_; 
   set sasuser.stress; 
   file 'Z:sasuser	ests.dat'; 
   put id $ 1-4 name  6-25 resthr 27-29 maxhr 31-33
        rechr 35-37 timemin 39-40 timesec 42-43 
        tolerance 45 totaltime 47-49; 
run;

The resulting raw data file would look like this.