VIEWING DATA FILE MANAGER STYLE WITH THE TREEVIEW CONTROL

The last control to examine is the TreeView control. This ActiveX control allows you to view your data in a manner similar to Windows Explorer, with the added feature of being able to include graphic images. An example of a TreeView control can be found on the WindowsCommonControlsTreeView form, which is in Chap14.mdb in the ExamplesChap14 folder on the accompanying CD-ROM. Figure 14.22 shows the WindowsCommonControlsTreeView form as a source object for the WindowsCommonControls form.

Notice in Figure 14.22 how the expanded category, called a node, is displaying a different image than an unexpanded one. This TreeView control uses three different images: unexpanded node, expanded node, and leaf node (sometimes called the bottom node). Figure 14.23 shows these images in the ImageList control called ocxImageList. (For more information on setting up the ImageList control, see the earlier section “Using the ImageList Control with the TabStrip Control.”)

After setting up the images, you need to set the ImageList property of the TreeView control to ocxListImageSub.

In addition to setting up the ImageList control, you need to set the Style property so that it displays images with lines. Eight different styles are available:

The style chosen for this example is 5 (Lines, Plus/Minus, Picture, Text). You can see Style 7, as well as other properties for the TreeView control, in Figure 14.24.

That's all you have to do to set up the TreeView for the current example on the WindowsCommonControlsTreeView form. The rest is performed in the following code, which is on the OnLoad event of the WindowsCommonControlsTreeView form (see Listing 14.15).

Listing 14.15. Chap14.mdb: Populating the TreeView Control

Private Sub Form_Load()

   Dim objCurrNode As Node

   Dim dbLocal As Database
   Dim dynCategories As Recordset, dynMovies As Recordset

   '-- Open the necessary recordset
   Set dbLocal = CurrentDb()
   Set dynCategories = dbLocal.OpenRecordset("Categories", dbOpenDynaset)
   Set dynMovies = dbLocal.OpenRecordset("qryMoviesByCategories", _
                     dbOpenDynaset)

   '-- Loop through the categories
   Do Until dynCategories.EOF

      '-- Add a top node (Category)
      Set objCurrNode = Me!ocxTreeView.Nodes.Add(, , _
               "Category" & CStr(dynCategories!CategoryCode), _
                                     dynCategories!Description, 1)

      '-- Establish which image to use for an expanded branch
      objCurrNode.ExpandedImage = 2

      If Not dynMovies.EOF Then
         '-- Add a branch to the current top node (Category)
         Do While dynMovies!CategoryCode = dynCategories!CategoryCode

            Set objCurrNode = Me!ocxTreeView.Nodes.Add( _
                  "Category" & CStr(dynCategories!CategoryCode), _
                      tvwChild, , dynMovies!Title, 3)

            dynMovies.MoveNext

            If dynMovies.EOF Then
               Exit Do
            End If

         Loop
      End If
      dynCategories.MoveNext
   Loop

   Me!ocxTreeView.Refresh

End Sub
					

The code in Listing 14.15 actually takes the data from within tables and stores it into the nodes of the TreeView control. Like other ActiveX controls, the TreeView control uses a collection, called Nodes. You see the Nodes collection in the steps this code performs:

Set objCurrNode = Me!ocxTreeView.Nodes.Add(, , _
         "Category" & CStr(dynCategories!CategoryCode), _
                               dynCategories!Description, 1)

objCurrNode.ExpandedImage = 2

Do While dynMovies!CategoryCode = dynCategories!CategoryCode

   Set objCurrNode = Me!ocxTreeView.Nodes.Add( _
         "Category" & CStr(dynCategories!CategoryCode), _
             tvwChild, , dynMovies!Title, 3)

The TreeView control can use quite a few properties and methods through the Nodes collection and the control itself. This example just touched on some of the power of the TreeView control.