Another way of permanently storing macros is to store a macro definition in a SOURCE entry in a SAS catalog. If you decide to store your macro programs in a SAS catalog, you must store each macro program in a separate SOURCE entry. It is a good idea to give each SOURCE entry the same name as the macro program that is stored within it. For example, a macro named Printit would be stored in a SOURCE entry that is also named Printit.

To store a macro definition as a SOURCE entry in a SAS catalog, you use the Save As Object window.

To save the Printit macro definition to the Sasuser.Mymacs catalog, perform these steps:

If you store your macros in a SAS catalog, you might want to view the contents of a particular catalog to see the macros that you have stored there. You can use the Explorer window to view the contents of a SAS catalog by navigating to the catalog and double clicking it. You can also use the CATALOG procedure to list the contents of a SAS catalog. The CONTENTS statement of the CATALOG procedure lists the contents of a catalog in the procedure output.

You can use PROC CATALOG to view all of the macros that are stored in the temporary Work.Sasmacr catalog, as follows:

proc catalog cat=work.sasmacr;
   contents;
   title "Default Storage of SAS Macros";
quit;

This PROC CATALOG step produces results that are similar to the output shown below. The macros that are actually listed are the macros that have been compiled during the current SAS session.

PROC CATALOG can display the names and attributes of compiled macros, but the macro definition itself cannot be viewed.

If you store a macro definition in a SOURCE entry of a SAS catalog, you can use the CATALOG access method in a FILENAME statement in conjunction with the %INCLUDE statement to insert the macro definition into a SAS program.

Suppose you have stored the following macro definition as a SOURCE entry in the SAS catalog Sasuser.Mymacs:

%macro prtlast;
   %if &syslast ne _NULL_ %then %do;
      proc print data=&syslast(obs=5);
         title "Listing of &syslast data set";
      run;
   %end
   %else
      %put No data set has been created yet.;
%mend;

You can use the CATALOG access method along with the %INCLUDE statement to compile the macro Prtlast. Then you can reference the macro later in the program.

filename prtlast catalog 'sasuser.mymacs.prtlast.source';
%include prtlast;
proc sort data=sasuser.courses out=bydays;
   by days;
run;
%prtlast

You can also use the CATALOG access method to reference multiple SOURCE entries as long as the entries are stored in the same SAS catalog.

Suppose you have two macros, named Prtlast and Sortlast, that are stored in a SAS catalog.

Catalog Entry: Sasuser.Mymacs.Prtlast.Source

%macro prtlast;
   %if &syslast ne _NULL_ %then %do;
      proc print data=&syslast(obs=5);
      title "Listing of &syslast data set";
      run;
   %end;
   %else
     %put No data set has been created yet.;
%mend;

Catalog Entry: Sasuser.Mymacs.Sortlast.Source

%macro sortlast(sortby);
   %if &syslast ne _NULL_ %then %do;
      proc sort data=&syslast out=sorted;
         by &sortby;
      run;
   %end;
   %else
     %put No data set has been created yet.;
%mend;

You can use the CATALOG access method in conjunction with the %INCLUDE statement to compile both macros. Then you can call the macros later in the program. In this example, assume that the macros have the same names as the SOURCE entries in which they are stored:

filename prtsort catalog 'sasuser.mymacs';
%include prtsort(prtlast) / source2;
%include prtsort(sortlast) / source2;

data current(keep=student_name course_title begin_date location);
   set sasuser.all;
   if year(begin_date)=2001;
   diff=year(today())-year(begin_date);
   begin_date=begin_date+(365*diff);
run;

%sortlast(begin_date)
%prtlast

This code produces the following output: