6.8. Multivariate Repeated Measures Data
When the data are collected on a set of q variables and on each of these variables at p different occasions, we have a set of multivariate repeated measures data. Analysis of such data is further complicated by the existence of correlation among the measurements on different variables in addition to the correlation among measurements taken at different occasions. Several approaches to analyze these data exist in the literature. We will briefly describe one of these here.
Let yijul, l=1,...,q; j = 1,...,p; u=1,...,ni; i = 1,...,k, be the observation on the lth variable for the uth individual in the ith treatment group at the jth occasion and let yiu=(yi1u1,...,yipu1,yi1u2,...,yipuq)′. Then yiu is pq by 1 random vector of responses corresponding to the uth individual in the ith group. Let D(yiu)= Ω, for u=1,...,ni; i = 1,...,k and 
. By defining
and following the approach described in Chapter 3, a multivariate linear model with an appropriate X matrix consisting of design (assumed to be fixed) and/or regression variables can be written as y=XB+ɛ. The rows of error matrix ɛ are assumed to be independent and distributed as pq-variate normal with a zero mean vector and the variance covariance matrix Ω. Thus, following the approaches presented in Chapters 3, 4, and 5 any linear hypothesis about the elements of B can be formulated in the form of a general linear hypothesis H0: LBM=0, for known and full (row and column respectively) rank matrices L and M. Using Wilks' Λ or any other standard multivariate tests, such a hypothesis can be tested.
This approach for analyzing the multivariate repeated measures data, known as the doubly multivariate model (DMM) analysis, is commonly adopted in practice. Since this approach has been discussed extensively in previous chapters we will not discuss this further here. However, see Timm (1980) for a detailed description of the theory and Timm and Mieczkowski (1997) for SAS applications of these methods.
An alternative approach (Naik and Rao, 1997) is to begin by making certain assumptions on the covariance structure of Ω. We assume
where V and Σ respectively are p by p and q by q positive definite matrices and ⊗s tands for the Kronecker product. In view of the defined arrangement of the elements in yiu the matrix V represents the variance covariance matrix of repeated measures for a given response variable. This is assumed to be same for all response variables. The matrix Σ represents the variance covariance matrix between the measurements on all response variables at a given time point. It is assumed that this does not depend on the particular time point and is the same for all time points.
This assumed structure of Ω has certain advantages over the general covariance structure. First, the variance covariance matrix of the repeated measures may have a simpler structure such as compound symmetric or AR(1). It is easier to accommodate different structures for the variance covariance matrix of repeated measures V in this formulation. Secondly, the number of unknown parameters of the variance covariance matrix Ω, in this set up, viz, [Q(q+1)/2+p(p + 1)/2], is smaller as compared to that in the general covariance structure, viz, [pq(pq+1)/2]. Further, this structure enables us to handle unbalanced multivariate repeated measures data more easily. Statistical analysis of multivariate repeated measures data assuming the above structure can be performed by using PROC MIXED. We illustrate this and the subsequent analysis in the following example.
EXAMPLE 10
Multivariate Repeated Measures Data, Data from a Dental Study Data used in Program 6.11 were collected by T. Zullo of the School of Dental Medicine at the University of Pittsburgh and have been considered in Timm (1980, Table 7.2). The study is concerned with determining the relative effectiveness of two orthopedic adjustments of the mandible. Nine subjects were assigned to each of two orthopedic treatments called activator treatments. The measurements were made on p=3 characteristics to assess the changes in the vertical position of the mandible at t=3 time points of activator treatment. The problem is to compare the two treatments, and study the time effect and the interaction between time and treatment.
As discussed earlier, here the assumed covariance structure for observations on any subject is of the form
We will assume Σ to be unstructured (UN) and V to have an AR(1) covariance structure. This can be specified using the option TYPE=UN @ AR(1) in the REPEATED statement. In this specification, the Kronkecker product ⊗ is specified by @. The complete SAS program is presented as Program 6.11.
/* Program 6.11 */
option ls=64 ps=45 nodate nonumber;
title1 'Output 6.11';
data a;input y1−y9;
cards;
117 59 10.5 117.5 59 16.5 118.5 60 16.5
109 60 30.5 110.5 61.5 30.5 111 61.5 30.5
117 60 23.5 120 61.5 23.5 120.5 62 23.5
112 67.5 33 126 70.5 32 127 71.5 32.5
116 61.5 24.5 118.5 62.5 24.5 119.5 63.5 24.5
123 65.5 22 126 61.5 22 127 67.5 22
130.5 68.5 33 132 69.5 32.5 134.5 71 32
126.5 69 20 128.5 71 20 130.5 73 20
113 58 25 116.5 59 25 118 60.5 24.5
128 67 24 129 67.5 24 131.5 69 24
116.5 63.5 28.5 120 65 29.5 121.5 66 29.5
121.5 64.5 26.5 125.5 67.5 27 127 69 27
109.5 54 18 112 55.5 18.5 114 57 19
133 72 34.5 136 73.5 34.5 137.5 75.5 34.5
120 62.5 26 124.5 65 26 126 66 26
129.5 65 18.5 133.5 68 18.5 134.5 69 18.5
122 64.5 18.5 124 65.5 18.5 125.5 66 18.5
125 65.5 21.5 127 66.5 21.5 128 67 21.6
;
/* This data set is from Timm, N.H. (1980). Courtesy of Dr. Thomas Zullo,
School of Dental Medicine, University of Pittsburgh. */
data b; set a;
if _n_<10 then group='1';
else group='2';
run;
data b; set b;
subj=_n_;
y=y1; m_var='var1'; time=1; output;
y=y2; m_var='var2'; time=1; output;
y=y3; m_var='var3'; time=1; output;
y=y4; m_var='var1'; time=2; output;
y=y5; m_var='var2'; time=2; output;
y=y6; m_var='var3'; time=2; output;
y=y7; m_var='var1'; time=3; output;
y=y8; m_var='var2'; time=3; output;
y=y9; m_var='var3'; time=3; output;
drop y1−y9;
title2 'Analysis of Multivariate Repeated Measures';
title3 'Kronecker Product Covariance Structure';
proc mixed data=b method=reml covtest;
classes group subj m_var time;
model y = m_var group time group*time;
repeated m_var time/type=un@ar(1) subject=subj;
run;The SAS code requires some explanation. First the data are converted to the univariate form using the standard technique discussed in several earlier examples. In addition to the variable TIME representing the repeated measures, the variable M_VAR representing three characteristics is also declared as a CLASS variable and is included in the MODEL statement of the MIXED procedure. This ensures that E(yijul)=μl, i = 1,2,3. That is, the three multivariate responses are ensured to have a mean vector without any structure. We have used the option TYPE=UN @ AR(1) in the REPEATED statement to specify the desired covariance structure discussed earlier. Currently, UN is the only option available for the specification of matrix Σ in the MIXED procedure. However, V can be chosen to have any of the several covariance structures discussed earlier. The output is presented in Output 6.11.
Example 6.11. Output 6.11
Analysis of Multivariate Repeated Measures
Kronecker Product Covariance Structure
Covariance Parameter Estimates (REML)
Cov Parm Subject Estimate Std Error Z
M_VAR UN(1,1) SUBJ 27.22223759 7.38869537 3.68
UN(2,1) SUBJ 1.23670272 8.66021630 0.14
UN(2,2) SUBJ 46.75441428 12.48825605 3.74
UN(3,1) SUBJ 6.34534291 3.78932984 1.67
UN(3,2) SUBJ 14.74008105 5.04747353 2.92
UN(3,3) SUBJ 17.19764219 4.35991193 3.94
TIME AR(1) SUBJ 0.92705104 0.02063137 44.93
Pr > |Z|
0.0002
0.8864
0.0002
0.0940
0.0035
0.0001
0.0001
Tests of Fixed Effects
Source NDF DDF Type III F Pr > F
M_VAR 2 120 1335.62 0.0001
GROUP 1 16 0.30 0.5942
TIME 2 120 12.50 0.0001
GROUP*TIME 2 120 0.64 0.5273 |
Testing for the equality of the means of the three responses may not be meaningful in this case. Thus, we note that only the TIME effect is statistically significant with a p value of 0.0001. Since, the interaction GROUP*TIME is not significant (p value = 0.5273) and since no overall differences between the groups have been observed (p value = 0.5942), the TIME trend is deemed the same for the two treatment groups.