When the DATA step contains a MODIFY statement, SAS writes the current observation to its original place in the SAS data set. This action occurs by default through an implied REPLACE statement at the bottom of the DATA step.

However, you can override this default behavior by explicitly adding the OUTPUT, REPLACE, or REMOVE statement.

Using OUTPUT, REPLACE, or REMOVE statements in a DATA step with a MODIFY statement can change the default replacement of observations. You can use these three statements together as long as the sequence is logical.

If the SAS data set Transaction has a variable named Code that has values of yes, no, and new, you can submit the following program in order to do one of the following:

data master;
   set transaction;
   modify master key = id;
   a = b;
   if code = 'no' then remove;
   else if code = 'yes' then replace;
   else if code = 'new' then output;
run;

When you use the MODIFY statement with a BY statement or KEY= option to update a data set, error checking is important for several reasons. The most important reason is that these tools use nonsequential access methods, so there is no guarantee that an observation is located so that it satisfies the request. Error checking enables you to perform updates or not, depending on the outcome of the I/O condition.

The automatic variable _IORC_ (Input Output Return Code) is created when you use the MODIFY statement with the BY statement or KEY= option. The value of _IORC_ is a numeric return code that indicates the status of the most recently executed I/O operation. Checking the value of this variable enables you to detect abnormal I/O conditions and direct execution in particular ways rather than having the application terminate abnormally.

Because the values of the _IORC_ automatic variable are internal and subject to change, %SYSRC, an autocall macro, was created to enable you to test for specific I/O conditions while protecting your code from future changes in _IORC_ values.

When you use %SYSRC, you can check the value of _IORC_ by specifying one of the mnemonics listed below.

Suppose you are using the MODIFY statement with the KEY= option to update a SAS data set. In the program below, when _IORC_ has the value _SOK, the observation is updated. When _IORC_ has the value _DSENOM, no matching observation is found, so the observation is appended to the data set by the OUTPUT statement and _ERROR_ is reset to 0 in the do group.

data master;
   set transaction;
   modify master key = id;
   if _IORC_=%sysrc(_sok) then
      do;
         a = b;
         replace;
      end;
   else
      if _IORC_=%sysrc(_dsenom) then
         do;
            output;
            _ERROR_ = 0;
         end;
run;