The CALL SYMPUTX routine does the following:

In the SYMPUTX routine, you use a literal string in the following places:

To use a literal with the SYMPUTX routine, you enclose the literal string in quotation marks.

You can assign the value of a DATA step variable as the value for a macro variable by using the DATA step variable's name as the second argument in a CALL SYMPUTX routine.

To use a DATA step variable as the value for a macro variable in a CALL SYMPUTX routine, place the name of the DATA step variable after the name of the macro variable, separated by a comma. You do not enclose the name of the DATA step variable in quotation marks.

This form of the CALL SYMPUTX routine creates a macro variable named macro-variable and assigns to it the current value of DATA-step-variable.

Using a DATA step variable as the second argument has these results:

Suppose you want the title to contain the course name and the course number, as well as the date on which the course was held. You also want the footnote to list the current amount of unpaid fees for the course.

This example creates three macro variables. The macro variable Csrname records the value of the DATA step variable Course_title. The macro variable date records the value of the DATA step variable Begin_date in MMDDYY10. format. Finally, the macro variable Due uses the values of the DATA step variables Paidup, Total, and Fee to record the current amount of unpaid fees in DOLLAR8. format. These macro variables are referenced later in the program in the TITLE and FOOTNOTE statements.

%let crsnum=3;
data revenue;
   set certadv.all end=final;
   where course_number=&crsnum;
   total+1;
   if paid='Y' then paidup+1;
   if final then do;
      call symputx('crsname',course_title);
      call symputx('date',put(begin_date,mmddyy10.));
      call symputx('due',put(fee*(total-paidup),dollar8.));
   end;
run;
proc print data=revenue;
   var student_name student_company paid;
   title "Fee Status for &crsname (#&crsnum) Held &date";
   footnote "Note: &due in Unpaid Fees";
run;

Use the CALL SYMPUTX routine with literal strings as both arguments in order to conditionally assign a value to the macro variable Foot based on values that are generated during DATA step execution.

options symbolgen pagesize=30;
%let crsnum=3;
data revenue;
   set certadv.all end=final;
   where course_number=&crsnum;
   total+1;
   if paid='Y' then paidup+1;
   if final then do;
   if paidup<total then do;
      call symputx('foot','Some Fees Are Unpaid');
   end;
   else do;
      call symputx('foot','All Students Have Paid');
   end;
end;
run;

proc print data=work.revenue;
   var student_name student_company paid;
   title "Payment Status for Course &crsnum";
   footnote "&foot";
run;

This time, the value that is assigned to Foot is either Some Fees Are Unpaid or All Students Have Paid, depending on the value of the DATA step variable Paidup, because the value is assigned during the execution of the DATA step. When you submit this code, you get the following output.

Once again, suppose you want to create a report about students who are enrolled in a particular course. This time, suppose you want to add a title that contains the course title and the course number, and you want to include a footnote that summarizes how many students have paid their fees.

In this example, a DATA step variable named Paidup records the number of students who have paid, and a DATA step variable named Total records the total number of students who are registered for the class. Macro variables are created to record the values of Paidup, the value of Total, and the value of Course_title. These macro variables are referenced later in the program.

%let crsnum=3;
data revenue;
   set certadv.all end=final;
   where course_number=&crsnum;
   total+1;
   if paid='Y' then paidup+1;
   if final then do;
      call symputx('numpaid',paidup);
      call symputx('numstu',total);
      call symputx('crsname',course_title);
   end;
run;
proc print data=revenue noobs;
   var student_name student_company paid;
   title "Fee Status for &crsname (#&crsnum)";
   footnote "Note: &numpaid Paid out of &numstu Students";
run;

This time, the footnote shows the correct information for how many students have paid.

Suppose you want to write a program that lists all of the scheduled dates for a particular course, using a macro variable to record the title of the course. You can use one call to the SYMPUTX routine to create a macro variable for each value of the DATA step variable Course_code and assign the corresponding value of Course_title to each macro variable. The macro processor creates a new macro variable for each observation. The new macro variable has the same name as the value of the data set variable Course_code for that observation. The value of the new macro variable is the value of the data set variable Course_title for that observation.

data _null_;
   set certadv.courses;
   call symputx(course_code,course_title);
run;
%put _user_;

GLOBAL A one:two-three four
GLOBAL C001 Basic Telecommunications
GLOBAL C002 Structured Query Language
GLOBAL C003 Local Area Networks
GLOBAL C004 Database Design
GLOBAL C005 Artificial Intelligence
GLOBAL C006 Computer Aided Design
GLOBAL CRSNAME Local Area Networks
GLOBAL CRSNUM 3
GLOBAL DELIM 
GLOBAL NUMPAID           14
GLOBAL NUMSTU           20
GLOBAL PATH C:Userscertadv
GLOBAL STRING william SMITH

%let crsid=C005;
proc print data=certadv.schedule noobs label;
   where course_code="&crsid";
   var location begin_date teacher;
   title1 "Schedule for &c005";
run;

%let crsid=C002;
proc print data=certadv.schedule noobs label;
   where course_code="&crsid";
   var location begin_date teacher;
   title1 "Schedule for &c002";
run;

Messages are written to the SAS log to alert you that automatic conversion has occurred. Remember that the CALL SYMPUTX routine automatically uses the BEST12. format for the conversion.

You might want to have explicit control over the numeric-to-character conversion. The PUT function returns a character string that is formed by writing a value with a specified format.

You can use the PUT function in the following ways:

Suppose you want to create a report that shows the amount of fees that are unpaid for a specific course. In the following example, you use the SYMPUTX routine to format the value of the numeric variable Begin_date with the MMDDYY10. format and assign that value to the macro variable Date. Then you also use another call to the SYMPUTX routine to format the result of an expression involving Fee, Total, and Paidup as a dollar amount and assign that value to the macro variable Due.

%let crsnum=3;
data revenue;
   set certadv.all end=final;
   where course_number=&crsnum;
   total+1;
   if paid='Y' then paidup+1;
   if final then do;
     call symputx('crsname',trim(course_title));
     call symputx('date',put(begin_date,mmddyy10.));
     call symputx('due',strip(put(fee*(total-paidup),dollar8.)));
   end;
run;

You can use the macro variables Date and Due in a PROC PRINT step to create your report. The values of these macro variables appear in the report with the formatting that you assigned to them when you created them.

proc print data=revenue;
   var student_name student_company paid;
   title "Fee Status for &crsname (#&crsnum) Held &date";
   footnote "Note: &due in Unpaid Fees";
run;