5.5. Statistical Analysis of a One-Factor Design with Repeated Measures

In this section, we discuss the methods for analyzing the body weight data from rodent and large animal toxicology studies. Since body weights of each animal are collected throughout the study, they are repeated measures data. The repeated measures analysis is a logical choice for large animal toxicology studies (Thakur, 2000) and rodent toxicology studies (Hoffman, et al., 2002) with data that are repeated in nature. For a typical four-treatment-group two-year carcinogenicity study, there could be as many as 60 rats per sex for each treatment group, each receiving a $0$ (vehicle), low, mid, or high dose of a compound daily for the entire two years. The body weights of each animal are usually collected weekly up to 13 weeks and biweekly thereafter. The purpose of the statistical analysis is to evaluate compound-related effects on body weight. The statistical methods are described and the analysis of the data is carried out using SAS. For a detailed description of repeated measures models and issues arising in the analysis of incomplete data, we refer the reader to Chapter 12, "Analysis of Incomplete Data."

5.5.1. Objectives of Statistical Comparisons

The main interest of the analysis is to identify the NOEL on body weight in each sex by comparing treatment groups to the vehicle control. Treatment-related effects need to be interpreted with reference to the time intervals in which they were observed. The compound-related effects at a single time point are discussed first to help lay the foundation for evaluation of those effects within a time span.

5.5.2. Assessment of Compound-Related Effects at a Single Time Point

Compound-related effects can be assessed using the sequential trend test described in Section 5.4.1. The trend test is performed to evaluate the monotonic dose-response relationship in group means. However, if researchers are also interested in detecting statistically significant differences between the lower doses and the control in the absence of a high dose effect, then the Dunnett test (Dunnett, 1964) at the significance level of 0.05 can be applied as a secondary test. To avoid an inflated Type I error rate by routinely performing Dunnett's t-test in the absence of a high dose effect, researchers can first perform an F-test at a lower significance level, 0.01. Dunnett's t-test is performed only if the F-test is significant. If the effects detected at lower doses in the absence of a high dose effect would be dismissed as not being dose-responsive, then neither the F-test nor Dunnett's t-test would be considered.

5.5.3. Assessment of Compound-Related Effects within a Time Span

The evaluation of compound effects can be expanded from a single time point to the entire time span of the experiment (Hoffman, et al., 2002). As the duration of a study increases, so does the number of body weight measurements. For example, in a two-year carcinogenicity study there would be more than 50 body weight measurements for each animal surviving to the end of the study. As one expects the growth pattern to change as animals mature, body weights are averaged accordingly to capture the characteristics. The calculation of average body weights in selected analysis intervals and the handling of missing data due to death are discussed in this section. The inclusion of baseline and the selection of a covariance structure for each animal across time are detailed first. After that, statistical methods for evaluation of monotonic and nonmonotonic dose-response relationships are explained.

5.5.4. Calculation of Interval-Averaged Body Weights

Analysis intervals for averaging body weights that are used in rodent and large animal studies at Eli Lilly and Company are listed in Table 5.2. Statistical analysis of rodent body weights collected in the first 3 months of the rapid growth phase is performed in one analysis. After 3 months, the growth of a rodent slows down and enters into the maintenance phase. Body weights beyond 3 months are evaluated in the second statistical analysis. The baseline body weight of each animal is included in both analyses as a covariate. Large animal studies are typically 2 weeks, 1, 3, 6, 9 or 12 months in duration. Evaluation of large animal body weights collected in the first 6 months is performed in one statistical analysis while additional body weights collected beyond 6 months are analyzed in a second analysis.

^[] Approximate time intervals which may vary from study to study.

^[] Duration of dog studies is generally up to 52 weeks.

Interval-averaged body weights for rodents are derived using the %ONEWEEK and %WEEKINT macros provided on the book's companion Web site. The INDDATA data set includes body weight measurements, collection days and general study information. The first few weeks of the study is called the initial period when no averaging is required. Weekly body weights are saved as INT_BW for those weeks starting from the study day that the first weekly data is recorded, WKLY_FIRST, to the study day that the last weekly data are recorded, WKLY_END. This is done using the %ONEWEEK macro. After the initial period, body weights in the selected intervals are averaged and saved as INT_BW in the macro. To obtain a representative body weight for the selected interval, the initial body weight in the current interval, which is the last body weight of the previous interval, is also included in the calculation. The %WEEKINT macro computes INT_BW by specifying the number of time points for averaging (NUM_TIMEPTS), the start day (INT_START) and the end day (INT_END) of the interval. This macro pulls the last observation from the previous interval into the calculation of INT_BW for the current interval.

As an illustration, Program 5.4 applies the macros to derive five weekly body weights and four biweekly interval-averaged body weights post dosing as INT_BW. These are appended to the base data set, ALL_INTERVAL. ALL_INTERVAL contains the weekly body weights for Days −1, 6, 13, 20, 27, and 34, and biweekly interval-averaged body weights for Days 48, 62, 76, and 90.

Example 5-4. Calculation of interval-averaged body weights

%oneweek(wkly_first=−1,wkly_end=34);
%weekint(num_timepts=2,int_start=41,int_end=90);

Example. Partial output of ALL_INTERVAL from Program 5.4

Gender    Phase            Day    Animal    Group     BW     INTVL_BW

Male      Treatment         −1     1001       1      132.5    132.5
Male      Treatment          6     1001       1      166.5    166.5
Male      Treatment         13     1001       1      194.8    194.8
Male      Treatment         20     1001       1      212.1    212.1
Male      Treatment         27     1001       1      246.3    246.3
Male      Treatment         34     1001       1      255.5    255.5
Male      Treatment         41     1001       1      277.3     NC
Male      Treatment         48     1001       1      294.7    275.8
Male      Treatment         55     1001       1      308.8     NC
Male      Treatment         62     1001       1      317.3    306.9
Male      Treatment         69     1001       1      330.8     NC
Male      Treatment         76     1001       1      328.3    325.5
Male      Treatment         83     1001       1      339.0     NC
Male      Treatment         90     1001       1      339.8    335.7

Female    Treatment         −1     2051       2      101.8    101.8
Female    Treatment          6     2051       2      116.5    116.5
Female    Treatment         13     2051       2      127.5    127.5
Female    Treatment         20     2051       2      145.5    145.5
Female    Treatment         27     2051       2      152.1    152.1
Female    Treatment         34     2051       2      156.0    156
Female    Treatment         41     2051       2      162.6     NC
Female    Treatment         48     2051       2      171.9    163.5
Female    Treatment         55     2051       2      178.6     NC
Female    Treatment         62     2051       2      189.5    180
Female    Treatment         69     2051       2      196.5     NC
Female    Treatment         76     2051       2      197.8    194.6
Female    Treatment         83     2051       2      201.9     NC
Female    Treatment         90     2051       2      204.2    201.3

5.5.4.1. Handling of Missing Data Due to Death

As animals age, their mortality rate also increases. It is not unusual to see 50% of the animals die before the end of a carcinogenicity study. Missing data due to death are different from missing data due to other reasons. When averaging body weights for an animal in a selected time interval, a missing value will be assigned in the former case while an average would be calculated based on all available body weights in the latter case. All body weights up to the time interval of death are included in the statistical analysis. Body weights that are collected prior to death but that are not included in the statistical analysis would be incorporated into the overall assessment of mortality data.

Program 5.5 demonstrates how to properly handle the missing data. For each animal, a survival index (SURVIVAL_DAY) is created to indicate the last day of non-missing observations. This index is used to identify if a missing body weight is due to death or other reasons. If this survival index day falls within an interval, the derived interval body weight (INT_BW) is set to missing for that animal. Otherwise, the program averages all available non-missing body weights.

The following arguments are used in Program 5.5:

• SURVIVAL_DAY is the last day of non-missing body weights.

• START is the first day of an interval (e.g., Day 48).

• END is the last day of an interval (e.g., Day 69).

Example 5-5. Handling of missing data

data survival_index;
    set all;
    if bw ne .;
proc sort data=survival_index;
    by animal gender;
data survival_index;
    set survival_index;
    by animal gender day;
    if last.animal;
    survival_day=day;
    keep animal gender survival_day;
data week&end;
    merge week&end(in=in1) survival_index(in=in2);
    by animal;
    if in1 and in2;
    if &start<=survival_day<&end then int_bw=.;
    run;

The output of Program 5.5 can be summarized into four possible scenarios. To illustrate, Table 5.3 includes both the weekly body weights and the derived interval body weights. For the first month, INT_BW values were captured directly from the five weekly body weights. INT_BW ending on Day 48 was computed by averaging the body weights collected on Days 34, 41 and 48. For the last time interval that ended on Day 62, INT_BW is derived from the average of three time points: Days 48, 55, and 62. The following scenarios are presented in Table 5.3:

Scenario 1.

Animal 1001 did not have any missing values.

Scenario 2.

Animal 1002 had a missing value on Day 55. Hence INT_BW for Day 62 was computed by averaging the body weights from Days 48 and 62.

Scenario 3.

Animal 1003 had two missing values on Days 41 and 48. Hence INT_BW for Day 48 was computed from Day 34, and INT_BW for Day 62 was computed by averaging the body weights from Days 55 and 62.

Scenario 4.

Animal 1004 is assumed dead right after Day 48 since there were no data collected beyond Day 48. Therefore, INT_BW for the last interval was set to be missing.

5.5.5. Selection of the Covariance Structure for Each Animal

To account for the initial differences in baseline body weight, it is important to include it as a covariate in the statistical model. In addition, to account for the correlation among repeated measures from the same animal, one needs to select an appropriate covariance structure for each animal. As a default covariance structure, consider repeated measures data from a split-plot design with a treatments, b time points and c animals. The split-plot model (Aldworth and Hoffman, 2002) with treatment as the whole-plot factor, time as the subplot factor and baseline as a covariate, is

where i = 1,...,a, j = 1,...,b and k = 1,...,c. In this equation, y is the body weight, μ is the grand mean, α is the treatment effect, γ is the regression coefficient for the covariate x and the overall mean of the covariate , β is the time effect, αβ is the treatment by time interaction, d is the random error for the animal nested in the treatment and e is random error at each time point.

The covariance matrix for an animal in this model has the variance components structure (VC). The covariance terms in VC are nonnegative. If negative correlations are allowed in the covariance structure of VC, the matrix will have a compound symmetric structure (CS).

In addition, the variances of an animal at different time points could be heterogeneous. Therefore, one can consider other covariance structures, including homogeneous variance components (VC), heterogeneous variance components (UN(1)), homogeneous compound symmetry (CS), heterogeneous compound symmetry (CSH) and spatial power (SP[POW]).

For the UN(1) and SP(POW) structures, both REPEATED and RANDOM statements are included in the MIXED procedure. An animal is specified as the subject in both statements and the intercept is specified in the RANDOM statement as a random effect.

For the CS and CSH structures, only the REPEATED statement is included while for the VC structure, only the RANDOM statement is included. The finite-sample corrected Akaike's Information Criterion (Keselman et al., 1998) can be used for selecting the covariance structure. The Kenward and Roger method (Kenward and Roger, 1997) is generally recommended for the denominator degrees of freedom. The PROC MIXED syntax for each covariance structure discussed above follows.

Homogeneous variance components (VC)

proc mixed data=one;
    class trt time animal;
    id trt time animal;
    model body_wt=trt time trt*time baseline/ddfm=kenwardroger solution;
    random int/type=vc subject=animal s;

Heterogeneous variance components (UN(1))

proc mixed data=one;
    class trt time animal;
    id trt time animal;
    model body_wt=trt time trt*time baseline/ddfm=kenwardroger solution;
    repeated time/type=un(1) subject=animal r;
    random int/subject=animal s;

Note that TYPE=UN(1) can be replaced with TYPE=VC GROUP=TIME.

Homogeneous compound symmetry (CS)

proc mixed data=one;
    class trt time animal;
    id trt time animal;
    model body_wt=trt time trt*time baseline/ddfm=kenwardroger solution;
    repeated time/type=cs subject=animal r;

Heterogeneous compound symmetry (CSH)

proc mixed data=one;
    class trt time animal;
    id trt time animal;
    model body_wt=trt time trt*time baseline/ddfm=kenwardroger solution;
    repeated time/type=csh subject=animal r;

Spatial power (SP[POW])

proc mixed data=one;
    class trt time animal;
    id trt time animal;
    model body_wt =trt time trt*time baseline/ddfm=kenwardroger solution;
    repeated time/type=sp(pow) (time) subject=animal r;
    random int/subject=animal s;

5.5.5.1. Evaluation of Monotonic and Nonmonotonic Dose-Response Relationships

A repeated measures analysis of variance is performed to assess compound-related effects across time. Treatment and time are entered in the statistical model as the two main factors. The interaction between treatment and time is also included in the model. Based on the significance of the interaction, compound effects are assessed either at each time point when the interaction is significant, or on results pooled across the entire time span when the interaction is not significant. This approach allows researchers to detect the start and end of compound-related effects.

The assessment of compound-related effects for repeated measures analysis of variance is carried out in the same manner as for single-time measurements. The additional dimension of time requires more detailed specifications for the comparisons of treatment groups at selected time points. The basic concept of evaluating a monotonic dose-response relationship using the sequential trend test by Tukey, Ciminera and Heyse (1985) and supplementing it with a pairwise to control test for a nonmonotonic dose-response relationship remains the overall strategy.

To test for a monotonic dose-response relationship in treatment, one first needs to evaluate the interaction between time and treatment by performing the following three interaction tests:

• Test 1 (linear trend in treatment by time at the 0.01 significance level). This test evaluates the similarity of the monotonic dose-response relationship across time. Consider a slope for each dose-response relationship being evaluated. The test checks for equality of these slopes at all time points.

• Test 2 (linear trend in treatment by linear trend in time at the 0.05 level). This test checks if the slopes defined above change consistently across time, e.g., if they continue to rise or continue to drop.

• Test 3 (linear trend in treatment by quadratic trend in time at the 0.05 level). This test checks if the slopes change in a quadratic fashion, i.e., rising or dropping in one direction to a point and then changing directions for the rest of the time span.

Tests 2 and 3 help researchers understand the treatment related dose-response effects within a time span. The interaction between the linear trend in treatment and time is a more general catch-all test to capture those scenarios when the slopes of the monotonic dose-response vary significantly across time and the profile of the slopes may be more complicated than linear or quadratic.

Following the strategy for handling monotonic and nonmonotonic treatment effects at a single time point, Test 1 is carried out at the 0.01 level and Tests 2 and 3 are carried out at the 0.05 level. If any of the three interaction tests is statistically significant at the respective significance level, contrasts need to be specified to examine the treatment effects either on the results pooled across time, or at each time point in addition.

In order to evaluate the monotonic dose-response relationship in treatment and the treatment by time interaction terms, several ESTIMATE and CONTRAST statements need to be specified. The %REPMEAS49 macro provided on the book's companion Web site is an example of proper ESTIMATE and CONTRAST parameters in a study design of four groups with nine time points post dosing. The doses are measured on an ordinal scale.

If no monotonic dose-response relationship is detected in treatment and a lower dose effect in the absence of a high dose effect may be meaningful, one can evaluate a nonmonotonic dose-response relationship. In the one-factor design, this is accomplished by conducting an F-test at a lower significance level, 0.01, and carrying out Dunnett's t-test at the 0.05 level only after the F-test is shown to be significant.

In the repeated measures analysis based on PROC MIXED, Dunnett's t-test would compare all combinations of treatment and time back to the first time point of the control group. This is not the same as comparing the treated group means back to the control at each time point. Therefore, Dunnett's t-test is replaced with the Bonferroni-adjusted t-test at the 0.05 level. The Bonferroni-adjusted t-test is preceded by two F-tests carried out at the 0.01 level for (1) the treatment by time interaction and (2) the treatment main effect:

• If the treatment by time interaction is significant, the Bonferroni-adjusted t-test will be applied to the treatment means for each time point.

• If the treatment main effect alone is significant, the Bonferroni-adjusted t-test will be applied only to the treatment means pooled across all time points.

• If neither is significant, no further testing is performed.

Note that the Bonferroni-adjusted t-test can be carried out using the %BONF_ADJ macro given on the book's companion Web site.

5.5.5.2. SAS Module for the Evaluation of Monotonic and Nonmonotonic Dose-Response Relationships

A comprehensive and flexible SAS module was developed by the authors to carry out the statistical analysis for the evaluation of monotonic and nonmonotonic dose-response relationships in a repeated measures ANOVA framework. In this macro-parameter-driven module, users can specify the names of the analysis variables and covariates (if any), levels of time factor, the covariance structure, denominator degrees of freedom method (DDFM), and an option of yes/no for inference tests. As an illustration, SAS code provided on the book's companion Web site uses the macro %PRF1FRM to analyze the INDDATA data set. Results from the analysis of the INDDATA data set using the module are given in Tables 5.4 and 5.5.

^[] Level of significance tested = .05; Two-sided test.

^[] Level of significance tested = .01.

^[] Level of significance tested = .05.

^[] Statistically significant.

^[] Level of significance tested = .05; Two-sided test.

^[] Level of significance tested = .01.

^[] Level of significance tested = .05.

^[] Statistically significant.