The rules for indirect references for macro variables rules are as follows:

Suppose you want to write a PROC PRINT step that you can reuse without any modification to print information about each course. You can do this by using an indirect reference in the TITLE statement.

data _null_;
   set certadv.courses;
   call symputx(course_code,(course_title));
run;

%let crsid=C002;
proc print data=certadv.schedule noobs label;
   where course_code="&crsid";
   var location begin_date teacher;
   title1 "Schedule for ???";
run;

In the example above, the macro variable C002 (as created by the SYMPUTX routine) has a value of Structured Query Language. Therefore, the TITLE statement should reference a macro variable that resolves to Structured Query Language. Remember that you want this reference to be flexible enough to apply to any of the macro variables that the SYMPUTX routine creates, such as C003 or C004, by changing only the %LET statement.

To obtain the value that you want, you must indirectly reference the macro variable C002 through a reference to the macro variable Crsid. If the value of the macro variable Crsid is C002, the following process might seem to be correct:

This sequence seems to imply that you should use the reference &&crsid to convert the value of the macro variable Crsid to the corresponding course description. However, the indirect reference rules indicate that this is not the correct solution.

Here is the correct solution:

title1 "Schedule for &&&crsid";

You can create a series of macro variables, Teach1 to Teachn, each containing the name of the instructor who is assigned to a specific course.

options symbolgen;
data _null_;
   set certadv.schedule;
   call symputx(cats('teach',course_number),teacher);
run;

The CATS function converts numeric values to character strings and removes leading and trailing blanks before concatenation. The SYMPUTX call routine eliminates leading and trailing blanks from the macro variables and values.

Then, you can reference one of these variables when a course number is designated. If you designate a course number in a %LET statement, you can use multiple ampersands in order to create a reference to the Teachn macro variable that corresponds to the current course number.

%let crs=3;
proc print data=certadv.register noobs;
   where course_number=&crs;
   var student_name paid;
   title1 "Roster for Course &crs";
   title2 "Taught by &&teach&crs";
run;

SYMBOLGEN:  Macro variable CRS resolves to 3
SYMBOLGEN:  Macro variable CRS resolves to 3
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable CRS resolves to 3
SYMBOLGEN:  Macro variable TEACH3 resolves to Forest, Mr. Peter