Remember that when a macro is compiled, it is stored in the temporary SAS catalog Work.Sasmacr by default. You can also store compiled macros in a permanent SAS catalog. Then you can use the Stored Compiled Macro Facility to access permanent SAS catalogs that contain compiled macros.

There are several advantages to using stored compiled macros:

Two SAS system options affect stored compiled macros: MSTORED and SASMSTORE=. The MSTORED system option controls whether the Stored Compiled Macro Facility is available.

The SASMSTORE= system option controls where the macro facility looks for stored compiled macros.

The MSTORED and SASMSTORE= system options can be set either at SAS invocation or with an OPTIONS statement during program execution.

To create a permanently stored compiled macro, you must do the following:

There are several restrictions on stored compiled macros.

An alternative to saving your source program separately from the stored compiled macro is to use the SOURCE option in the %MACRO statement to combine and store the source of the compiled macro with the compiled macro code. The SOURCE option requires that the STORE option and the MSTORED option be set. The %MACRO statement below shows the correct syntax for using the SOURCE option.

%macro macro-name<(parameter list)> /STORE SOURCE;

The source code that is saved by the SOURCE option begins with the %MACRO keyword and ends with the semicolon following the %MEND statement.

Suppose you want to store the Words macro in compiled form in a SAS library. This example shows the macro definition for Words. The macro takes a text string, divides it into words, and creates a series of macro variables to store each word.

Notice that both the STORE option and the SOURCE option are used in the macro definition so that Words is permanently stored as a compiled macro and the macro source code is stored with it, as follows:

libname macrolib 'c:storedlib';
options mstored sasmstore=macrolib;

%macro words(text,root=w,delim=%str( ))/store source;
   %local i word;
   %let i=1;
   %let word=%scan(&text,&i,&delim);
   %do %while (&word ne );
      %global &root&i;
      %let &root&i=&word;
      %let i=%eval(&i+1);
      %let word=%scan(&text,&i,&delim);
   %end;
   %global &root.num;
   %let &root.num=%eval(&i-1);
%mend words;

If the Sasmacr catalog does not exist in the Macrolib library, it is automatically created. You can list the contents of the Macrolib.Sasmacr catalog to verify that the compiled macro was created, as follows:

proc catalog cat=macrolib.sasmacr;
   contents;
   title "Stored Compiled Macros";
quit;

Here is the output from the PROC CATALOG step if no other compiled macros are stored in Macrolib.Sasmacr.

In order to access a stored compiled macro, you must do the following:

The following program calls the Words macro. Assume that the Words macro was compiled and stored in an earlier SAS session.

libname macrolib 'c:storedlib';
options mstored sasmstore=macrolib;

%words(This is a test)
%put Number of Words (wnum): &wnum;
%put Word Number 1 (w1): &w1;
%put Word Number 2 (w2): &w2;
%put Word Number 3 (w3): &w3;
%put Word Number 4 (w4): &w4;

Here is a portion of the messages that are written to the SAS log when this code is submitted.

9    libname macrolib 'c:storedlib';
NOTE: Libref MACROLIB was successfully assigned as follows:
      Engine:        V9
      Physical Name: c:storedlib
10       options mstored sasmstore=macrolib;
11
12       %words(This is a test)
13       %put Number of Words (wnum): &wnum;
Number of Words (wnum): 4
14       %put Word Number 1 (w1): &w1;
Word Number 1 (w1): This
15       %put Word Number 2 (w2): &w2;
Word Number 2 (w2): is
16       %put Word Number 3 (w3): &w3;
Word Number 3 (w3): a
17       %put Word Number 4 (w4): &w4;
Word Number 4 (w4): test

If you use the SOURCE option of the %MACRO statement to store your macro source code along with the stored compiled macro, you can use the %COPY statement to access the stored source code.

Suppose you submitted the program below to create a stored compiled macro named Words.

libname macrolib 'c:storedlib';
options mstored sasmstore=macrolib;

%macro words(text,root=w,delim=%str( ))/store source;
   %local i word;
   %let i=1;
   %let word=%scan(&text,&i,&delim);
   %do %while (&word ne );
      %global &root&i;
      %let &root&i=&word;
      %let i=%eval(&i+1);
      %let word=%scan(&text,&i,&delim);
      %end;
   %global &root.num;
   %let &root.num=%eval(&i-1);
%mend words;

The %COPY statement writes the source code for the Words macro to the SAS log. Here is an example:

%copy words/source;

The partial SAS log below shows the source code of the Words macro.

17     %copy words/source;
%macro words(text,root=w,delim=%str( ))/store source;

        %local i word;
        %let i=1;
        %let word=%scan(&text,&i,&delim);
        %do %while (&word ne );
           %global &root&i;
           %let &root&i=&word;
           %let i=%eval(&i+1);
           %let word=%scan(&text,&i,&delim);
        %end;
        %global &root.num;
        %let &root.num=%eval(&i-1);
%mend words;

The Stored Compiled Macro Facility can be used in conjunction with the Autocall Facility and with session-compiled macros. When you submit a macro call such as %words, the macro processor searches for the macro Words as