This PROC MEANS step creates a report that displays the mean of the analysis variable Quantity for each value of the class variable Order_Type.

proc means data=retail.orders 
     (keep=order_type quantity)
     mean maxdec=2;
   class order_type;
   var quantity;
run;

PROC REPORT

This PROC REPORT step creates a report that displays the mean of the analysis variable Quantity for each value of the class variable Order_Type.

proc report data=retail.orders
     (keep=order_type quantity);
   column order_type quantity;
   define order_type / group width=13
          'Order Type';
   define quantity / mean format=5.2
          'Average Quantity'
          width=8;
run; 

This program uses a PROC SORT step and a DATA step to create a report. The PROC SORT step sorts the data by the values of the variable Order_Type, keeps only the necessary variables, and generates the temporary output data set Orders. The DATA step calculates the mean of the analysis variable Quantity for each value of the BY variable Order_Type and displays these values in a report.

proc sort data=retail.orders 
     (keep=order_type quantity)
     out=orders;
   by order_type;
run;

data _null_;
   set orders;
   by order_type;
   format average_order 5.2;
   if first.order_type then do;
      num=0;
      sum=0;
   end;
   num+1;
   sum+quantity;
   if last.order_type then do;
      average_order=sum / num;
      file print;
      put @5 'Order Type' @20 'Average Order';
      put;
      put @13 Order_type 1. @27 Average_order 5.2;
   end;
run;

This PROC SQL step creates a report that displays the mean of the analysis variable Quantity for each value of the group variable Order_Type.

proc sql;
   select order_type,
     avg(quantity) label='Average Order'
                   format=5.2
     from retail.orders
     group by order_type;
quit; 

This PROC TABULATE step creates a report that displays the mean of the analysis variable Quantity for each value of the class variable Order_Type.

proc tabulate data=retail.orders
     (keep=order_type quantity)
     format=comma8.2;
   class order_type;
   var quantity;
   table order_type, quantity*mean;
run; 

This program calculates the average employee salary for two 3-way combinations of the class variables Employee_Country, Department, Employee_Gender, and Section. The TYPES statement requests the two combinations. The program generates a report data set and an output data set named Summary.

proc means data=retail.organization mean;
   class employee_country department
         employee_gender section;
   var salary;
   types employee_country*department*employee_gender
         department*section*employee_gender;
   output out=summary
          n=employees
          mean=average;
run;

Each of the two PROC MEANS steps in this program calculates the average employee salary for a combination of three of the four class variables Employee_Country, Department, Employee_Gender, and Section. In each step, the NWAY option specifies that all three variables that are specified in the CLASS statement should be combined. The program generates two reports and two output data sets named Summary1 and Summary2.

proc means data=retail.organization nway;
   class employee_country department
         employee_gender;
   var salary;
   output out=summary1
          n=employees
          mean=average;
run;
	 
proc means data=retail.organization nway;
   class department section
         employee_gender;
   var salary;
   output out=summary2
          n=employees
          mean=average;
run;

This program calculates the average employee salary for two 3-way combinations of the class variables Employee_Country, Department, Employee_Gender, and Section. The WHERE= data set option in the OUTPUT statement specifies the two combinations by their _TYPE_ values. The program generates a report and an output data set named Summary3.

proc means data=retail.organization;
   class employee_country department
         employee_gender section;
   var salary;
   output out=summary3 (where=(_type_ in (7,14)))
          n=employees
          mean=average;
run;