By default, DATA step match-merging combines all observations in all input data sets.

To exclude unmatched observations from your output data set, use the following in your DATA step:

To match-merge the data sets Clinic.Demog and Clinic.Visit and select only observations that appear in both data sets, use IN= to create two temporary variables, Indemog and Invisit. The IN= variable is a temporary variable that is available to program statements during the DATA step, but it is not included in the SAS data set that is being created.

The DATA step that contains the IN= options appears below. The first IN= creates the temporary variable indemog, which is set to 1 when an observation from Clinic.Demog contributes to the current observation. Otherwise, it is set to 0. Likewise, the value of Invisit depends on whether Clinic.Visit contributes to an observation or not.

data clinic.merged; 
   merge clinic.demog(in=indemog)  
         clinic.visit(in=invisit
                     rename=(date=BirthDate)); 
   by id; 
run;

To select only observations that appear in both Clinic.Demog and Clinic.Visit, specify a subsetting IF statement in the DATA step.

The subsetting IF statement checks the values of Indemog and Invisit and continues processing only those observations that meet the condition of the expression. The condition is that both Clinic.Demog and Clinic.Visit contribute to the observation. If the condition is met, the new observation is written to Clinic.Merged. Otherwise, the observation is deleted.

data clinic.merged; 
   merge clinic.demog(in=indemog  
                     rename=(date=BirthDate)) 
         clinic.visit(in=invisit 
                      rename=(date=VisitDate));  
   by id; 
   if indemog=1 and invisit=1; 
run; 
proc print data=clinic.merged; 
run;

In previous examples, Clinic.Merged contained 12 observations. In the output below, notice that only 10 observations met the condition in the IF expression.

SAS evaluates the expression within an IF statement to produce a result that is either nonzero, zero, or missing. A nonzero and nonmissing result causes the expression to be true; a zero or missing result causes the expression to be false.

It is possible to specify the subsetting IF statement from the previous example in either of the following ways. The first IF statement checks specifically for a value of 1. The second IF statement checks for a value that is neither missing nor 0 (which for IN= variables is always 1).

if indemog=1 and invisit=1;  

if indemog and invisit;