9.2. Permuted Block Randomization

Permuted block randomization is commonly used in clinical trials to allocate subjects to the treatment arms in required ratios. It is well accepted in the clinical community, provides good balance in treatment assignments, and supports the needs of drug packaging and distribution.

9.2.1. Permuted Block Designs

The permuted block schedule consists of a sequence of blocks that contain the treatment assignments in desired ratios; the treatment assignments are randomly permuted within the blocks. Consider, for example, a study in which subjects are to be assigned to three treatments (Treatment 1, Treatment 2 and Treatment 3) using a 2:2:1 ratio. The smallest permuted block that provides the 2:2:1 treatment ratio is the block of size 5 and is a random permutation of

(1,1,2,2,3).

An example of a sequence of treatment assignments (with blocks bracketed to illustrate the technique) is

(2, 1, 1, 3, 2), (1, 1, 2, 3, 2), (3, 2, 1, 2, 1), ... .

A larger block size (a multiple of 5) can also be used. If the block size of 10 is chosen, the blocks will each be a random permutation of

(1, 1, 1, 1, 2, 2, 2, 2, 3, 3).

Stratifying the randomization is easy with the permuted block schedule. Since any set of blocks constitutes a permuted block schedule on its own, each stratum can be assigned a set of blocks from one common schedule. This property is useful in multi-center trials where, as recommended by the ICH Guidance entitled "Guidance on Statistical Principles for Clinical Trials' (ICH E9), the allocation is typically stratified by center. The stratification is implemented by assigning a set of blocks to each center.

The permuted block allocation provides a good balance in treatment assignments: when most of the blocks in the allocation schedule are filled, the treatment ratio of allocated subjects at the end of the study is close to the planned one. Unless there are many strata and thus, many unfilled blocks, the balance stays reasonably tight throughout the enrollment as well. This improves the efficiency of interim analyses and helps mitigate the accidental bias if a time trend in treatment effect is present.

These properties made the permuted block randomization an industry standard for masked clinical trials. For unmasked trials, where selection bias is an issue, other approaches such as a permuted block design with a random block size or maximal procedure (Berger et al, 2003) might offer benefit.

9.2.2. Choice of Block Size in Permuted Block Designs

The choice of the block size for a masked permuted block schedule requires some consideration. It is preferred to have a block size big enough to include at least two subjects on each treatment to mitigate the impact of rare instances when a subject's allocation may need to be unblinded due to a serious adverse event. Having at least two subjects on each treatment within a permuted block will not narrow the list of possible assignments for other subjects from the block that the unblinded subject belongs to. This would lessen the potential for selection bias (if some of the subjects on the block are yet to be enrolled) and an observer bias.

This approach will allow using the minimal block size when the smallest block with required ratio already includes at least two subjects on each treatment (e.g., a 3:2:2 allocation ratio). When the smallest block includes only one subject on any of the treatments, e.g., a 2:2:1 ratio, the preferred block size will be at least twice as large as the minimal block size (that is, at least 10).

The outlined block size selection strategy is intended to lessen the impact of unblinding and might not be advisable for a multi-center trial with small centers. For example, if the minimal block size is 5 and most of the centers are expected to enroll about six subjects, using a block size of 10 will lead to predominantly incomplete blocks and thus to suboptimal balance in treatment assignments. A compromise can often be reached by using one of the variations of permuted block designs (see Sections 9.3.2 and 9.3.4); however, if the possibility of unblinding is low, the most practical option might be to use the smallest block size. In reality, designs with a block size of 2 in which an unblinding of one subject leads to the unblinding of the other subject in the same block, are rarely used.

9.2.3. Generating Permuted Block Schedules

Permuted block schedules can be easily generated using PROC PLAN. PROC PLAN is a powerful procedure and often allows to generate the same randomization schedule using several different sets of options. We will present one of the options in the example below.

EXAMPLE: Three-arm clinical trial with a 2:2:1 randomization ratio

Consider a study in which 120 subjects are allocated to three treatment arms (Treatment 1, Treatment 2 and Treatment 3) with a 2:2:1 ratio using the permuted block randomization with a block size 5. As is typically the case, it was decided to prepare an allocation schedule for more than 120 subjects by generating a total of 60 permuted blocks.

Program 9.1 uses PROC PLAN to generate a permuted block schedule for the three-arm trial. The first option (SEED=56789) in the PROC PLAN statement specifies a random seed to make the schedule reproducible. If no seed is provided, the time of the day will be used as a default seed and each run of the program will result in a different schedule. The random seed used in the schedule should not be disclosed until the study is unblinded. The next statement

factors block=60 ordered treatment=5;

requests that the BLOCK variable be created in the output data set with values ordered from 1 to 60. For each value of BLOCK, five observations with five levels of the TREAT variable will be generated in a random order. Next,

output out=schedule treatment nvals=(1 1 2 2 3);

specifies the name of the output data set (SCHEDULE) as well as numeric values (1, 1, 2, 2 and 3) that will be assigned to the five levels of the TREATMENT variable. PROC PLAN is followed by a DATA step that assigns consecutive allocation numbers (AN variable) from 1 to 300 to all observations on the list. The treatment assignment is stored in the TREATMENT variable.

Example 9-1. Three-arm clinical trial with a 2:2:1 randomization ratio

ods listing close;
proc plan seed=56789;
    factors block=60 ordered treatment=5;
    output out=schedule treatment nvals=(1 1 2 2 3);
data schedule;
    set schedule;
    an=_n_;
    label treatment='Treatment group'
          block='Block number'
          an='Allocation number';
proc print data=schedule noobs label;
    var an treatment block;
    ods listing;
    run;

Example. Partial output from Program 9.1

Allocation    Treatment     Block
  number        group      number

     1            3           1
     2            2           1
     3            2           1
     4            1           1
     5            1           1
     6            1           2
     7            1           2
     8            2           2
     9            3           2
    10            2           2

Output 9.1 shows the first ten observations in the SCHEDULE data set. These observations represent the allocation of the first ten subjects (two permuted blocks).

To generate 30 permuted blocks of size 10, the PROC PLAN options in Program 9.1 need to be modified in the following way:

proc plan seed=56789;
    factors block=30 ordered treatment=10;
    output out=schedule treat nvals=(1 1 1 1 2 2 2 2 3 3);

The described approach to generating permuted block schedules relies on drawing permuted blocks with replacement from a set of all existing permuted blocks with specified contents. The resulting schedule does not necessarily use all existing permuted blocks of a given structure and the same block can appear on the schedule multiple times. This approach is simple to implement and, in most circumstances, adequately serves the needs of clinical researchers.

An alternative approach was described by Zelen (1974) for two-arm studies with a 1:1 allocation that uses the permuted blocks of size 4. Zelen proposed to list all six existing permuted blocks,

(1, 1, 2, 2), (1, 2, 1, 2), (1, 2, 2, 1), (2, 1, 1, 2), (2, 1, 2, 1), (2, 2, 1, 1),

and then randomly permute them to form a randomization sequence for the first 24 subjects. The procedure can be repeated as many times as needed to produce the randomization schedule for any number of subjects. With this approach, the sets of all existing permuted blocks are repeatedly used. This strategy can also be implemented with PROC PLAN. Section 9.3.4 describes the circumstances under which the Zelen approach can be beneficial.