8.2. Bioequivalence Testing
Bioequivalence testing is performed to provide evidence that a new formulation of drug substance (e.g., a new tablet) is equivalent in vivo to an existing formulation of drug product. Such testing is used by manufacturers of new chemical entities when making changes to a formulation of drug product used in confirmatory clinical trials, and additionally is used by the generic pharmaceutical industry to secure market access at patent expiration of an existing marketed product.
The new formulation (T) is generally studied relative to the existing formulation (R) in a randomized, open-label, cross-over trial (Jones and Kenward, 2003; Wellek, 2003; Senn, 2002; Chow and Liu, 2000). The structure of testing the question of bioequivalence is:
where μT is the adjusted mean for the test formulation and μR is the adjusted mean for the reference formulation on the natural log scale. The factor ln 1.25 was chosen by regulatory agencies (FDA, 1992; Barrett et al., 2000) and each one-sided test is performed at a 5% significance level without adjustment for multiplicity (Hauck et al., 1995).
Both tests must reject the null hypotheses for AUC and Cmax in order for bioequivalence to be declared. This testing procedure is referred to as the TOST (two-one sided testing, see Schuirmann, 1987) assessment of average bioequivalence and constitutes the current FDA standard approach. See the FDA guidance page, http://www.fda.gov/cder/guidance/ for more details. In practice, a 90% confidence interval for μT − μR is derived for the ln-transformed AUC and Cmax, using a model appropriate to the study design. If both intervals fall completely within the interval (− ln 1.25, ln 1.25), bioequivalence is concluded. This procedure is designated the average bioequivalence (ABE) because only the test and reference means are compared. A summary of other approaches and issues of interest in bioequivalence testing may be found in Hauck and Anderson (1992), Anderson and Hauck (1996), Benet (1999) and Zariffa and Patterson (2001). This type of approach is termed a confirmatory bioequivalence assessment for the purposes of this chapter.
This type of approach to data analysis is applied to clinical PK data in a variety of other setting in exploratory clinical pharmacology research. Examples include drug-drug interaction trials, food effect assessment and comparison of rate and extent of bioavailability in renal-impaired and hepatic insufficient populations. See the FDA guidance page, http://www.fda.gov/cder/guidance/ for details. In these studies, the range of plausible values as expressed by a confidence interval is used to assess the degree of equivalence or comparability, depending upon the setting. A TOST need not necessarily be performed. Under such an approach, confidence level (Type I error rate) is termed consumer or regulator risk, i.e., the risk of the regulator agency in making an incorrect decision. Though often a pre-specified equivalence limit is difficult or impossible to define prior to study initiation, thus inhibiting the ability of study sponsors to adequately ensure adequate power to demonstrate equivalence if such is desired, power is of less concern when assessing the results of such studies than the confidence level. This approach to statistical inference gives regulator agencies an easy standard under which to assess the results of such exploratory pharmacokinetic studies.
We now turn to an example of a confirmatory bioequivalence trial.
EXAMPLE: Two-period cross-over study with test and reference formulations
Consider the following 2 × 2 cross-over study where a test formulation was compared to a reference formulation in approximately 50 normal healthy volunteer subjects.
The AUC data set, reproduced with permission from Patterson (2001), summarizes AUC values derived for the test and reference periods (the data set can be found on the book's companion Web site). The SEQUENCE variable codes the treatment sequence (RT denotes "'reference-test" and TR denotes "test-reference") and, lastly, the AUCT and AUCR variables contain AUC values when given Test and Reference formulations, respectively, in [ng/mL/h].
Program 8.1 uses PROC MIXED to fit a random-intercept model (Jones and Kenward, 2003) to the AUC data set once the AUC data are formatted by subject, sequence, period, and formulation (program not shown).
Example 8-1. Comparison of AUC values in the two-period cross-over study with test and reference formulations
data lnauc(keep=subject sequence period formula lnauc);
set auc;
lnauc=log(auc);
proc mixed data=lnauc method=reml;
class sequence subject period formula;
model lnauc=sequence period formula/ddfm=kenwardroger;
random subject(sequence);
estimate 'T-R' formula −1 1/cl alpha=0.10;
run; |
Example. Output from Program 8.1
Cov Parm Estimate
subject(sequence) 1.5921
Residual 0.1991
Type 3 Tests of Fixed Effects
Num Den
Effect DF DF F Value Pr > F
sequence 1 44.8 0.12 0.7254
period 1 43.1 0.37 0.5463
formula 1 43.1 0.92 0.3424Estimates
Standard
Label Estimate Error DF t Value Pr > |t|
T-R 0.09023 0.09399 43.1 0.96 0.3424
Label Alpha Lower Upper
T-R 0.1 −0.06776 0.2482 |
Output 8.1 displays the estimated difference between the test and reference formulations in the ln-transformed AUC with a 90% confidence interval. The 90% confidence interval is (−0.0678, 0.2482). As insufficient information is present to reject H02, bioequivalence was not demonstrated. No significant differences in sequence (p = 0.7254), period (p = 0.5463), and formulation (p = 0.3424) were detected. Between-subject variance in ln-AUC was 1.5921, and within-subject variance was 0.1991.
Alternatively we can use the following RANDOM statement to explicitly specify a random-intercept model:
random int/subject=subject(sequence);
Specifying the RANDOM statement results in equivalent findings to the above.
These are the models required by FDA (1992) for the assessment of bioequivalence using a 2 × 2 cross-over design. Note that the Huyhn-Feldt condition (Hinkelmann and Kempthorne, 1994) is applied to the variance components using this model.
We may also use the REPEATED statement in PROC MIXED if the total variance (between plus within subject variation) of test and reference formulations and their covariance are of interest in a 2 × 2 cross-over study:
proc mixed data=lnauc method=reml;
class sequence subject period formula;
model lnauc=sequence period formula/ddfm=kenwardroger;
repeated formula/type=un subject=subject(sequence);
estimate 'T-R' formula −1 1/cl alpha=0.10;
run;Results of this last statement may differ slightly from the random-intercept model above when data are missing. It is unlikely, but not impossible, that missing data can affect inference.
8.2.1. Alternative Designs in Bioequivalence Testing
The FDA guidance also allows for alternative designs to demonstrate bioequivalence. One such design is the replicate cross-over design where each subject receives each formulation twice, with each administration being separated by a wash-out period of five half-lives.
EXAMPLE: A replicate cross-over study
Consider the following replicate design cross-over study where test and reference formulations were adminstered in a randomized, four-period cross-over design in approximately 36 normal healthy volunteer subjects.
The RAUC data summarizes AUC values collected in the test and reference periods (the data set can be found on the book's companion Web site). The SUBJECT variable is the subject's ID number, SEQUENCE variable codes the treatment sequence (ABBA denotes "test-reference-reference-test" and BAAB denotes "reference-test-test-reference") and, lastly, AUC1TEST, AUC2TEST, AUC1REF, AUC2REF variables contain AUC values when given Test and Reference formulations in the first and second administrations, respectively, in [ng/mL/h].
The FDA guidance requires that the construction of the confidence interval for μT − μR be appropriate to the study design. In the case of a replicate design model, this recommendation results in a requirement to specify a factor-analytic variance-covariance structure for the between-subject variance components and calculation of within-subject variances for each formulation; see Patterson and Jones (2002) for more details.
Program 8.2 uses PROC MIXED to fit a factor-analytic variance-covariance structure using the FA0(2) option to the ln-transformed AUC data by subject, sequence, period, and formulation. See FDA Guidance (2001) for a description of why this option is used.
Example 8-2. Analysis of AUC data from a replicate cross-over study with test and reference formulations
data lnauc(keep=subject sequence period formula lnauc);
set rauc;
lnauc=log(auc);
proc mixed data=lnauc method=reml;
class sequence subject period formula;
model lnauc=sequence period formula/ddfm=kenwardroger;
random formula/type=FA0(2) subject=subject;
repeated/group=formula subject=subject;
estimate "T-R' formula 1 −1/cl alpha=0.1;
ods output estimates=test;
data test;
set test;
lowerb=exp(lower); * Lower bound on original scale;
upperb=exp(upper); * Upper bound on original scale;
proc print data=test noobs;
var lowerb upperb;
run; |
Example. Output from Program 8.2
Covariance Parameter Estimates
Cov Parm Subject Group Estimate
FA(1,1) subject 0.5540
FA(2,1) subject 0.5542
FA(2,2) subject 1.24E-17
Residual subject formula A 0.09851
Residual subject formula B 0.1110
Type 3 Tests of Fixed Effects
Num Den
Effect DF DF F Value Pr > F
sequence 1 35.6 0.09 0.7706
period 3 106 2.28 0.0835
formula 1 106 7.68 0.0066Estimates
Standard
Label Estimate Error DF t Value Pr > |t|
T-R −0.1449 0.05227 106 −2.77 0.0066
Label Alpha Lower Upper
T-R 0.1 −0.2316 −0.05816
lowerb upperb
0.79324 0.94350 |
Output 8.2 lists the findings. For ln-transformed AUC, a confidence interval of (−0.2316, −0.0582) is found. As insufficient information is present to reject H01 in this case, bioequivalence was not demonstrated. These limits are saved in the TEST data set using an ODS statement and may be exponentiated in an additional DATA step if findings on the original scale are desired. In this case, the lower and upper bounds are 0.7932 and 0.9425.
Within-subject variation for the test and reference formulations were 0.09851 and 0.1110, respectively. Variation associated with subject-by-formulation was negligible, with an estimated standard deviation of 1.24E-17.
No significant evidence of sequence (p = 0.7706) or period (p = 0.0835) effects was detected; however, the formulations were observed to be significantly different (p = 0.0066).
The FDA guidance (2001) states that "In the Random statement, Type=FA0(2) could possibly be replaced by Type=CSH. This guidance recommends that Type=UN not be used, as it could result in an invalid (i.e., non-negative definite) estimated covariance matrix."
There is however a similar issue with use of TYPE=FA0(2) or CSH. These are constrained structures in that their application does not allow all positive definite covariance structures to be estimable (Patterson and Jones, 2002). For example, in the CSH structure, the estimate for correlation, ρ, is constrained by PROC MIXED so that it lies in the interval −1 ≤ ρ ≤ 1. The FA0(2) structure similarly imposes constraints such that the estimate for the subject-by-formulation standard deviation is zero or greater.
The choice of FA0(2) is somewhat arbitrary and reflective in regulatory application of George Box's statement "All models are wrong, but some are useful." In applications, it has been shown that this procedure protects the Type I error rate (of key concern to regulators) when variance estimates of interest are constrained to be positive or null (Patterson and Jones, 2004). It has the additional benefit of providing variance-covariance estimates that are readily interpretable (i.e., non-negative); however, statisticians using these procedures should recognize that the variance-covariance estimates may be biased as a consequence of this choice. Note that restricted maximum likelihood modeling (REML) is also specified as a recommended option, and those desiring to apply a different method should first talk with the FDA. Although REML estimates do possess less bias than maximum likelihood estimates, they do not produce estimates which maximize the likelihood function. The FDA has thus chosen a model which is readily interpretable and potentially biased, but which protects their risk of making a false positive decision of bioequivalence.
Note that if the TYPE=UN option is specified in Program 8.2, removing this constraint, a confidence interval of (−0.2220, −0.0710) is derived as subject-by-formulation variation is estimated to be negative.