5.4. Factorial Designs
When the treatment combinations are made up of various levels of several factors, then both the multivariate and univariate approaches are generalized in a straightforward way. It is so because all these situations can still be dealt within the general framework of multivariate linear model. Also, the assumption of compound symmetry of covariance structure needed in the univariate analysis is on the error. Therefore, what design has been used for data collection does not affect the univariate approach. For the multivariate approach, the MANOVA partitioning of the total sums of squares and crossproduct matrix has been seen to be the straightforward generalization of the univariate ANOVA and therefore the multivariate approach essentially parallels that for the univariate ANOVA. This similarity has already been discussed in Chapters 3 and 4. We illustrate the approach for the factorial designs using a three-factor experiment originally discussed by Box (1950).
EXAMPLE 7
A Two-Way Factorial Experiment, Abrasion Data Box (1950) presented data on fabric weight loss due to abrasion. Some of the fabrics were given a surface treatment (SURFTRT) and some were not, leading to two levels, YES and NO, for SURFTRT. Two fillers (FILL) A and B were used at three proportions (PROP), namely, 25\%, 50\%, and 75\%, and the weight losses were recorded at three successive periods, each after 1000 revolutions of the machine which tested the abrasion resistance. Two replicates for each treatment combination in this 2× 2× 3 factorial experiment were obtained. Program 5.11 performs the multivariate as well as the univariate analysis of the data.
The repeated measures are taken with respect to the increasing number of revolutions (REVOLUTN). The corresponding values of the dependent variable weight loss are denoted by Y1, Y2, and Y3. We first fit the multivariate model with all main variables and two- and three-factor interactions. The standard MANOVA (not shown) indicates that SURFTRT, FILL, SURFTRT*FILL, PROP, and FILL*PROP are all highly significant. For illustration we examine only the profiles corresponding to variable PROP. Thus, all the comparisons are about the average weight losses due to various proportions of the fillers. The three sequential hypotheses to be tested are, are the PROP profiles parallel? given that they are parallel, are the PROP profiles coincidental? given that they are coincidental, are the PROP profiles horizontal?
Each of these three hypotheses is specified as LBM = 0 in the linear model setup with the specific choices of matrices of L and M in the three hypotheses. Since the three hypotheses are about the variable PROP only, the L matrix is specified by using the CONTRAST statement with PROP as the variable of interest. The M matrices are appropriately defined with the M= specification on the MANOVA statement. Specifically, the SAS statements specifying L and M for each hypothesis are listed below.
Are the PROP profiles parallel?
contrast '"prop-parallel?"' prop 1 0 -1,
prop 0 1 -1;
manova h=prop m=(1 -1 0,
1 0 -1);Given that they are parallel, are the PROP profiles coincidental?
contrast '"prop-coincidental?"' prop 1 0 -1
prop 0 1 -1;
manova h=prop m=(1 1 1);Given that they are coincidental, are the PROP profiles horizontal?
contrast '"prop-horizontal?"' intercept 1;
manova h=prop m=(1 -1 0,
1 0 -1);/* Program 5.11 */
options ls=64 ps=45 nodate nonumber;
title1 ' Output 5.11';
data box;
infile 'box.dat';
input surftrt $ fill $ prop y1 y2 y3 ;
title2 'Repeated Measures in Factorials: Tire Wear Data';
proc glm data = box;
class surftrt fill prop;
model y1 y2 y3 =surftrt|fill|prop/nouni;
contrast '"prop-parallel?"' prop 1 0 -1,
prop 0 1 -1;
contrast '"prop-horizontal?"' intercept 1;
manova h=prop m= (1 -1 0, 1 0 -1)/printe printh;
contrast '"prop-concidental?"' prop 1 0 -1,
prop 0 1 -1 ;
manova h = prop m=(1 1 1) /printe printh;
run;
proc glm data = box;
class surftrt fill prop;
model y1 y2 y3 = surftrt|fill|prop/ nouni ;
repeated revolutn 3 polynomial/summary printm printe ;
title2 'Univariate Split Plot Analysis of Tire Wear Data';
run;
data boxsplit;
set box;
array yy{3} y1-y3;
subject+1;
do time=1 to 3;
y=yy(time);
output;
end;
run;
proc mixed data = boxsplit method = reml ;
class surftrt fill prop subject;
model y = surftrt fill prop surftrt*fill surftrt*prop
fill*prop surftrt*time fill*time prop*time
surftrt*fill*time surftrt*prop*time fill*prop*time/chisq;
repeated /type = ar(1) subject = subject r ;
title2 'Analysis of Tire Wear Data Using PROC MIXED';
run;Example 5.11. Output 5.11
Repeated Measures in Factorials: Tire Wear Data
General Linear Models Procedure
Multivariate Analysis of Variance
Manova Test Criteria and F Approximations for
the Hypothesis of no Overall "prop-parallel?" Effect
on the variables defined by the M Matrix Transformation
H = Contrast SS&CP Matrix for "prop-parallel?"
E = Error SS&CP Matrix
S=2 M=-0.5 N=4.5Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.469985 2.5227 4 22 0.0701
Pillai's Trace 0.550475 2.2786 4 24 0.0904
Hotelling-Lawley Trace 1.084195 2.7105 4 20 0.0594
Roy's Greatest Root 1.042434 6.2546 2 12 0.0138
NOTE: F Statistic for Roy's Greatest Root is an upper bound.
NOTE: F Statistic for Wilks' Lambda is exact.
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no Overall "prop-concidental?" Effect
on the variables defined by the M Matrix Transformation
H = Contrast SS&CP Matrix for "prop-concidental?"
E = Error SS&CP Matrix
S=1 M=0 N=5
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.216071 21.769 2 12 0.0001
Pillai's Trace 0.783929 21.769 2 12 0.0001
Hotelling-Lawley Trace 3.628115 21.769 2 12 0.0001
Roy's Greatest Root 3.628115 21.769 2 12 0.0001
Univariate Split Plot Analysis of Tire Wear Data
General Linear Models Procedure
Repeated Measures Analysis of Variance
Univariate Tests of Hypotheses for Within Subject Effects
Source: REVOLUTN
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 60958.5278 30479.2639 160.68 0.0001 0.0001 0.0001
Source: REVOLUTN*SURFTRT
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 8248.0278 4124.0139 21.74 0.0001 0.0001 0.0001
Source: REVOLUTN*FILL
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 18287.6944 9143.8472 48.20 0.0001 0.0001 0.0001
Source: REVOLUTN*SURFTRT*FILL
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 2328.0833 1164.0417 6.14 0.0070 0.0111 0.0070
Source: REVOLUTN*PROP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
4 1762.8056 440.7014 2.32 0.0857 0.1002 0.0857Source: REVOLUTN*SURFTRT*PROP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
4 685.9722 171.4931 0.90 0.4772 0.4658 0.4772
Source: REVOLUTN*FILL*PROP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
4 1415.6389 353.9097 1.87 0.1493 0.1633 0.1493
Source: REVOLUTN*SURFTRT*FILL*PROP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
4 465.9167 116.4792 0.61 0.6566 0.6308 0.6566
Source: Error(REVOLUTN)
DF Type III SS Mean Square
24 4552.6667 189.6944
Greenhouse-Geisser Epsilon = 0.8384
Huynh-Feldt Epsilon = 1.8522
Analysis of Variance of Contrast Variables
REVOLU.N represents the nth degree
polynomial contrast for REVOLUTN
Contrast Variable: REVOLU.1
Source DF Type III SS F Value Pr > F
MEAN 1 60705.18750000 565.91 0.0001
SURFTRT 1 7676.02083333 71.56 0.0001
FILL 1 9436.02083333 87.96 0.0001
SURFTRT*FILL 1 1938.02083333 18.07 0.0011
PROP 2 1035.12500000 4.82 0.0290
SURFTRT*PROP 2 191.54166667 0.89 0.4350
FILL*PROP 2 260.54166667 1.21 0.3309
SURFTRT*FILL*PROP 2 255.79166667 1.19 0.3371
Error 12 1287.25000000
Contrast Variable: REVOLU.2
Source DF Type III SS F Value Pr > F
MEAN 1 253.34027778 0.93 0.3536
SURFTRT 1 572.00694444 2.10 0.1727
FILL 1 8851.67361111 32.53 0.0001
SURFTRT*FILL 1 390.06250000 1.43 0.2543
PROP 2 727.68055556 1.34 0.2991
SURFTRT*PROP 2 494.43055556 0.91 0.4292
FILL*PROP 2 1155.09722222 2.12 0.1625
SURFTRT*FILL*PROP 2 210.12500000 0.39 0.6879
Error 12 3265.41666667Analysis of Tire Wear Data Using PROC MIXED
The MIXED Procedure
R Matrix for SUBJECT 1
Row COL1 COL2 COL3
1 368.56581667 -166.1922475 74.93875414
2 -166.1922475 368.56581667 -166.1922475
3 74.93875414 -166.1922475 368.56581667 |
Output 5.11 shows that while the null hypothesis of parallel profiles for PROP is not rejected at 5\% level of significance (with a p value for Wilks' Λ equal to 0.0701), the hypothesis of coincidental profiles is rejected with Λ=0.2161 (leading to an observed value of F (2,12) as 21.769 which corresponds to a very small p value of 0.0001).
To perform the univariate split plot analysis, we use the REPEATED statement. The corresponding time variable is defined here as REVOLUTN as the repeated measures are taken for the three increasing numbers of revolutions, namely, 1,000, 2,000, and 3,000. If we are interested in studying the effects of various orthogonal polynomial contrasts, we must choose the POLYNOMIAL transformation for the type of orthogonal contrasts. The corresponding SAS statement is
repeated revolutn 3 polynomial;
In Program 5.11 we have made certain other choices such as printing the corresponding E and M matrices and only summary output. The M matrix here is a 2 by 3 matrix of first- and second-degree orthogonal polynomial coefficients and the 2 by 2 matrix E is the matrix of the corresponding error SS&CP.
Output 5.11 shows that the interaction REVOLUTN*SURFTRT*FILL is highly sig-nificant (with a p value = 0.0070) and respective interactions of REVOLUTN with SURFTRT and FILL are very highly significant (both p values = 0.0001). The interaction of REVOLUTN with PROP is only marginally significant (p value = 0.0857). This indicates that the abrasion curves for various levels of the variables SURFTRT, FILL, and PROP are not parallel. The univariate F tests adjusted by using 
(= 0.8384) or 
(= 1.0, since it cannot exceed 1) for various interactions with REVOLUTN lead to the same conclusions. These adjustments, however, may not be necessary as Mauchly's test for the sphericity of orthogonal contrasts provides sufficient evidence (p value = 0.3079) to assume sphericity. This part has not been included in Output 5.11.
The tests on the linear and quadratic contrasts respectively denoted by REVOLUTN.1 and REVOLUTN.2 reveal that the quadratic contrast is not significant for any effect or interaction except FILL (p value = 0.0001). However, the linear contrast is significant for all main variables and the SURFTRT*FILL interaction. The data can also be analyzed under various covariance structures, other than compound symmetry using the MIXED procedure which will be discussed in detail in Chapter 6. While most of the output has been suppressed, the appropriate statements under AR(1) covariance structure and REML estimation procedure are included in Program 5.11. One especially interesting observation is that some of the off-diagonal elements of the estimates of the R matrix (referred to as Σsubject in the previous example) are negative. Normally we would not expect the negative correlations between the repeated measures of these weight losses. Lindsey (1993, p. 83) interprets such an occurrence as evidence of a situation where there is a greater variability within the experiment or subject than among the experiments or subjects.
EXAMPLE 8
Two-Factor Experiment with Both Repeated Measures Factors In a factorial design, if there are repeated measures on more than two variables then the analysis of the previous section can be applied in a straightforward manner. For example, consider this example: three participants in an experiment were given a large amount of a sleep-inducing drug on the day before the experiment. The next day, they were given placebos. The participants were tested in the morning (AM) and afternoon (PM) of the two different days. Each participant was given a stimulus, and his or her reaction (the response variable) was timed. See Cody and Smith (1991, p. 182). The problem considered here is to determine whether the drug had any effect on the reaction time and the effects are the same for AM and PM.
Since each subject is measured under two levels of TIME (AM, PM) and for two levels of DRUG (DRUG1 (Placebo), DRUG2), it is a 2 by 2 factorial experiment with both TIME and DRUG as repeated measures variables or repeated measures factors. The data are given below and the SAS code for analyzing these data is given in Program 5.12.
| DRUG1 | DRUG1 | DRUG2 | DRUG2 | |
|---|---|---|---|---|
| SUBJECT | AM | PM | AM | PM |
| 1 | 77 | 67 | 82 | 72 |
| 2 | 84 | 76 | 90 | 80 |
| 3 | 102 | 92 | 109 | 97 |
Both the univariate and multivariate analysis are performed using the SAS statement
repeated drug 2, time 2;
One important thing to remember is that the order in which the variables are written in the REPEATED statement and the order in which data are presented in the INPUT statement must correspond. For every level of variable DRUG there are two levels of the variable TIME and the REPEATED statement given above reads exactly that way. That is, level 1 of variable DRUG and levels 1 and 2 of variable TIME are selected first, level 2 of variable DRUG and levels 1 and 2 of variable TIME are selected next, and so on. The logic behind writing the variables in the REPEATED statement is the same as the logic behind nested DO loops.
/* Program 5.12 */
option ls=64 ps=45 nodate nonumber;
title1 'Output 5.12';
title2 'Analysis with Two Repeated Factors';
data react;
input y1 y2 y3 y4;
lines;
77 67 82 72
84 76 90 80
102 92 109 97
;
proc glm;
model y1-y4= /nouni;
repeated drug 2, time 2;
run;Example 5.12. Output 5.12
Analysis with Two Repeated Factors
General Linear Models Procedure
Repeated Measures Analysis of Variance
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no DRUG Effect
H = Type III SS&CP Matrix for DRUG E = Error SS&CP MatrixS=1 M=-0.5 N=0
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.007752 256 1 2 0.0039
Pillai's Trace 0.992248 256 1 2 0.0039
Hotelling-Lawley Trace 128 256 1 2 0.0039
Roy's Greatest Root 128 256 1 2 0.0039
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no TIME Effect
H = Type III SS&CP Matrix for TIME E = Error SS&CP Matrix
S=1 M=-0.5 N=0
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.006623 300 1 2 0.0033
Pillai's Trace 0.993377 300 1 2 0.0033
Hotelling-Lawley Trace 150 300 1 2 0.0033
Roy's Greatest Root 150 300 1 2 0.0033
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no DRUG*TIME Effect
H = Type III SS&CP Matrix for DRUG*TIME E = Error SS&CP Matrix
S=1 M=-0.5 N=0
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.333333 4 1 2 0.1835
Pillai's Trace 0.666667 4 1 2 0.1835
Hotelling-Lawley Trace 2 4 1 2 0.1835
Roy's Greatest Root 2 4 1 2 0.1835 |
An examination of Output 5.12 reveals that there is no interaction between the variables TIME and DRUG (p value = 0.1835). However, the variable DRUG with a p value of 0.0039 and the variable TIME with a p value of 0.0033 are both highly significant.
Three-Factor Experiment with Two Repeated Measures Factors In an educational testing program, students from two groups, namely, those with relatively higher socioeconomic status (GP1) and with lower socioeconomic status (GP2), were tested and their scores in the tests recorded. See Cody and Smith (1991, pp. 194–195). The study was conducted for three years (denoted by 1, 2, and 3) during each of the two seasons, FALL and SPRING, for a group of 10 students. Each group consisted of five subjects. In this setup there are three variables, namely, GROUP, YEAR, and SEASON. Repeated measures on each of the ten subjects are available for the variables YEAR and SEASON. In that sense, YEAR and SEASON are two repeated measures variables.
The three problems of interest are to test
whether students do better on a reading comprehension test in the Spring than in the Fall,
whether the differences in the mean scores become negligible as students get older,
whether these differences in the mean scores are more prominent for one socio-economic group than the other.
In order to find answers to these problems, we first determine whether there are significant main effects and interactions. Once that is determined, if needed, we can perform an analysis of the means, applying multiple comparison techniques, to conduct pairwise differences between the variables. However, we restrict ourselves to the determination of the significance of the main effects and their interactions. We assume that the underlying variances of responses for both seasons and for all three years are the same. The data and SAS code are given in Program 5.13 and the corresponding output in Output 5.13. The REPEATED statement is used to perform both the multivariate and univariate analyses.
/* Program 5.13 */
options ls=64 ps=45 nodate nonumber;
title1 'Output 5.13';
title2 'Three Factors Case with Two Repeated Factors';
data read;
input group y1-y6;
lines;
1 61 50 60 55 59 62
1 64 55 62 57 63 63
1 59 49 58 52 60 58
1 63 59 65 64 67 70
1 62 51 61 56 60 63
2 57 42 56 46 54 50
2 61 47 58 48 59 55
2 55 40 55 46 57 52
2 59 44 61 50 63 60
2 58 44 56 49 55 49
;
/* Source: Cody, R. P./Smith, J. K. APPLIED STATISTICS AND SAS
PROGRAMMING LANGUAGE, 3/E, 1991, p. 194. Reprinted by permission of
Prentice-Hall, Inc. Englewood Cliffs, N.J. */
proc glm data=read;
class group;
model y1-y6=group/nouni;
repeated year 3, season 2;
run;
proc glm data=read;
class group;
model y1-y6=group/nouni;
repeated year 3(1 2 3) polynomial,
season 2/summary nom nou;
run;Example 5.13. Output 5.13
Three Factors Case with Two Repeated Factors
General Linear Models Procedure
Repeated Measures Analysis of Variance
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no YEAR Effect
H = Type III SS&CP Matrix for YEAR E = Error SS&CP Matrix
S=1 M=0 N=2.5
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.195582 14.395 2 7 0.0033
Pillai's Trace 0.804418 14.395 2 7 0.0033Hotelling-Lawley Trace 4.112941 14.395 2 7 0.0033
Roy's Greatest Root 4.112941 14.395 2 7 0.0033
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no YEAR*GROUP Effect
H = Type III SS&CP Matrix for YEAR*GROUP
E = Error SS&CP Matrix
S=1 M=0 N=2.5
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.96176 0.1392 2 7 0.8724
Pillai's Trace 0.03824 0.1392 2 7 0.8724
Hotelling-Lawley Trace 0.03976 0.1392 2 7 0.8724
Roy's Greatest Root 0.03976 0.1392 2 7 0.8724
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no SEASON Effect
H = Type III SS&CP Matrix for SEASON E = Error SS&CP Matrix
S=1 M=-0.5 N=3
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.034362 224.82 1 8 0.0001
Pillai's Trace 0.965638 224.82 1 8 0.0001
Hotelling-Lawley Trace 28.10193 224.82 1 8 0.0001
Roy's Greatest Root 28.10193 224.82 1 8 0.0001
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no SEASON*GROUP Effect
H = Type III SS&CP Matrix for SEASON*GROUP
E = Error SS&CP Matrix
S=1 M=-0.5 N=3
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.177593 37.047 1 8 0.0003
Pillai's Trace 0.822407 37.047 1 8 0.0003
Hotelling-Lawley Trace 4.630854 37.047 1 8 0.0003
Roy's Greatest Root 4.630854 37.047 1 8 0.0003
Manova Test Criteria and Exact F Statistics for
the Hypothesis of no YEAR*SEASON Effect
H = Type III SS&CP Matrix for YEAR*SEASON
E = Error SS&CP Matrix
S=1 M=0 N=2.5
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.037144 90.727 2 7 0.0001
Pillai's Trace 0.962856 90.727 2 7 0.0001
Hotelling-Lawley Trace 25.92199 90.727 2 7 0.0001
Roy's Greatest Root 25.92199 90.727 2 7 0.0001Manova Test Criteria and Exact F Statistics for
the Hypothesis of no YEAR*SEASON*GROUP Effect
H = Type III SS&CP Matrix for YEAR*SEASON*GROUP
E = Error SS&CP Matrix
S=1 M=0 N=2.5
Statistic Value F Num DF Den DF Pr > F
Wilks' Lambda 0.916038 0.3208 2 7 0.7357
Pillai's Trace 0.083962 0.3208 2 7 0.7357
Hotelling-Lawley Trace 0.091658 0.3208 2 7 0.7357
Roy's Greatest Root 0.091658 0.3208 2 7 0.7357
Repeated Measures Analysis of Variance
Tests of Hypotheses for Between Subjects Effects
Source DF Type III SS F Value Pr > F
GROUP 1 680.0666667 13.54 0.0062
Error 8 401.6666667
Univariate Tests of Hypotheses for Within Subject Effects
Source: YEAR
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 252.033333 126.016667 26.91 0.0001 0.0002 0.0001
Source: YEAR*GROUP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 1.033333 0.516667 0.11 0.8962 0.8186 0.8700
Source: Error(YEAR)
DF Type III SS Mean Square
16 74.933333 4.683333
Greenhouse-Geisser Epsilon = 0.6757
Huynh-Feldt Epsilon = 0.8658
Source: SEASON
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
1 680.066667 680.066667 224.82 0.0001 . .
Source: SEASON*GROUP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
1 112.066667 112.066667 37.05 0.0003 . .
Source: Error(SEASON)
DF Type III SS Mean Square
8 24.200000 3.025000Source: YEAR*SEASON
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 265.433333 132.716667 112.95 0.0001 0.0001 0.0001
Source: YEAR*SEASON*GROUP
Adj Pr > F
DF Type III SS Mean Square F Value Pr > F G-G H-F
2 0.433333 0.216667 0.18 0.8333 0.7592 0.8168
Source: Error(YEAR*SEASON)
DF Type III SS Mean Square
16 18.800000 1.175000
Greenhouse-Geisser Epsilon = 0.7073
Huynh-Feldt Epsilon = 0.9221
Analysis of Variance of Contrast Variables
YEAR.N represents the nth degree polynomial contrast for YEAR
Contrast Variable: YEAR.1
Source DF Type III SS F Value Pr > F
MEAN 1 490.05000000 31.06 0.0005
GROUP 1 1.25000000 0.08 0.7855
Error 8 126.20000000
Contrast Variable: YEAR.2
Source DF Type III SS F Value Pr > F
MEAN 1 14.01666667 4.74 0.0612
GROUP 1 0.81666667 0.28 0.6135
Error 8 23.66666667
SEASON.N represents the contrast between the
nth level of SEASON and the last
Contrast Variable: SEASON.1
Source DF Type III SS F Value Pr > F
MEAN 1 4080.40000000 224.82 0.0001
GROUP 1 672.40000000 37.05 0.0003
Error 8 145.20000000
YEAR.N represents the nth degree polynomial contrast for YEAR
SEASON.N represents the contrast between the
nth level of SEASON and the last
Contrast Variable: YEAR.1*SEASON.1Source DF Type III SS F Value Pr > F MEAN 1 530.45000000 157.17 0.0001 GROUP 1 0.05000000 0.01 0.9061 Error 8 27.00000000 Contrast Variable: YEAR.2*SEASON.1 Source DF Type III SS F Value Pr > F MEAN 1 0.41666667 0.31 0.5903 GROUP 1 0.81666667 0.62 0.4550 Error 8 10.60000000 |
The multivariate tests indicate that the YEAR*SEASON*GROUP and YEAR*GROUP interactions are not significant (p values are 0.7357 and 0.8724 respectively) whereas, YEAR and SEASON have significant effects with respective p values 0.0033 and 0.0001. Also significant are the interactions YEAR*SEASON (p value = 0.0001) and SEASON* GROUP (p value = 0.0003). The univariate tests also support these findings. Note from the output that there is a significant difference between the two socio-economic groups (p value = 0.0062). Note also that the values of 
and 
are quite large, indicating that Type H structure for the covariance may be satisfied.
In order to understand the nature of the significant effect of the repeated measures variable YEAR, since the levels of it are quantitative (1, 2, 3), it may be useful to analyze the variables obtained by using the POLYNOMIAL transformation. The statement
repeated year 3 polynomial, season/summary nom nou;
can be used for this purpose. Both NOM and NOU options suppress redundant output. If the time points were not equidistant then the transformation "POLYNOMIAL(t1, t2, t3)" can be used in the REPEATED statement to indicate the time points. The PRINTM option is used to print the contrast transformation. The output for this part of the analysis is shown in Output 5.13. The variable YEAR.N represents the nth degree orthogonal polynomial contrast for the variable YEAR as indicated in the output. Thus, in the output, YEAR.1 represents the first degree (linear) polynomial contrast and YEAR.2 represents the quadratic contrast. The line MEAN, listed under column SOURCE in the output, tests the hypothesis that the linear component of the variable YEAR is zero. Since the mean effect for YEAR.1 is significant (p value = 0.0005), the linear component of YEAR is significantly different from zero. The variable GROUP listed under SOURCE is used to test the hypothesis that the first-order polynomial for the variable YEAR is the same for different levels of the variable GROUP. This hypothesis is not rejected (p value = 0.7855). Similar interpretations are applicable for the contrast YEAR.2. Since the p value for the MEAN effect in this case is 0.0612 there is slight evidence that the quadratic component is different from zero. See Section 5.3.4 for a more detailed description and interpretation of the analysis of the orthogonal polynomial contrasts.