5.7. Crossover Designs
In crossover experiments, treatments are administered in a variety of sequences on various subjects. Thus, each subject may get more than one treatment in the course of the experiment. One reason for doing so is that there is usually more variability across subjects than within subjects. Hence the subjects can be treated as random blocks for the purpose of increasing the precision by controlling experimental error variance. The problem, however, becomes complicated by the fact that the successive measurements on the subjects may be correlated. There is also the possible presence of carryover effect(s) at a given time point, from the treatment(s) applied at previous time point(s). This calls for a careful analysis of the data by incorporating these effects appropriately in the model.
5.7.1. Analysis of Crossover Designs
A linear model for crossover design for the response from the mth subject receiving the ith sequence and the kth treatment in the jth time point is
i = 1,...,s, j = 1,...,p, k = 1,...,a, m = 1,...,ni, where μijk is the average response of the kth treatment in sequence i at time point j, 
is the error corresponding to the mth experimental unit in sequence i and €ijkm is the random error associated with time point j of the mth experimental unit in sequence i.
The mean response μijk is, for convenience, assumed to be composed of several components as
where αk is the treatment effect, πj the time effect, and 
is the carryover effect of krth treatment administered in one or more times during time points 0, 1,...,j−1, on the observation at time point j. Initially, at the beginning of any sequence, there is not any carryover effect, so 
is zero. To simplify the model, we also assume that any carryover effect lasts only up to the next time point, and hence we take 
. We also denote, for convenience, 
. In view of this the model becomes
It is further assumed that 
are all independent and are independent of 
also for all i, i′, j, m, m′. However, the assumption of independence of €ijkm and 
may not be realistic. It is so because the observations taken over time on a given subject would most likely be correlated. For convenience the model in Equation 5.23 has been often analyzed as a split plot design, with an assumption of compound symmetric covariance structure for the observation on a given subject. The split plot analysis of Equation 5.23 is straightforward. We will illustrate it by an example adopted from Jones and Kenward (1989, p. 229).
EXAMPLE 15
Univariate Analysis, Comparison of Drugs Two drugs A and B and their combination termed drug C are to be compared for their effectiveness to control hypertension. Each subject was given three drugs in one of the six possible sequences ABC, ACB, BAC, BCA, CAB, and CBA and systolic blood pressure (Y) was measured at the conclusion of each of the three treatments, each of which lasted for four weeks. The data were collected at four different centers. However, we will not consider the variability due to location in our analysis. The data are presented as part of Program 5.20 (the carryover effect for the initial period is defined as zero). The objective of the study is to examine if there were significant differences between drugs, and to examine the period effect and the carryover effect. The model given in Equation 5.23 is the appropriate model and can be fitted using PROC GLM with the following MODEL statement
model y= subject period treat carry;
where all the variables on the right side are CLASS variables. Since SUBJECT forms a random sample, the variable SUBJECT is declared to be random. This instructs SAS to use the appropriate sums of squares in forming the F ratios for the tests.
/* Program 5.20 */
options ls= 64 ps=45 nodate nonumber;
title1 'Output 5.20';
title2 'Analysis of Crossover Design';
data bp;
infile 'bpress.dat';
input patient $ y treat $ carry $ period center subject;
proc glm data = bp ;
class treat carry period subject;
model y = subject period treat carry/ ss1 ;
random subject/test ;
contrast ' a vs. b' treat 1 -1 0;
contrast ' a vs. c' treat 1 0 -1;
contrast ' b vs. c' treat 0 1 -1;
run;
proc glm data = bp ;
class treat carry period subject;
model y = subject period treat carry/ ss3 ;
random subject/test ;
contrast ' a vs. b' treat 1 -1 0;
contrast ' a vs. c' treat 1 0 -1;
contrast ' b vs. c' treat 0 1 -1;
run;Example 5.20. Output 5.20
Analysis of Crossover Design
General Linear Models Procedure
Dependent Variable: Y
Source DF Sum of Squares F Value Pr > F
Model 28 40095.9560700 4.95 0.0001
Error 40 11573.9859589
Corrected Total 68 51669.9420290
R-Square C.V. Y Mean
0.776002 9.575829 177.637681
Source DF Type I SS F Value Pr > F
SUBJECT 22 30646.6086957 4.81 0.0001
PERIOD 2 1395.5942029 2.41 0.1026
TREAT 2 7983.8717062 13.80 0.0001
CARRY 2 69.8814653 0.12 0.8866
Dependent Variable: Y
Contrast DF Contrast SS F Value Pr > F
a vs. b 1 6303.02403115 21.78 0.0001
a vs. c 1 1471.22264872 5.08 0.0297
b vs. c 1 1491.20262487 5.15 0.0287 |
The resulting output is presented in Output 5.20, which indicates a significant effect due to the differences in treatments (for Type I SS, the observed value of F(2,40) is 13.80 and the corresponding p value is 0.0001). However, the carryover effect and the period effect are both statistically insignificant. The same conclusions are reached when the analysis is done using Type III SS. Note that because of our convention of using 0 for the carryover effect at the initial period, the sum of squares due to the carryover effect is different from that reported by Jones and Kenward.
In view of the absence of the carryover effect and the period effect, it may be meaningful to compare the treatment means. The estimated difference between the mean effects of A and B, A and C, and B and C are respectively, 25.3971, 12.4140, and −12.9831, which are obtained by first obtaining the least squares solutions using the SOLUTION option in the MODEL statement and then by computing the appropriate differences 
, 
, and 
. Using separate CONTRAST statements, we can perform tests for the significance of treatment differences. All three treatments are significantly different from each other (respective p values are 0.0001, 0.0297 and 0.0287), and A and B are especially markedly different from each other. Treatment C, being the combination of drugs A and B, falls in between the two.
It must be remembered that the course of analysis in crossover designed data depends heavily on what the significant and insignificant effects are. The reason for this is that, depending on the particular design, certain effects may be confounded with each other, and if a sum of squares representing two or more confounded effects is found to be significant, it would require a further careful examination of data to decide which of the many confounded effects may have led to the statistical significance of the particular sum of squares. In fact, if each of the treatment sequences is tried on the groups of subjects, then the group*period interaction is composed of
the treatment effect,
carryover effect and treatment*period interaction, and
other left over effects associated with group*period effects.
Since it is desirable that the effects listed above are all estimated, the choice of an appropriate crossover design becomes of great importance. This topic has been addressed at length in Jones and Kenward (1989) and Ratkowsky, Evans and Alldredge (1993). Later in this section we present the SAS code for generating suitable designs from two useful classes of crossover designs.
In some special cases, it may be possible to perform a straightforward multivariate analysis of crossover data. One such case is the analysis of AB/BA designs, which are two-sequence (namely, AB and BA) designs in two treatments A and B respectively applied to the groups of size, say n1 and n2. Since the analysis would follow a familiar pattern described earlier in great detail, it can be best illustrated by an example.
EXAMPLE 16
Multivariate Analysis, Effect of Onions in Diet Dunsmore (1981) presents a case study which was initiated to investigate the effect of including onions in the diet on plasma triglyceride levels. A two-sequence crossover design with two treatments, namely, breakfast without and with onions, to be referred to as A and B respectively, is used. Eight patients were assigned to sequence AB and six to BA. Increases in the plasma triglyceride levels at 1, 2, 3, 4, 5, and 6 hours after breakfast were measured. The analysis here is performed on 10,000 times the logarithm of the plasma triglyceride levels. In the SAS code the respective 12 responses are denoted as Y11,...,Y16 and Y21,...,Y26. While Dunsmore analyzed the data using the univariate technique, Grender and Johnson (1992) chose the multivariate route and listed a SAS approach using the 12 by 1 vectors of responses on each of the 14 subjects, which we will briefly present here. Multivariate normality has been assumed for the analysis. There are two groups, namely, AB and BA. These are referred to as Group 1 and 2. Let us denote by μij, the 6 by 1 vector of true mean responses on a subject in the ith group and under jth treatment, i, j = 1,2. This is displayed in Table 5.3:
| Group | Treatment | Mean | Treatment | Mean |
| 1 | A | μ11 | B | μ12 |
| 2 | B | μ21 | A | μ22 |
where μij=(μij1,...,μij6)′, i,j = 1,2. Also, let μ1′ = (μ11′ : μ12′) and μ2′ = (μ21′ : μ22′) and let μi = μ + αi, i = 1,2 for some μ and α1, α2. Then the linear model for these data can be written as
which is in the form of standard linear model
From Equation 5.23 we have
Thus, we have
Hence
These sums and differences can be calculated by pre- and post-multiplying B = (μ, α1, α2)′ by certain specific matrices, that is, as LBM, where L and M are to be appropriately chosen. As a result, most of the relevant hypotheses can be expressed as LBM = 0.
We adopt the following strategy for the analysis. The appropriate SAS code has been provided by Grender and Johnson (1992), which has been produced here with a few notational changes.
Test for the equal carryover effect, that is, H0 : λ1 = λ2. For this, use L = ( 0 1 -1) and, say, M′ = (1 1 1 1 1 1 1 1 1 1 1 1) = M2.
If there are equal carryover effects, then test the hypothesis of no treatment*time interaction. For this, L = (0 1 -1) and M′ = M1.
If there is no group*time interaction (that is, if H0 in Step 1 is not rejected), we may test the hypothesis of no period*time interaction. For this L = ( 1 0 0) and M′ = M1.
Test for the time effect by using L = ( 1 0 0) and M′ = M1.
Test for equal treatment effects using L = ( 1 0 0) and M′ = (1 1 1 1 1 1 -1 -1 -1 -1 -1 -1) = M3.
Test for equal treatment effects using L = ( 1 0 0) and M′ = M3.
stands for Kronecker product (Rao, 1973).SAS code to analyze Dunsmore's data is presented in Program 5.21. The interpretation of multivariate tests is straightforward and we do not cover it here. The corresponding output has been therefore supressed.
/* Program 5.21 */
options ls=64 ps=45 nodate nonumber;
title1 'Output 5.21';
title2 'Multivariate Analysis of Crossover Design';
data onion;
infile 'onion.dat';
input patient meal$ y11 y12 y13 y14 y15 y16 group
patient2 meal2$ y21 y22 y23 y24 y25 y26 group2;
run;
proc glm data = onion ;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
contrast 'Group*Time Interaction' group 1 -1 ;
manova
m = y11-y12+y21-y22,
y12-y13+y22-y23,
y13-y14+y23-y24,
y14-y15+y24-y25,
y15-y16+y25-y26;
title3 'Test for Group*Time Interaction';
run;
proc glm data = onion;
class group;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
contrast 'Carryover Effect' group 1 -1 ;
manova
m = y11+y12+y13+y14+y15+y16+y21+y22+y23+y24+y25+y26;
title3 'Test for Equality of Carryover Effects';
run;
proc glm data = onion;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
contrast 'Teatment*Time Interaction' group 1 -1 ;manova
m = y11-y12-y21+y22,
y12-y13-y22+y23,
y13-y14-y23+y24,
y14-y15-y24+y25,
y15-y16-y25+y26;
title3 'Test for Treatment*Time Interaction
(Assuming equal Carryover Effects)';
run;
proc glm data = onion ;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
manova h = intercept m = y11-y12-y21+y22,
y12-y13-y22+y23,
y13-y14-y23+y24,
y14-y15-y24+y25,
y15-y16-y25+y26;
title3 'Test for Period*Time Interaction
(assuming no Group*Time Interaction)';
run;
proc glm data = onion ;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
contrast 'Treatment Effect' group 1 -1 ;
manova
m = y11+y12+y13+y14+y15+y16-y21-y22-y23-y24-y25-y26;
title3 'Test for Equality of Treatment Effects';
run;
proc glm data = onion ;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
manova h = intercept
m = y11-y12+y21-y22,
y12-y13+y22-y23,
y13-y14+y23-y24,
y14-y15+y24-y25,
y15-y16+y25-y26;
title3 'Test for Time Effect';
run;
proc glm data = onion ;
class group ;
model y11 y12 y13 y14 y15 y16 y21 y22 y23 y24 y25 y26=
group / nouni;
manova h = intercept
m = y11+y12+y13+y14+y15+y16-y21-y22-y23-y24-y25-y26;
title3 'Test for Equality of Period Effects';
run;5.7.2. Construction of Crossover Designs
There is a vast amount of literature available on the construction of p period crossoverreak designs under various desirable criteria, such as the variance balance or the D-optimality criterion. These criteria have been discussed in detail in Jones and Kenward (1989). One common crossover design consists of augmenting various mutually orthogonal Latin squares one below the other. These designs are variance balanced in that the variances of the estimates of the treatment differences are minimum. The resulting design is a design in p periods, p treatments that require p(p−1) subjects (provided such a design exists). See Jones and Kenward (1989) for further details.
A complete set of p by p mutually orthogonal Latin squares, if it exists, is equivalent to a resolution III fractional factorial design for p + 1, p level variables in p2 runs that is a p(p + 1)-(p−1) fractional factorial design. The problem can be approached by first generating the appropriate fractional factorial layout and then by extracting the elements to arrange (p−1) Latin squares one below the other. In these, the columns denote the period, and rows denote the subject number. Since the transpose of a Latin square is also a Latin square, some caution needs to be exercised about which of the two should be chosen; a simple way to ensure that the correct one of the two is being used is to make sure that all subjects have distinct sequences. The entry at the (i, j)th place indicates the particular treatment administered at the jth time point on the ith subject. The desired p(p + 1)-(p−1) fractional factorial design is generated by using the FACTEX procedure. A sample program to generate a 4 period, 4 treatment crossover arrangement requiring 12 subjects is given in Program 5.22. The output is given in Output 5.22. Crossover designs with a = p treatments and p1 < p periods can be obtained by removing any (p-p1) columns from the above design.
/* Program 5.22 */
options ls=64 ps=45 nodate nonumber;
title1 'Output 5.22';
title2 'Generation of a Latin Square Crossover Design';
title3 ' 4 Treatments, 4 Time Points in 12 Subjects';
proc factex;
factors row col t1-t3/nlev=4;
size design=16;
model resolution=3;
output out=latinsq;
run;
data latinsq1;
set latinsq;
keep t1-t3;
proc iml;
use latinsq1;
read all into z0;
p=4;
latin1 = i(p);
latin2 = i(p);
latin3 = i(p);
do i = 1 to p;
do j = 1 to p;
ij = (j-1)*p +i ;
latin1[i,j] = z0[ij,1];
latin2[i,j] = z0[ij,2];
latin3[i,j] = z0[ij,3];
end;
end;
cross = ((latin1//latin2)//latin3);
print cross;Example 5.22. Output 5.22
Generation of a Latin Square Crossover Design
4 Treatments, 4 Time Points in 12 Subjects
CROSS
0 3 1 2
3 0 2 1
1 2 0 3
2 1 3 0
0 2 3 1
3 1 0 2
1 3 2 0
2 0 1 3
0 1 2 3
3 2 1 0
1 0 3 2
2 3 0 1 |
Since the design obtained from the complete set of p × p mutually orthogonal Latin squares requires p(p−1) subjects (and such a design may not even exist, e.g., when p = 6), a smaller design may be desired. Williams' designs are possible candidates. These designs are obtained from a p × p cyclic Latin square (i.e., for which the ith row is i, i + 1,...,p, 1,...,i−1). When p is even, it requires only p subjects. However, when p is odd, the number of subjects required by the Williams' design is 2p.
Given a cyclic Latin square, we first find its mirror image and interlace the columns of the two. That is, if A1,...,Ap are columns of the cyclic Latin square and Bp(=A1),Bp-1(= A2),...,B1(= Ap) are their respective mirror images (which appear in the order B1,...,Bp), then the resulting arrangement is
obtained by interlacing B1,...,Bp with A1,...,Ap. This gives an arrangement with 2p columns. It can be generated by using Program 5.23 and is shown in Output 5.23 for p = 5. The desired design in p periods is obtained by taking either the first p or the last p columns of the above arrangement if p is even and by arranging the last p columns below the first p columns if p is odd. By virtue of being generated from a Latin square, all p treatments will appear in the design and every treatment will appear exactly once (if p is even) or twice (if p is odd) in every time period.
/* Program 5.23 */
options ls=64 ps=45 nodate nonumber;
title1 'Output 5.23';
title2 'Williams Design: p Treatments in p Time points ';
proc iml;
p=5;
p2=p*2;
pover2 =p/2;
/*Initialize the matrices;
a is the circular p by p Latin Square, b is
its mirror image and the specific;*/
a=i(p);
b=i(p);
w=j(p,p2);
*Create the matrix a;
do i = 1 to p;i1=i-1;
do j = 1 to p;
if (i = 1) then a[i,j] =j;
if (i > 1) then do;
if (j < p) then do ;
jmod = j+1;
a[i,j] = a[i1,jmod] ;
end ;
if (j = p) then do ;
jmod = 1 ;
a[i,j] = a[i1,jmod] ;
end ;
end ;
end ;
end ;
* Create b, the mirror image of a;
do i = 1 to p;
do j = 1 to p;
jj=(p+1-j);
b[i,j] = a[i,jj];
end ;
/*Interlace the Circular Latin Square and its
mirror image;*/
do k = 1 to p2;
kby2 =k/2;
if kby2=floor(kby2) then do;
w[i,k] = b[i,kby2];
end;
if kby2>floor(kby2) then do;
kk= floor(kby2)+1;
w[i,k] = a[i,kk];
end;
end;
end;
print 'p is equal to ' p;
print 'The following is the Desired Williams Design: ';
print '_____________________________________________ ';
/*
Design requires p (if p even) or 2p subjects (if p odd).
If p is even take first p or last p columns.
If p is odd slice after first p columns
and augment last p columns below it.
*/
w1 = w*(i(p)//j(p,p,0));
w2 =w*(j(p,p,0)//i(p));
if pover2 > floor(p/2) then do;
williams =w1//w2;
end;
else williams =w1 ;
print williams;Example 5.23. Output 5.23
Williams Design: p Treatments in p Time points
P
p is equal to 5
The following is the Desired Williams Design:
_____________________________________________
WILLIAMS
1 5 2 4 3
2 1 3 5 4
3 2 4 1 5
4 3 5 2 1
5 4 1 3 2
3 4 2 5 1
4 5 3 1 2
5 1 4 2 3
1 2 5 3 4
2 3 1 4 5 |
There are a number of alternative methods available to construct other crossover designs. See, for example, Jones and Kenward (1989) and John (1971). An extensive catalog of many useful designs is given in Ratkowsky, Evans and Alldredge (1993).