10.6. Research Question 1, Continued: Crucial Error Rates for Mortality Analysis
In developing the statistical considerations for the QCA/malaria trial, Dr. Gooden understands the value in assessing its crucial Type I and Type II error rates, and she presses her CHI colleagues to complete the exercise faithfully. As mentioned before, they are optimistic that QCA is effective, but to compute crucial error rates, they must now quantify that optimism by setting γ. Initial discussions place γ near 0.75, but the 0.30 value reported by Lee and Zelen (2000) tempers their thinking substantially. They settle on γ = 0.50. Dr. Gooden will also use γ = 0.30.
Program 10.4 gives the code to handle this. First, a more focused version of Program 10.3 computes the powers. Second, a macro called %CrucialRates (given in Appendix B and available on the book's web site) converts the PROC POWER results into crucial Type I and Type II error rates. Finally, PROC TABULATE organizes these crucial rates effectively.
Example 10-4. Compute crucial error rates for mortality endpoint
options ls=80 nocenter FORMCHAR="|----|+|---+=|-/<>*";
proc power;
ODS output output=MortalityPowers;
TwoSampleFreq
GroupWeights = (1 2) /* 1 UCO for every 2 QCA */
RefProportion = .12 .15 /* UCO mortality rate */
RelativeRisk = .75 .67 /* QCA rate vs UCO rate */
alpha = .01 .05
sides = 2
Ntotal = 2700
test = LRchi /* likelihood ratio chi-square */
power = .;
plot key=OnCurves;
run;
* Call %CrucialRates macro, given in Appendix B of this chapter;
%CrucialRates( PriorPNullFalse = .30 .50,
Powers = MortalityPowers,
CrucialErrRates = MortalityCrucRates )
proc tabulate data=MortalityCrucRates format=4.3 order=data;
title3 "Crucial Error Rates for QCA Malaria Trial";
format alpha 4.3;
class RefProportion RelativeRisk alpha gamma TypeError NTotal;
var CrucialRate;
table
Ntotal="Total N: ",
RefProportion="Usual Care Mortality"
* RelativeRisk="QCA Relative Risk",
alpha="Alpha"
* gamma="PriorP[Null False]"
* TypeError="Crucial Error Rate"
* CrucialRate=""*mean=" "
/ rtspace = 26;
run; |
Output 10.4 shows that the most optimistic case considered here presumes that the mortality rate is 0.15 under usual care and it takes QCA to have a prior probability of γ = 0.50 of being effective, where "effective'" is a QCA relative risk of 0.67. If so, then by using α = 0.05, the crucial Type I and Type II error rates are α* = 0.050 and β* = 0.040, respectively, which seem very good. However, for α = 0.01, β* rises to 0.115. Now consider the most pessimistic case. If γ = 0.30 and the non-null scenario has a mortality rate of 0.12 under usual care and a QCA relative risk is 0.75, then using α = 0.05 gives α* = 0.147 and β* = 0.127. The team from Children's Health International decides that they can tolerate these values and thus planning continues around N = 2700.
After going through this process, Dr. Capote remarks that if all clinical trial protocols where vetted in this manner, a great many of them would show crucial Type I and Type II error rates that would severely temper any inferences that can be made. This is true.
Example. Output from Program 10.4
Total N: 2700 ------------------------------------------------------------------ | | Alpha | | |---------------------------------------| | | .010 | .050 | | |-------------------+-------------------| | |PriorP[Null False] |PriorP[Null False] | | |-------------------+-------------------| | | 0.3 | 0.5 | 0.3 | 0.5 | | |---------+---------+---------+---------| | | Crucial | Crucial | Crucial | Crucial | | | Error | Error | Error | Error | | | Rate | Rate | Rate | Rate | | |---------+---------+---------+---------| | |Type|Type|Type|Type|Type|Type|Type|Type| | | I | II | I | II | I | II | I | II | |------------------------+----+----+----+----+----+----+----+----| |Usual Care |QCA Relative| | | | | | | | | |Mortality |Risk | | | | | | | | | |-----------+------------| | | | | | | | | |0.12 |0.75 |.051|.196|.022|.362|.147|.127|.069|.254| | |------------+----+----+----+----+----+----+----+----| | |0.67 |.030|.095|.013|.197|.114|.041|.052|.091| |-----------+------------+----+----+----+----+----+----+----+----| |0.15 |0.75 |.040|.158|.017|.305|.130|.089|.060|.186| | |------------+----+----+----+----+----+----+----+----| | |0.67 |.026|.053|.011|.115|.108|.018|.050|.040| ------------------------------------------------------------------ |