When you include positional parameters in a macro definition, a macro variable is automatically created for each parameter when you call the macro. To define macros that include positional parameters, you list the names of macro variables in the %MACRO statement of the macro definition. Positional parameters are so named because the order in which you specify them in a macro definition determines the order in which they are assigned values from the macro call. That is, when you call a macro that includes positional parameters, you specify the values of the macro variables that are defined in the parameters in the same order in which they are defined.

To call a macro that includes positional parameters, precede the name of the macro with a percent sign, and enclose the parameter values in parentheses. List the values in the same order in which the parameters are listed in the macro definition, and separate them with commas, as follows:

The following statements are true about the values listed in a macro call:

You can use positional parameters to create the macro variables Dsn and Vars in the Printdsn macro definition, as follows:

%macro printdsn(dsn,vars);
   proc print data=&dsn;
      var &vars;
   title "Listing of %upcase(&dsn) data set";
   run;
%mend;

In this case, when you call the Printdsn macro you assign values to the macro variables that are created in the parameters. In the following example, the value Certadv.Courses is assigned to the macro variable Dsn, and the value course_code course_title days is assigned to the macro variable Vars. Notice that the value for Dsn is listed first and the value for Vars is listed second, since this is the order in which they are listed in the macro definition.

%printdsn(certadv.courses,course_code course_title days)

%printdsn(,course_code course_title days)

You can also include keyword parameters in a macro definition. Like positional parameters, keyword parameters create macro variables. However, when you use keyword parameters to create macro variables, you specify the name, followed by the equal sign, and the value of each macro variable in the macro definition.

Keyword parameters can be listed in any order. Whatever value you assign to each parameter (or variable) in the %MACRO statement becomes its default value. Null values are allowed.

When you call a macro whose definition includes keyword parameters, you specify the keyword, followed by the equal sign, and the value for each parameter, in any order. If you omit a keyword parameter from the macro call, the keyword variable retains its default value, as follows:

%macro-name(keyword-1=value-1<,...,keyword-n=value-n>)

You can use keyword parameters to create the macro variables Dsn and Vars in the Printdsn macro. This example assigns a default value of Certadv.Courses to the macro variable Dsn and assigns a default value of course_code course_title days to the macro variable Vars:

%macro printdsn(dsn=certadv.courses,
               vars=
course_code course_title days);
   proc print data=&dsn;
      var &vars;
   title "Listing of %upcase(&dsn) data set";
   run;
%mend;

To call the Printdsn macro with a value of Certadv.Schedule for Dsn and a value of teacher course_code begin_date for Vars, issue the following call:

%printdsn(vars=teacher course_code begin_date, dsn=certadv.schedule)

To call the Printdsn macro with default values for the parameters (Certadv.Courses as the value for Dsn and course_code course_title days as the value for Vars), you could issue the following call:

%printdsn()

%printdsn(dsn=certadv.courses,vars=course_code course_title days)

You can also include a parameter list that contains both positional and keyword parameters in your macro definitions. All positional parameter variables in the %MACRO statement must be listed before any keyword parameter variable is listed.

Similarly, when you call a macro that includes a mixed parameter list, you must list the positional values before any keyword values, as follows:

%macro-name(value-1<,...,value-n>,
            keyword-1=value-1<,...,keyword-n=value-n>)

You can use a combination of positional and keyword parameters to create the macro variables in the Printdsn macro definition. This code uses a positional parameter to create the macro variable Dsn, and a keyword parameter to create the macro variable Vars:

%macro printdsn(dsn, vars=course_title course_code days);
   proc print data=&dsn;
      var &vars;
   title "Listing of %upcase(&dsn) data set";
   run;
%mend;

The following call to the Printdsn macro assigns the value Certadv.Schedule to the macro variable Dsn and assigns the value teacher location begin_date to the macro variable Vars. Notice that the value for Dsn is listed first, since Dsn is the positional parameter.

%printdsn(certadv.schedule, vars=teacher location begin_date)

Now, suppose you want to execute the Printdsn macro, assigning the default value course_title course_code days to the macro variable Vars and assigning the value Certadv.Courses to the macro variable Dsn. You could issue the following call:

%printdsn(certadv.courses)

Because this call omits the keyword parameter (Vars), the default value for that parameter is used.