You have learned that the VALUE statement can associate a text label with a discrete numeric or character value. Suppose you want to insert text characters into a numeric value. For example, you might have stored phone numbers as numeric values like 1111231234 that you want to display as (111) 123-1234. You can use the PICTURE statement to create a template for printing numbers.

Pictures are specified with three types of characters:

Consider using digit selectors and message characters first. You learn about directives in a later topic.

Digit selectors are numerals (0 through 9) that define positions for numbers. If you use nonzero digit selectors, zeros are added to the formatted value as needed. If you use zeros as digit selectors, no zeros are added to the formatted value.

In the picture definitions below, you can see the difference between using nonzero digit selectors (99) and zero digit selectors (00) on the formatted values.

picture month 1-12='99';

picture month 1-12='00';

Message characters are nonnumeric characters that are printed as specified in the picture. They are inserted into the picture after the numeric digits are formatted. Digit selectors must come before message characters in the picture definition. The prefix option can be used to append text in front of any digits. In the picture definition below, the text string JAN consists of message characters.

picture month 1='99 JAN';

The following PICTURE statement contains both digit selectors and message characters. Because the RAINAMT. format has nonzero digit selectors, values are printed with leading zeros. The keyword OTHER is used to print values and message characters for any values that do not fall into a specified range.

proc format;
   picture rainamt
           0-2='9.99 slight'
           2<-4='9.99 moderate'
           4<-<10='9.99 heavy'
           other='999 check value';
run;
data rain;
   input Amount;
   datalines;
   4
   3.9
   20
   .5
   6
   ;
proc print data=rain;
   format amount rainamt.;
run;

The following output shows the values with the RAINAMT. format applied.

The final way to specify a picture is with a directive. Directives are special characters that you can use in the picture to format date, time, or datetime values. If you use a directive, you must specify the DATATYPE= option in the PICTURE statement. This option specifies that the picture applies to a SAS date, SAS time, or SAS datetime value.

The percent sign (%) followed by a letter indicates a directive. Directives that you can use to create a picture format are listed in the table below.

Although directives generally return numbers with no leading zeros, you can add 0 in the directive so that if a one-digit numeric value is returned, it is preceded by a 0.

As shown below, when you create a picture with directives, the number of characters inside quotation marks is the maximum length of the formatted value. You must add trailing blanks to the directive if your values contain more characters than the picture. The formatted value is truncated if you do not.

Suppose you want to display values for employee hire dates in the format dd-mmmyyyy (such as 25-JAN2000). This format requires spaces for 10 characters.

The following code creates this format. There are a few things that you should notice about the picture definition:

proc format;
   picture mydate
           low-high='%0d-%b%Y  ' (datatype=date);
run;

proc print data=sasuser.empdata 
     (keep=division hireDate lastName obs=5);
   format hiredate mydate.;
run;

The output below shows the values for HireDate formatted with the MYDATE. picture format.