Once you have a generation group that contains more than one generation data set, you might want to select a particular data set to process. To select a particular generation, you use the GENNUM= data set option.

To print the current version of the data, you do not need to use the GENNUM= option. Simply use code such as the following:

proc print data=year;
run;

To print the youngest historical version, you have several choices. You can specify either the absolute or relative reference in the GENNUM= option, as shown:

proc print data=year(gennum=4);  /*absolute reference*/
run;

proc print data=year(gennum=-1);  /*relative reference*/
run;

You can also view information about a specific generation using the GENNUM= option with PROC CONTENTS, as shown:

proc contents data=year(gennum=-1);  /*relative reference*/
run;

Now that you have seen a few examples of using the GENNUM= option, consider how generation numbers change.

When you use the GENNUM= option, you can refer to either the absolute or relative generation number. It is helpful to understand how generation numbers change so that you can identify the generation that you want to process.

First, consider how SAS names generation data sets. The first time a data set with generations in effect is replaced, SAS keeps the replaced data set, and appends a four-character version number to its member name. The name includes the pound symbol (#) and a three-digit number. That is, for a data set named A, the replaced data set becomes A#001. When the data set is replaced for the second time, the replaced data set becomes A#002. That is, A#002 is the version that is chronologically closest to the base version. The table below shows the result after three replacements.

The limit for version numbers that SAS can append is #999. After 1000 replacements, SAS rolls over the youngest version number to #000.

Now we consider how absolute and relative generation numbers (specified on the GENNUM= option) change. Each time SAS creates a new generation, the absolute generation number increases sequentially. As older generations are deleted, their absolute generation numbers are retired.

In contrast, the relative generation number always refers to generations in relation to the base generation. The base or current generation is always 0 and -1 is the youngest historical version.

The following table shows data set names and their absolute and relative GENNUM= numbers.

You have learned that you use PROC DATASETS to initiate generation data sets on an existing SAS data set. Once you have created generation data sets, you can use PROC DATASETS to perform management tasks such as the following:

The following code uses the CHANGE statement to rename the data set SalesData to Sales. If generations have been created, the base name of all generations is renamed.

proc datasets library=quarter1 nolist;
   change salesData=sales;
quit;

The following code uses the GENNUM= option to rename only the second historical data set:

proc datasets library=quarter1 nolist;
   change sales(gennum=2)=newsales;
quit;

The following code deletes one historical version. This action might leave a hole in the generation group.

proc datasets library=quarter1 nolist;
   delete newsales(gennum=-1);
quit;

When you use the GENNUM= option with the DELETE statement, you can use the HIST and ALL keywords. The following code uses the HIST keyword to delete all of the historical versions:

proc datasets library=quarter1 nolist;
   delete newsales(gennum=HIST);
quit;

The following code uses the ALL keyword in the GENNUM= option to delete all of the SAS data sets in a generation group:

proc datasets library=quarter1 nolist;
   delete newsales(gennum=ALL);
quit;